StringRegExpReplace (date format)

[JohnOne]

I'm trying to change some date formats to simple numerical values for easy sorting.

With the assistance of the help file I managed to complete the first format, but the second one, I am stuck at.

$Date = '21/09/2009 21:35'

$DatePattern = '(\d{2})/(\d{2})/(\d{4})( )(\d{2})(:)(\d{2})'

$SRER = StringRegExpReplace($Date, $DatePattern, '$3$2$1$5$7')

ConsoleWrite($Date & @LF & @LF & $SRER & @LF & @LF & @error & " " & @extended & @LF)


$Date2 = '16-Mar-2010 22:14:00'

$DatePattern2 = "^(\d\d)-([A-Za-z]{3})-(\d{4})( )(\d{2})(:)(\d{2})(:)(\d{2})\z"

$SRER2 = StringRegExpReplace($Date2, $DatePattern2, '$3$2$1$5$7')

ConsoleWrite($Date2 & @LF & @LF & $SRER2 & @LF & @LF & @error & " " & @extended & @LF)

In this case, "Mar" should be replaced with "03". If it were "Dec" it would be replaced with "12".

I was shown a stricter way to capture that part by another member SadBunny in another thread, but I still do not know how I could replace with corresponding numerical value.

"^([0-3]?[0-9]-(Jan|Feb|Mar|Apr|May|Jun|Jul|Aug|Sep|Oct|Nov|Dec)-\d{4} [0-2][0-9]:[0-5][0-9]:[0-5][0-9])\z"

Any help and explanations are warmly welcomed.

Edited February 23, 2015 by JohnOne

[Melba23]

JohnOne,

Trying to deal with date formats (particularly ones with letter months/days) is very difficult and I am not sure you can do it in a single RegEx - cue for someone to prove me wrong!

I had to write quite a complex UDF to do it - look in my sig for Date_Time_Convert:

#include "DTC.au3"

$sDate = '21/09/2009 21:35'
$sRet = _Date_Time_Convert($sDate, "dd/MM/yyyy HH:mm", "yyyyMMddHHmm")
ConsoleWrite($sRet & @CRLF)

$sDate = '16-Mar-2010 22:14:00'
$sRet = _Date_Time_Convert($sDate, "dd-MMM-yyyy HH:mm:ss", "yyyyMMddHHmm")
ConsoleWrite($sRet & @CRLF)

M23

[JohnOne]

Thanks M

That works a treat.

Appreciate it.

[iamtheky]

$Date2 = '16-Mar-2010 22:14:00'

$DatePattern2 = "^(\d\d)-([A-Za-z]{3})-(\d{4})( )(\d{2})(:)(\d{2})(:)(\d{2})\z"

$SRER2 = StringRegExpReplace($Date2, $DatePattern2, '$3$2$1$5$7')

Dim $MonthAbb[13] = [12 , "Jan" , "Feb" , "Mar" , "Apr" , "May" , "Jun" , "Jul" , "Aug" , "Sep" , "Oct" , "Nov" , "Dec"]

For $i = 1 to 12
$SRER2 = stringreplace($SRER2 , $MonthAbb[$i] , stringformat("%02s" , $i))
Next

ConsoleWrite($Date2 & @LF & @LF & $SRER2 & @LF & @LF & @error & " " & @extended & @LF)

[SadBunny]

$Date2 = '16-Mar-2010 22:14:00'

$DatePattern2 = "^(\d\d)-([A-Za-z]{3})-(\d{4})( )(\d{2})(:)(\d{2})(:)(\d{2})\z"

$SRER2 = StringRegExpReplace($Date2, $DatePattern2, '$3$2$1$5$7')

Dim $MonthAbb[13] = [12 , "Jan" , "Feb" , "Mar" , "Apr" , "May" , "Jun" , "Jul" , "Aug" , "Sep" , "Oct" , "Nov" , "Dec"]

For $i = 1 to 12
$SRER2 = stringreplace($SRER2 , $MonthAbb[$i] , stringformat("%02s" , $i))
Next

ConsoleWrite($Date2 & @LF & @LF & $SRER2 & @LF & @LF & @error & " " & @extended & @LF)

 

At the very least case-insensitivize the patterns

Yes, and then someone runs this on a Dutch or German system and Mar, May and Oct suddenly become month 0 or are not replaced and your whole system breaks in three different months of the year. I hate dateformats with alpha chars in them Especially stupid are dates retrieved from a MSSQL server. If you duplicate a MSSQL server including DB's in them but install the thing on a Windows Server OS in another language, the dates come in another language by default. Fun, if your dev env has a dutch server and your prod env has an English one, because of cheap idiots managing idiotic M$ licensing. Grmbl. Sorry for the rant.

Also, even if it would be possible with a single regex (and it probably is), I couldn't be arsed in the slightest This is one of these cases where I wonld only use regex to match stuff, then use a lookup array to fix like boththose.

Edited February 23, 2015 by SadBunny

[Malkey]

Here is an English version.

Local $Date = '16-Mar-2010 22:14:00'

Local $Date2 = Execute(StringRegExpReplace($Date, "(?i)^(\d{2})-([A-Z]{3})-(\d{4})\h(\d{2}):(\d{2}):(\d{2})$", _
        "'$3' & StringRight('0' & UBound(StringRegExp('$2', '(Jan)|(Feb)|(Mar)|(Apr)|(May)|(Jun)|(Jul)|(Aug)|(Sep)|(Oct)|(Nov)|(Dec)|', 3)) - 1, 2) & '$1$4$5$6'"))

ConsoleWrite($Date2 & @LF) ; Returns 20100316221400