FF.au3 (v0.6.0.1b-15) [End of life]

[Danp2]

Apparently that file doesn't have the correct layout. It probably isn't signed as well.

Try retrieving the latest version directly from Mozilla at https://addons.mozilla.org/en-US/firefox/downloads/latest/mozrepl/addon-264678-latest.xpi?src=dp-btn-primary

[mLipok]

Finally  good file.
Where/How you found this file ?
I was searching him about 2 hours.

[Danp2]

That's the URL that gets accessed when you install MozRepl from the add-on library.

[mLipok]

I see a small issue with this UDF or maybe this is intentional ?
 

Switch StringLower($sMode)
        Case "label"
            Local $RetVal = Int(_FFCmd("FFau3.SearchTab('" & $sLabel & "')", 3000))

RetVal is decalared many time inside this _FFTabExists() function

so I get:

Quote

>Running AU3Check (3.3.15.2)  params:-d -w 1 -w 2 -w 3 -w- 4 -w 5 -w 6 -w 7  from:z:\AutoItPortable\AutoIt_3_3_12_0_My  input:Z:\TOOLs\Macro\PROGRAMY\......_stripped.au3
"Z:\TOOLs\Macro\PROGRAMY\......_stripped.au3"(75083,75) : warning: $RetVal already declared/assigned
Local $RetVal = Int(_FFCmd("FFau3.SearchTabURL('" & $sLabel & "')", 3000))

It would be enough to move Local RetVal Declaration before Switch ...

Edited April 27, 2017 by mLipok

[jchd]

After a bit of discussion in MP, I can answer the issue raised by @mLipok here

The problem is that the string retrieved by the UDF is already UTF8. Writing to a file open with UTF8 flag forces AutoIt to reencode in UTF8 the individual characters of the UTF8 string. Encoding to UTF8 twice in a row makes the string gribberish.

In this case (UTF8 input) you just need to filewrite things in a file open with the BINARY flag, no UTF8 at all.

Edited April 27, 2017 by jchd
To satisfy anti-typo fascists

[mLipok]

19 hours ago, mLipok said:

I see a small issue with this UDF or maybe this is intentional ?
 

Switch StringLower($sMode)
        Case "label"
            Local $RetVal = Int(_FFCmd("FFau3.SearchTab('" & $sLabel & "')", 3000))

RetVal is decalared many time inside this _FFTabExists() function

Here is quick fix:

expandcollapse popup

Func _FFTabExists($sLabel, $sMode = "label")
    Local Const $sFuncName = "_FFTabExists"

    _FFLoadWait()

    Local $RetVal = 0
    Switch StringLower($sMode)
        Case "label"
            $RetVal = Int(_FFCmd("FFau3.SearchTab('" & $sLabel & "')", 3000))
            Switch @error
                Case $_FF_ERROR_Success
                    If $RetVal > -1 Then
                        SetExtended($RetVal)
                        Return 1
                    ElseIf $RetVal = -3 Then
                        SetError(__FFError($sFuncName, $_FF_ERROR_InvalidExpression, "$sLabel: " & $sLabel))
                        Return 0
                    Else
                        SetError(__FFError($sFuncName, $_FF_ERROR_NoMatch, "$sLabel: " & $sLabel))
                        Return 0
                    EndIf
                Case Else
                    SetError(__FFError($sFuncName, $_FF_ERROR_GeneralError))
                    Return 0
            EndSwitch
        Case "href"
            $RetVal = Int(_FFCmd("FFau3.SearchTabURL('" & $sLabel & "')", 3000))

            Switch @error
                Case $_FF_ERROR_Success
                    If $RetVal > -1 Then
                        SetExtended($RetVal)
                        Return 1
                    ElseIf $RetVal = -3 Then
                        SetError(__FFError($sFuncName, $_FF_ERROR_InvalidExpression, "$sLabel: " & $sLabel))
                        Return 0
                    Else
                        SetError(__FFError($sFuncName, $_FF_ERROR_NoMatch, "$sLabel: " & $sLabel))
                        Return 0
                    EndIf
                Case Else
                    SetError(__FFError($sFuncName, $_FF_ERROR_GeneralError))
                    Return 0
            EndSwitch

    EndSwitch
EndFunc   ;==>_FFTabExists

 

[mLipok]

How to get outer/inner HTML or Text for selected element ?

 

Edited May 4, 2017 by mLipok
typo

[mLipok]

In IE I was using:

