FF.au3 (v0.6.0.1b-15) [End of life]

[mLipok]

Thanks, it works as expected

 

[mLipok]

On 27.04.2017 at 0:57 PM, jchd said:

In this case (UTF8 input) you just need to filewrite things in a file open with the BINARY flag, no UTF8 at all.

@jchd How I could use this strings without saving them to file ?

Here is example showing what I'm trying to do:

#include "FF.au3"
#include <FileConstants.au3>

If _FFConnect(Default, Default, 3000) Then
    _Example()
    If _FFDisConnect() Then MsgBox(64, "", "Disconnected from FireFox!")
Else
    MsgBox(64, "", "Can't connect to FireFox!")
EndIf

Exit

Func _Example()
    _FFOpenURL('http://wolnelektury.pl/')

    Local $sObject = _FFObjGet("nav#menu>ul#user-info>li>a#login", 'QuerySAll', 0)
    Local $sOuterHTML = _FFObj($sObject, 'outerHTML')
    MsgBox(0, "_FFCmd($sObject & '.outerHTML')", $sOuterHTML)
    If @error Then ConsoleWrite('! ---> @error=' & @error & '  @extended=' & @extended & ' : QuerySelectorAll ... textContent' & @CRLF)

    ClipPut($sOuterHTML)
    #cs
        the problem is $sOuterHTML contain string presented in this following line
        <a href="/uzytkownik/login/?next=/" id="login">Zaloguj siÄ™</a>

        instead:
        <a href="/uzytkownik/login/?next=/" id="login">Zaloguj się</a>
    #ce

    If StringInStr($sOuterHTML, 'Zaloguj się') Then
        MsgBox(0, 'Zaloguj się', 'Found')
    Else
        MsgBox(0, 'Zaloguj się', 'Not Found')
    EndIf
EndFunc   ;==>_Example

 

I would be very much obliged if we could work together to refine this UDF so that the returned values were with user-specific encoding.

Edited May 5, 2017 by mLipok
script fix: #CS #CE >> #cs #ce

[jchd]

I get an error using your scirpt (before the conversion I added).

expandcollapse popup

#include "..\include\FF.au3"
#include <FileConstants.au3>

If _FFConnect(Default, Default, 3000) Then
    _Example()
    If _FFDisConnect() Then MsgBox(64, "", "Disconnected from FireFox!")
Else
    MsgBox(64, "", "Can't connect to FireFox!")
EndIf

Exit

Func _Example()
    _FFOpenURL('http://wolnelektury.pl/')

    Local $sObject = _FFObjGet("nav#menu>ul#user-info>li>a#login", 'QuerySAll', 0)
    Local $sOuterHTML = _FFObj($sObject, 'outerHTML')
    If @error Then ConsoleWrite('! ---> @error=' & @error & '  @extended=' & @extended & ' : QuerySelectorAll ... textContent' & @CRLF)
    MsgBox(0, "_FFCmd($sObject & '.outerHTML')", $sOuterHTML)
    ; convert UTF8 to native UTF16
    $sOuterHTML = BinaryToString(StringToBinary($sOuterHTML, 1), 4)
    MsgBox(0, "_FFCmd($sObject & '.outerHTML')", $sOuterHTML)

    ClipPut($sOuterHTML)
    #cs
        the problem is $sOuterHTML contain string presented in this following line
        <a href="/uzytkownik/login/?next=/" id="login">Zaloguj siÄ™</a>

        instead:
        <a href="/uzytkownik/login/?next=/" id="login">Zaloguj się</a>
    #CE

    If StringInStr($sOuterHTML, 'Zaloguj się') Then
        MsgBox(0, 'Zaloguj się', 'Found')
    Else
        MsgBox(0, 'Zaloguj się', 'Not Found')
    EndIf
EndFunc   ;==>_Example

This yields:

_FFConnect: OS: WIN_7 WIN32_NT 7601 Service Pack 1
_FFConnect: AutoIt: 3.3.14.0
_FFConnect: FF.au3: 0.6.0.1b-15
_FFConnect: IP: 127.0.0.1
_FFConnect: Port:   4242
_FFConnect: Delay:  2ms
_FFConnect: Socket:     540
_FFConnect: Browser:    Mozilla/5.0 (Windows NT 6.1; WOW64; rv:53.0) Gecko/20100101 Firefox/53.0
__FFSendJavaScripts: Sending functions to FireFox .......... done
_FFOpenURL: http://wolnelektury.pl/
__FFSend: try{window.content.top.document.location.href='http://wolnelektury.pl/'}catch(e){'_FFCmd_Err';};
__FFRecv: http://wolnelektury.pl/
_FFLoadWait: .... loaded in 1310ms
[object HTMLDocument] - {location: {...}, getElementsByName: function() {...}, open: function() {...}, close: function() {...}, write: function() {...}, writeln: function() {...}, execCommand: function() {...}, ...}
__FFSend: FFau3.WCD=window.content.top.document;
__FFRecv: [object HTMLDocument] - {location: {...}, getElementsByName: function() {...}, open: function() {...}, close: function() {...}, write: function() {...}, writeln: function() {...}, execCommand: function() {...}, ...}
[object HTMLDocument] - {location: {...}, getElementsByName: function() {...}, open: function() {...}, close: function() {...}, write: function() {...}, writeln: function() {...}, execCommand: function() {...}, ...}
__FFSend: try{FFau3..hasAttribute('outerHTML')}catch(e){'_FFCmd_Err';};
_FFObjGet ==> Invalid value: (id|name|class|tag) $sMode: QuerySAll
__FFSend: ;
__FFRecv: 
__FFSend: try{FFau3..outerHTML}catch(e){'_FFCmd_Err';};

