Listview flicker when in tab item

[JohnOne]

My script needs to load data from external source to listview control, sometimes over 1000 items.

I have a need to have more than one listview control loaded with data, so decided to add a couple of tabs.

Without listview in tabitem, it loads within around 500ms, but when it is in tab item it takes 10x that and flickers like crazy.

Anyone know of a workaround?

Below is my reproducer code, test it without tab item, then uncomment Tab 1 to see problem.

#include <ListViewConstants.au3>
#include <GuiListView.au3>

$sLVI = "one|two|three|four"

$Gui = GUICreate("GUI", 600, 600, 100, 100)

$button = GUICtrlCreateButton("go", 560, 20)

GUICtrlCreateTab(0, 0, 500, 500)
;GUICtrlCreateTabItem("Tab 1")

$hLV = GUICtrlCreateListView($sLVI, 0, 20, 500, 500)
_GUICtrlListView_SetExtendedListViewStyle($hLV, BitOR($LVS_EX_GRIDLINES, $LVS_EX_DOUBLEBUFFER))

GUICtrlCreateTabItem("Tab 2")

GUISetState()
While 3
    Switch GUIGetMsg()
        Case -3
            Exit
        Case $button
            PopulateLV()
    EndSwitch
WEnd

Func PopulateLV()
    For $i = 0 To 300
        GUICtrlCreateListViewItem($sLVI, $hLV)
    Next
EndFunc   ;==>PopulateLV

Disabling the listview control has no effect, nor does hiding it.

[mLipok]

Anyone know of a workaround?

 

avoid repaint

switch to tab 2

fill listview

switch to tab 1

repaint

edit: typo

Edited February 22, 2015 by mLipok

[JohnOne]

Makes no difference bud, still flicker.

[JohnOne]

Only workaround I can figure is to hide the whole gui, which is a bit overkill I think.

Func PopulateLV()
    GUISetState(@SW_HIDE)
    For $i = 0 To 300
        GUICtrlCreateListViewItem($sLVI, $hLV)
    Next
    GUISetState(@SW_SHOW)
EndFunc   ;==>PopulateLV

[mLipok]

Makes no difference bud, still flicker.

 

Time for Func PopulateLV  is much better.

expandcollapse popup

#include <ListViewConstants.au3>
#include <GuiListView.au3>
#include <WindowsConstants.au3>


$sLVI = "one|two|three|four"

Global $hGUI = GUICreate("GUI", 600, 600, 100, 100)

$button = GUICtrlCreateButton("go", 560, 20)

GUICtrlCreateTab(0, 0, 500, 500)
GUICtrlCreateTabItem("Tab 1")
Global $hLV = GUICtrlCreateListView($sLVI, 0, 20, 500, 500)
_GUICtrlListView_SetExtendedListViewStyle($hLV, BitOR($LVS_EX_GRIDLINES, $LVS_EX_DOUBLEBUFFER))
GUICtrlCreateTabItem("Tab 2")
GUICtrlCreateTabItem("")
GUISetState()


While 3
    Switch GUIGetMsg()
        Case -3
            Exit
        Case $button
            PopulateLV(False)
            PopulateLV(True)
    EndSwitch
WEnd

Func PopulateLV($bTest)
    Local $hTimer = TimerInit()
;~  If $bTest Then _WinAPI_RedrawWindow ( $hGUI,0,0,BitOR($RDW_NOINTERNALPAINT,$RDW_NOERASE , $RDW_NOFRAME ) )
    If $bTest Then _GUICtrlListView_BeginUpdate ( $hLV)
    For $i = 0 To 300
        GUICtrlCreateListViewItem($sLVI, $hLV)
    Next
    Local $iDiff = TimerDiff($hTimer)
    If $bTest Then _GUICtrlListView_EndUpdate( $hLV)
;~  If $bTest Then _WinAPI_RedrawWindow ( $hGUI,0,0,$RDW_INTERNALPAINT )
    MsgBox(0, "Time Difference", $iDiff/1000)

EndFunc   ;==>PopulateLV

[Kilmatead]

Func PopulateLV()
    _WinAPI_LockWindowUpdate($Gui)

    For $i = 0 To 300
        GUICtrlCreateListViewItem($sLVI, $hLV)
    Next

    _WinAPI_LockWindowUpdate(Null)
    _WinAPI_InvalidateRect($Gui)
    _WinAPI_UpdateWindow($Gui)
EndFunc   ;==>PopulateLV

[JohnOne]

Ace that, Kilmatead.

Thank you muchly bud.

[JohnOne]

Combined with mLipok sugestion, which on it's own still produces flicker, it is even quicker.

Thank you both.

Func PopulateLV()
    _GUICtrlListView_BeginUpdate ($hLV)
    _WinAPI_LockWindowUpdate($hGUI)

    For $i = 0 To 1000
        GUICtrlCreateListViewItem($sLVI, $hLV)
    Next

    _WinAPI_LockWindowUpdate(Null)
    _GUICtrlListView_EndUpdate( $hLV)
    _WinAPI_InvalidateRect($hGUI)
    _WinAPI_UpdateWindow($hGUI)