....
$oIE_Form = _IEFormGetObjByName($oIE, 'formWynikiWyszukiwania')
$oIE_TD = _IETagNameGetCollection($oIE_Form, 'td', 0)
_IEAction($oIE_TD, 'click')
If StringInStr($oIE_Form.outerHTML, 'aria-selected=true') Then ExitLoop
....

I'm not sure how to find td inside Form using FF.au3 .
And as I ask above how to get outerHTML of element - in this case I was using $oIE_Form.outerHTML with IE.au3

Any help how to make this two things with FF.au3 ?

 

 

[mLipok]

I have some question about scripting convention used in this UDF.

Is that intentional that there are using such structure:
 

If Not @error And $RetVal = 1 Then
        Return "OBJECT|" & $sRet
    Else
        SetError(__FFError($sFuncName, $_FF_ERROR_NoMatch, "$sElement not found: " & $sElement))
        Return ""
    EndIf

Instead:
 

If Not @error And $RetVal = 1 Then  Return "OBJECT|" & $sRet
    
    SetError(__FFError($sFuncName, $_FF_ERROR_NoMatch, "$sElement not found: " & $sElement))
    Return ""

 

Edited May 4, 2017 by mLipok
typo

[mLipok]

_FFObjGet - feature proposal - querySelectorAll:

expandcollapse popup

; #FUNCTION# ===================================================================
; Name ..........: _FFObjGet
; Description ...: Returns an object (string to use with the other _FFObj* functions)
; Beschreibung ..: Liefert ein Object zurueck. (String zur Verwendung mit den anderen _FFObj* Funktionen)
; AutoIt Version : V3.3.0.0
; Syntax ........: _FFObjGet($sElement[, $sMode = "id"[, $iIndex = 0]])
; Parameter(s): .: $sElement    -
;                  $sMode       - Optional: (Default = "id") :
;                               | ID
;                               | Name + index
;                               | Class + index
;                               | Tag-name + index
;                               | QuerySAll + index
;                  $iIndex      - Optional: (Default = 0) :
; Return Value ..: Success      - String (object to use in the _FFObj* functions)
;                  Failure      - Epmty string
;                  @ERROR       -
; Author(s) .....: Thorsten Willert
; Modified ......: mLipok
; Link ..........:
; Related .......: _FFObj, _FFObjNew, _FFObjDelete, _FFClick
; Example .......: Yes
; ==============================================================================
Func _FFObjGet($sElement, $sMode = "id", $iIndex = 0)
    Local Const $sFuncName = "_FFObjGet"
    Local $sRet = ''

    Switch StringLower($sMode)
        Case "id"
            $sRet = ".getElementById('" & $sElement & "')"
        Case "name"
            $sRet = ".getElementsByName('" & $sElement & "')[" & $iIndex & "]"
        Case "class"
            $sRet = ".getElementsByClassName('" & $sElement & "')[" & $iIndex & "]"
        Case "tag"
            $sRet = ".getElementsByTagName('" & $sElement & "')[" & $iIndex & "]"
        Case "QuerySAll"
            $sRet = ".querySelectorAll('" & $sElement & "')[" & $iIndex & "]"
        Case Else
            SetError(__FFError($sFuncName, $_FF_ERROR_InvalidValue, "(id|name|class|tag) $sMode: " & $sMode))
            Return ""
    EndSwitch

    Local $RetVal = _FFCmd("window.content.document" & $sRet & "?1:0;")
    If Not @error And $RetVal = 1 Then
        Return "OBJECT|" & $sRet
    Else
        SetError(__FFError($sFuncName, $_FF_ERROR_NoMatch, "$sElement not found: " & $sElement) & "   $sMode:" & $sMode )
        Return ""
    EndIf
EndFunc   ;==>_FFObjGet

As you can see I also propose to add 

& "   $sMode:" & $sMode

in __FFError third parameter.

 

[Danp2]

Looks good to me, although I do wonder why you would need this when we already have _FFXPath.

[mLipok]

This is a matter of additive capabilities including in this UDF and partial "compatibility" with IE.au3.
The main thing is to have an easy way to move the script from one browser to another.

As I use QuerySelectorAll in my scripts based on IE.au3 so I'll be happy to use the same with FF.au3

I hope other members also will be happy

 

Edited May 4, 2017 by mLipok

[Danp2]

4 hours ago, mLipok said:

How to get outer/inner HTML or Text for selected element ?

I generally would get the inner text like this --

