Bug ? StringIsDigit("-123")

[Trong]

MsgBox(48,"","-123 Is Digit: "&StringIsDigit("-123") &@CRLF) 

"-123" Is not a number? or a bug?

[BrewManNH]

That function only deals with numbers, the minus sign isn't a number so the string isn't seen as a number. It would be the same result if you used "1.0", as the decimal point isn't a number. Not a bug.

[Trong]

I found a solution to the numbers and strings!

 

First I nested these particular expressions in parentheses and it didn't work. I then thought it would be more consistant to create them as separate groups and it worked. However, you are right to point out that it is needless bloat. Thanks!

Func _StringIsNumber($sString)
    Return StringRegExp($sString, "(?i)\A(\-?\d+(\.\d+)?(e[\+\-]\d{1,3})?|0x[A-F\d]{1,16})\z") = 1
EndFunc

Edit:

Identify Binary (0xABC0FF) is the number! Not perfect

Edited February 25, 2015 by Trong

[czardas]

Identify Binary (0xABC0FF) is the number! Not perfect

 

The intention with the above function was to return true for all numeric formats recognized by AutoIt: 0xABC0FF becomes a number when the interpreter executes that string. We can remove parts of the regular expression to prevent various formats from returning True, as I have done below. This gives several alternatives.

;

#include <Array.au3>

Func _StrIsNumHx($sString) ; original expression
    Return StringRegExp($sString, "(?i)\A(\-?\d+(\.\d+)?(e[\+\-]\d{1,3})?|0x[A-F\d]{1,16})\z") = 1
EndFunc


Func _StrIsNumEx($sString) ; no hex representation
    Return StringRegExp($sString, "(?i)\A(\-?\d+(\.\d+)?(e[\+\-]\d{1,3})?)\z") = 1
EndFunc


Func _StrIsNumFl($sString) ; no exponential notation
    Return StringRegExp($sString, "\A(\-?\d+(\.\d+)?)\z") = 1
EndFunc


Func _StrIsNumIn($sString) ; no floats
    Return StringRegExp($sString, "\A(\-?\d+)\z") = 1
EndFunc

Local $aTruthTable[5][5] = [['Input','_StrIsNumHx','_StrIsNumEx','_StrIsNumFl','_StrIsNumIn']]

$aTruthTable[1][0] = '0xABC0FF' ; binary
$aTruthTable[2][0] = '-1e-101' ; exponential
$aTruthTable[3][0] = '12.007' ; float
$aTruthTable[4][0] = '-123' ; integer

For $i = 1 To 4
    $aTruthTable[$i][1] = _StrIsNumHx($aTruthTable[$i][0])
    $aTruthTable[$i][2] = _StrIsNumEx($aTruthTable[$i][0])
    $aTruthTable[$i][3] = _StrIsNumFl($aTruthTable[$i][0])
    $aTruthTable[$i][4] = _StrIsNumIn($aTruthTable[$i][0])
Next

_ArrayDisplay($aTruthTable, "Truth Table")

Edited February 26, 2015 by czardas

[Trong]

A simple solution and accurate: by >SmOke_N