EndFunc   ;==>PopulateLV

[mLipok]

take a look:

expandcollapse popup

#include <ListViewConstants.au3>
#include <GuiListView.au3>
#include <WindowsConstants.au3>
#include <WinAPIGdi.au3>
#include <GuiTab.au3>

$sLVI = "one|two|three|four"

Global $Gui = GUICreate("GUI", 600, 600, 100, 100)

$button = GUICtrlCreateButton("go", 560, 20)

Global $hTab = GUICtrlCreateTab(0, 0, 500, 500)
Global $idTab1 = GUICtrlCreateTabItem("Tab 1")
Global $hLV = GUICtrlCreateListView($sLVI, 0, 20, 500, 500)
_GUICtrlListView_SetExtendedListViewStyle($hLV, BitOR($LVS_EX_GRIDLINES, $LVS_EX_DOUBLEBUFFER))
Global $idTab2 = GUICtrlCreateTabItem("Tab 2")
GUICtrlCreateTabItem("")
GUISetState()


While 3
    Switch GUIGetMsg()
        Case -3
            Exit
        Case $button
            PopulateLV()
    EndSwitch
WEnd

Func PopulateLV()
    Local $hTimer = TimerInit()
    _WinAPI_LockWindowUpdate($Gui)
    _GUICtrlTab_ClickTab($hTab, 1)
    For $i = 0 To 300
        GUICtrlCreateListViewItem($sLVI, $hLV)
    Next
    _GUICtrlTab_ClickTab($hTab, 0)
    _WinAPI_LockWindowUpdate(0)
;~  _WinAPI_InvalidateRect($Gui)
;~  _WinAPI_UpdateWindow($Gui)
    MsgBox(0, "Time Difference", TimerDiff($hTimer) / 1000)
EndFunc   ;==>PopulateLV

[JohnOne]

That makes it quicker indeed, mLipok.

Good thinking.

For me though, I may have many tabs, and keeping track of which is active may not outweigh the benefits of the speed.

Thanks again.

EDIT:

Also, when script first starts, there may only be one tab, until another is added.

Edited February 23, 2015 by JohnOne

[mLipok]

I am interested in explaining why these two functions:

;~  _WinAPI_InvalidateRect($Gui)
;~  _WinAPI_UpdateWindow($Gui)

have been used, although as you can see they are not needed.

Does anyone have any ideas?

[SmOke_N]

https://msdn.microsoft.com/en-us/library/windows/desktop/dd145005(v=vs.85).aspx

Should explain both questions... don't forget to read after the code area.

[kylomas]

J1,

No flicker and 1000 loaded in .05 sec...

expandcollapse popup

#include <ListViewConstants.au3>
#include <GuiListView.au3>
#include <WindowsConstants.au3>
#include <WinAPIGdi.au3>
#include <GuiTab.au3>

$sLVI = "one|two|three|four"

Global $Gui = GUICreate("GUI", 600, 600, 100, 100)

$button = GUICtrlCreateButton("go", 560, 20)

Global $hTab = GUICtrlCreateTab(0, 0, 500, 500)
Global $idTab1 = GUICtrlCreateTabItem("Tab 1")
Global $hLV = GUICtrlCreateListView($sLVI, 0, 20, 500, 500)
_GUICtrlListView_SetExtendedListViewStyle($hLV, BitOR($LVS_EX_GRIDLINES, $LVS_EX_DOUBLEBUFFER))
Global $idTab2 = GUICtrlCreateTabItem("Tab 2")
GUICtrlCreateTabItem("")
GUISetState()


While 3
    Switch GUIGetMsg()
        Case -3
            Exit
        Case $button
            PopulateLV()
    EndSwitch
WEnd

Func PopulateLV()
    Local $hTimer = TimerInit()
    GUISetState(@SW_LOCK)
    For $i = 0 To 1000
        GUICtrlCreateListViewItem($sLVI, $hLV)
    Next
    GUISetState(@SW_UNLOCK)
    _GUICtrlTab_ClickTab($hTab, 0)
    MsgBox(0, "Time Difference", TimerDiff($hTimer) / 1000)
EndFunc   ;==>PopulateLV

[mLipok]

and Dreams Come to True

[kylomas]

The run times between _WinAPI_LockWindowUpdate anf GuiSetState ar almost identical...I just chose the simplest way that I knew to prevent re-painting...

[JohnOne]

Thanks, kylomas, that is so simple, I'm a little ashamed I never thought of it myself.

Not sure how the clicking tab is needed though.

[mLipok]

@J1

I made some tests.

With Clicikng tab is slower then without clicking.

@kylomas can you edit your script, so for posterity

[kylomas]

Not sure how the clicking tab is needed though.

 

It has no bearing on flicker or speed on populating the listview.  I thought it was part of what you were doing afterward.

[JohnOne]

I'm wondering now if _WinAPI_LockWindowUpdate and GUISetState(@SW_LOCK) are actually the same thing.

Meaning AutoIt native function is LockWindowUpdate.

[kylomas]

That is exaclty what I thought when I looked at this thread...