__FFWaitForRepl ==> Error return value: MozRepl ....>
__FFRecv: !!! SyntaxError: missing name after . operator

Details:
"C:\Users\jc\Documents\AutoMAT\tmp\t.au3" (42) : ==> Can not initialize a variable with itself.:
Local $sOuterHTML = BinaryToString(StringToBinary($sOuterHTML, 1), 4)
Local $sOuterHTML = BinaryToString(StringToBinary(^ ERROR

 

[Danp2]

@jchd He's using a modified version of _FFObjGet, which he posted a few days ago in this thread.

[mLipok]

There is no problem now but it would be if you back with Local declaration

Local $sOuterHTML = BinaryToString(StringToBinary($sOuterHTML, 1), 4)

But I see you fix it , by not redeclaring them again as this variable was declared before.

Now this works properly.

 

I'm curious if this following line:

Return BinaryToString(StringToBinary($RetVal, 1), 4)
; instead
; Return $RetVal

Inside this UDF will cause any problems for other users of this UDF.

 

[mLipok]

3 minutes ago, Danp2 said:

@jchd He's using a modified version of _FFObjGet, which he posted a few days ago in this thread.

ah... of course you have right.

[Danp2]

Looks like the UTF-8 encoding is coming from MozRepl.

See https://github.com/bard/mozrepl/pull/29

Edited May 5, 2017 by Danp2

[jchd]

Ah, I ignored this relied on a modified UDF. Sorry I don't follow this thread in detail.

If MozRepl returns UTF8 in all cases (I mean regardless of the encoding declared by the website, MozRepl converts everything to UTF8 for output), then it's safe [and even mandatory] to convert outputs to UTF16-LE for proper processing with AutoIt.

If the cake is half-cooked (MozRepl doesn't always output UTF8 in all cases) then things are much, MUCH difficult to deal with properly.
Yet I'd be a bit surprised if there are "significant" websites not using UTF8 today.

[mLipok]

As anybody using FF.au3 should know which encoding is needed, I would propose this as a optional feature to this UDF.

In this weekend I prepare some proposal/solution to this case.

I want to make it as universall as it is possible.

Edited May 5, 2017 by mLipok

[mLipok]

@Danp2  I would like to ask you about what you think about adding to next release ,  my proposal  for  querySelectorAll  feature  in _FFObjGET()

 

 

 

[Danp2]

@mLipok I think it's fine. Just pondering the options for ongoing maintenance of the UDF. Since @Stilgar hasn't reappeared, I'm thinking about setting up a repo on Github to maintain it.

[mLipok]

Today I have some issue with FF.au3

I get this:

Quote

__FFSend: FFau3.xpath=null;try{FFau3.xpath=FFau3.WCD.evaluate("//a[@id='j_idt121']",FFau3.WCD,null,XPathResult.FIRST_ORDERED_NODE_TYPE,null).singleNodeValue;}catch(e){'_FFXPath_Error: '+e;};
__FFRecv: _FFXPath_Error: TypeError: can't access dead object
__FFSend: try{FFau3.simulateEvent(0,'MouseEvents','click');}catch(e){'_FFCmd_Err';};
_FFXPath ==> Error return value: _FFXPath_Error: TypeError: can't access dead object
__FFRecv: -3
_FFClick ==> No match: $sElement: 0
 

In my script there was code like this:

Local $oElement = _FFXPath("//a[@id='" & $sID_jdt_RozwinWszystko & "']")
    _FFClick($oElement)

This code was in a some kind of Loop, and I constantly gets this above output.

So I stop this script and  I made separate testing script just this few lines
 

If _FFConnect(Default, Default, 3000) Then
    Local $sID_jdt_RozwinWszystko = 'j_idt121'
    Local $oElement = _FFXPath("//a[@id='" & $sID_jdt_RozwinWszystko & "']")
    _FFClick($oElement)
EndIf

And all was correctly processed.

Question:
How you think in that case wat mean this error log: can't access dead object

?

 

[Danp2]

Not sure. You could try adding some error checking to see if that helps identify / handle the error.

Also, may want to review this article.

[mLipok]

MODYFICATION:

expandcollapse popup

Func _FFObj($sObject, $sAttrib = "", $vValue = "")
    Local Const $sFuncName = "_FFObj"

    If StringLeft($sObject, 7) = "OBJECT|" Then $sObject = StringMid($sObject, 8)
    If StringLeft($sObject, 1) = "." Then $sObject = "window.content.document" & $sObject
    If Not (StringInStr($sObject, "window.content") Or StringInStr($sObject, "FFau3.")) Then $sObject = "FFau3." & $sObject

    If $sAttrib <> "" Then
        If Not StringInStr($sAttrib, "(") Then
            _FFCmd($sObject & ".hasAttribute('" & $sAttrib & "')")
            If @error And $vValue <> "" Then
                ;SetError(__FFError($sFuncName, $_FF_ERROR_InvalidValue, "$sAttrib not found: " & $sAttrib))
                _FFCmd($sObject & "setAttributeNode('" & $sAttrib & "')")
            EndIf
        EndIf
        $sObject &= "." & $sAttrib

        If IsInt($vValue) Then
            $sObject &= "=" & $vValue
        ElseIf IsBool($vValue) Then
            $sObject &= "=" & __FFB2S($vValue)
        ElseIf $vValue <> "" Then
            $sObject &= "='" & $vValue & "'"
        EndIf
    EndIf

    Local $RetVal = _FFCmd($sObject)
    If Not @error And $RetVal <> "_FFCmd_Err" Then
        Return __FF_Encoder($RetVal)
    Else
        SetError(__FFError($sFuncName, $_FF_ERROR_NoMatch, "$sObject not found: " & $sObject))
        Return ""
    EndIf
EndFunc   ;==>_FFObj

Func _FF_EncodingFunction($fnEncodingFunction = Default)
    Local Static $fnEncodingFunction_static = Null
    If IsFunc($fnEncodingFunction_static) Then Return $fnEncodingFunction_static
    If IsFunc($fnEncodingFunction) Then
        $fnEncodingFunction_static = $fnEncodingFunction
        Return $fnEncodingFunction_static
    EndIf

    If $fnEncodingFunction = Null Then $fnEncodingFunction_static = Null
    Return SetExtended(1)
EndFunc   ;==>_FF_EncodingFunction

Func __FF_Encoder(ByRef $sData)
    Local $fnEncodingFunction = _FF_EncodingFunction()
    If IsFunc($fnEncodingFunction) Then Return $fnEncodingFunction($sData)
    Return $sData
EndFunc   ;==>__FF_Encoder

Func _FF_Encoder1(ByRef $sData)
    Return BinaryToString(StringToBinary($sData, 1), 4)
EndFunc   ;==>__FF_Encoder

 

EXAMPLE:
 

#include "FF_modified.au3"
#include <FileConstants.au3>

If _FFConnect(Default, Default, 3000) Then
    _Example()
    If _FFDisConnect() Then MsgBox(64, "", "Disconnected from FireFox!")
Else
    MsgBox(64, "", "Can't connect to FireFox!")
EndIf

Exit

Func _Example()
    _FFOpenURL('http://wolnelektury.pl/')

    _FF_EncodingFunction(_FF_Encoder1)
    Local $sObject = _FFObjGet("nav#menu>ul#user-info>li>a#login", 'QuerySAll', 0)
    Local $sOuterHTML = _FFObj($sObject, 'outerHTML')
    If @error Then ConsoleWrite('! ---> @error=' & @error & '  @extended=' & @extended & ' : QuerySelectorAll ... textContent' & @CRLF)
    MsgBox(0, "_FFCmd($sObject & '.outerHTML')", $sOuterHTML)

    If StringInStr($sOuterHTML, 'Zaloguj się') Then
        MsgBox(0, 'Zaloguj się', 'Found')
    Else
        MsgBox(0, 'Zaloguj się', 'Not Found')
    EndIf
EndFunc   ;==>_Example

 

[mLipok]

On 5.05.2017 at 11:39 PM, Danp2 said:

Not sure. You could try adding some error checking to see if that helps identify / handle the error.

Also, may want to review this article.

Is there any way to check if this following error:

On 5.05.2017 at 10:59 PM, mLipok said:

TypeError: can't access dead object

happend ?

The best way would be just by checking @error .

 

[Danp2]

12 hours ago, mLipok said:

_FF_EncodingFunction(_FF_Encoder1)

Not sure about this.  Couple of questions --

• Will this compile / run without error if _FF_Encoder1 is defined outside of the UDF?
• Couldn't this be easily resolved the writing your own custom function that wraps _FFObj and performs the desired changes?

[mLipok]

_FF_Encoder1  is only an example function name.

You could use any other == your own function to handle encoding.

_FF_EncodingFunction(_MyOwnEncodingFunction)

 

 

Edited May 8, 2017 by mLipok
typo

[mLipok]

2 hours ago, Danp2 said:

Will this compile / run without error if _FF_Encoder1 is defined outside of the UDF?

_FF_Encoder1 is not a required part of UDF, but can be as an example.

[mLipok]

On 5.05.2017 at 10:00 PM, Danp2 said:

I'm thinking about setting up a repo on Github to maintain it.

Very good decision.
 

Please also include the versions here:
https://www.autoitscript.com/forum/files/category/8-databases-and-web-connections/

As this is the main expected download place in this forum.

And of course a link to GitHub and to this support topic.

Regards,
mLipok

 

[Danp2]

Github repo can be found here.