_FFXPath("//input[@id='yourelementid']")
$textvalue = _FFCmd("FFau3.xpath.textContent")

 

[Danp2]

4 hours ago, mLipok said:

In IE I was using:

....
$oIE_Form = _IEFormGetObjByName($oIE, 'formWynikiWyszukiwania')
$oIE_TD = _IETagNameGetCollection($oIE_Form, 'td', 0)
_IEAction($oIE_TD, 'click')
If StringInStr($oIE_Form.outerHTML, 'aria-selected=true') Then ExitLoop
....

I'm not sure how to find td inside Form using FF.au3 .
And as I ask above how to get outerHTML of element - in this case I was using $oIE_Form.outerHTML with IE.au3

Any help how to make this two things with FF.au3 ?

I would normally use _FFXPath to retrieve the desired element. Something like --

$oElement = _FFXPath( "//form[@name='formWynikiWyszukiwania']/td")
_FFClick($oElement)

 

[Danp2]

3 hours ago, mLipok said:

I have some question about scripting convention used in this UDF.

Is that intentional that there are using such structure:

They both have the same outcome, so IMO it is just the coding style of the original author. ;-)

[mLipok]

"I'm not sure how to find td inside Form using FF.au3 ."

This one I solved by my self - I use querySelectorAll

but this is still important to know: "how to get outerHTML innerHTML of element " ?

 

Edited May 4, 2017 by mLipok

[Danp2]

32 minutes ago, mLipok said:

but this is still important to know: "how to get outerHTML innerHTML of element " ?

I believe you can use the same technique as described above. IE:

_FFXPath("//input[@id='yourelementid']")
$innerHTML = _FFCmd("FFau3.xpath.innerHTML")
$outerHTML = _FFCmd("FFau3.xpath.outerHTML")

 

[mLipok]

I'll try today. 

[mLipok]

22 hours ago, Danp2 said:

I believe you can use the same technique as described above. IE:

_FFXPath("//input[@id='yourelementid']")
$innerHTML = _FFCmd("FFau3.xpath.innerHTML")
$outerHTML = _FFCmd("FFau3.xpath.outerHTML")

 

Works ok.
But why not works when I use this :

Local $sObject = _FFObjGet("nav#menu>ul#user-info>li>a#login",'QuerySAll',0)
MsgBox(0, "_FFCmd($sObject & '.outerHTML')", _FFCmd($sObject & '.outerHTML')

Do you have any idea why ?

Here is my testing scirpt:
 

#include "FF.au3"
#include <FileConstants.au3>

; trying to connect to a running FireFox with MozRepl on
If _FFConnect(Default, Default, 3000) Then
    _FFOpenURL('http://wolnelektury.pl/')

    Local $sObject = _FFObjGet("nav#menu>ul#user-info>li>a#login",'QuerySAll',0)
    MsgBox(0, "_FFCmd($sObject & '.outerHTML')", _FFCmd($sObject & '.outerHTML'))
    If @error Then ConsoleWrite('! ---> @error=' & @error & '  @extended=' & @extended & ' : QuerySelectorAll ... textContent' & @CRLF)

    Local $oElement = _FFXPath( "//nav[@id='menu']/ul[@id='user-info']/li/a[@id='login']")
    If @error Then ConsoleWrite('! ---> @error=' & @error & '  @extended=' & @extended & ' : FFXPath' & @CRLF)
    Local $sOuterHTML = _FFCmd("FFau3.xpath.outerHTML")
    ClipPut($sOuterHTML)
    MsgBox(0, '_FFCmd("FFau3.xpath.outerHTML")', $sOuterHTML)

    If _FFDisConnect() Then MsgBox(64, "", "Disconnected from FireFox!")
Else
    MsgBox(64, "", "Can't connect to FireFox!")
EndIf

 

Edited May 5, 2017 by mLipok

[Danp2]

26 minutes ago, mLipok said:

Works ok.
But why not works when I use this :

Local $sObject = _FFObjGet("nav#menu>ul#user-info>li>a#login",'QuerySAll',0)
MsgBox(0, "_FFCmd($sObject & '.outerHTML')", _FFCmd($sObject & '.outerHTML')

Do you have any idea why ?

From the online help --

Quote

_FFObjGet

---

Returns an object (string to use with the other _FFObj* functions)

So, you'll need to use _FFObj, like this --

MsgBox(0, "_FFCmd('outerHTML'", _FFObj($sObject, 'outerHTML'))