FF.au3 (v0.6.0.1b-15) [End of life]

[robertocm]

Dear All,

Just to share an example of tracking Maersk containers.

In order to test, two lines should be added in the _FFTableWriteToArray function. Because the $sMode parameter does not allow a table to be selected by the class attribute.

Case "class"
            $sTable = "//table[@class='" & $vTable & "']"

And this is the example:

#include <FF V0.6.0.1b-15.au3>
#Include <Array.au3>

If _FFStart("https://my.maerskline.com/webuser/login?", Default, 2) Then
  _FFSetValue("myusername", "textfield-1017-inputEl", "id")
  Sleep(1000)
  _FFSetValue("mypassword", "textfield-1019-inputEl", "id")
EndIf

If _FFIsConnected() Then
   Sleep(1000)
   _FFClick("button-1023-btnIconEl", "id")
   Sleep(2000)

   _FFOpenURL("https://my.maerskline.com/shipmentbinder/b/958633021/show")
   _FFLoadWait()
   Sleep(5000)

   $aTable = _FFTableWriteToArray("route-details-table", "class", "text", 13, True)
   _ArrayDisplay($aTable)
EndIf

 

[careca]

Got this line that works on firefox cmd line to change youtube video volume:

video = document.getElementsByClassName('video-stream html5-main-video')[0]; video.volume = 1

tried: _FFCmd('video = document.getElementsByClassName("video-stream html5-main-video")[0]; video.volume = 0.5')

What am i missing here?

Thanks.

[Danp2]

This seems to work fine

_FFCmd(".getElementsByClassName('video-stream html5-main-video')[0].volume = .2")

 

[careca]

Thanks for the reply, but it still doesn't work, im on ver FF V0.6.0.1b-15.au3 btw, it just puts out:

__FFSend: try{window.content.top.document.getElementsByClassName('video-stream html5-main-video')[0].volume = .2}catch(e){'_FFCmd_Err';};
__FFRecv: _FFCmd_Err

Any suggestion?

Thanks

Edited December 11, 2016 by careca

[Danp2]

You need to make sure that Youtube is the active FF tab. Otherwise, the command will fail.

[Maneesh]

hey guys, iam using "class" in _FFSetValue function and iam not getting any idea what value i should give in _FFFormSubmit(). 

please any body please provide an example code using "class" instead "id"  in _FFSetValue to fill the the online form. please

[Danp2]

Not sure that I understand the issue. Here is the English translation of the German documentation for _FFSetValue.

If that doesn't help, then please come back with a better description of the problem and some sample code to show what you've tried.

[vkrisz81]

hi guys!

i downloaded mozrepl for firefox and there is no button options or other.. i can only disable or enable, so obvious my au3 program cant connect to firefox... any idea what can i do with this? :S

or its a dead way..

[Danp2]

Look under the Tools menu item for a MozRepl submenu.

[careca]

I've been thinking, wouldn't it be nice to include a function in the udf, that would install and activate MozRepl? I see some people have trouble with it.

Or maybe just a compiled script with the xpi file, separated from the udf..

[Danp2]

There is a function named _FF_MozRepl_Detect in FFEx.au3 that will detect / install MozRepl if it's missing. However, I don't recall ever testing it so YMMV.

[Jefrey]

Here are my contribs.

1. Improved _FFClick so now it's able to click based on the CSS selector and on the text

expandcollapse popup

Func _FFClick($sElement, $sMode = "elements", $iIndex = 0, $bLoadWait = True)
    Local Const $sFuncName = "_FFClick"

    If Not IsInt($iIndex) Then
        SetError(__FFError($sFuncName, $_FF_ERROR_InvalidDataType, "(int) $iIndex: " & $iIndex))
        Return 0
    EndIf

    If $sMode = Default Then $sMode = "elements"
    If $iIndex = Default Then $iIndex = 0

    Switch StringLower($sMode)
        Case "elements"
            If StringLeft($sElement, 7) = "OBJECT|" Then $sElement = StringMid($sElement, 8)
        Case "id"
            $sElement = ".getElementById('" & $sElement & "')"
        Case "name"
            $sElement = ".getElementsByName('" & $sElement & "')[" & $iIndex & "]"
        Case "class"
            $sElement = ".getElementsByClassName('" & $sElement & "')[" & $iIndex & "]"
        Case "tag"
            $sElement = ".getElementsByTagName('" & $sElement & "')[" & $iIndex & "]"
        Case "selector"
            $sElement = ".querySelectorAll('" & $sElement & "')[" & $iIndex & "]"
        Case "text"
            $sElement = ".evaluate(""//*[contains(text(), '" & $sElement & "')]"", document, null, XPathResult.FIRST_ORDERED_NODE_TYPE, null).singleNodeValue;"
        Case Else
            SetError(__FFError($sFuncName, $_FF_ERROR_InvalidValue, "(elements|id|name|class|tag) $sMode: " & $sMode))
            Return 0
    EndSwitch

    If StringLeft($sElement, 1) = "." Then $sElement = "FFau3.WCD" & $sElement

    Local $RetVal = _FFCmd("FFau3.simulateEvent(" & $sElement & ",'MouseEvents','click');")
    If Not @error And $RetVal <> "_FFCmd_Err" And $RetVal = 1 Then
        Sleep(25)
        If $bLoadWait Then Return _FFLoadWait()
        __FFSetTopDocument()
        Return 1
    Else
        SetError(__FFError($sFuncName, $_FF_ERROR_NoMatch, "$sElement: " & $sElement))
        Return 0
    EndIf

EndFunc

Examples:

_FFClick(".menu a.menuitem", "selector", 0)
_FFClick("Search", "text")

2. Added proxy changing support

Func _FFSetProxy($host, $port, $type)
    _FFUnSetProxy()
    _FFPrefSet("network.proxy.type",1)
    If $type = "http" Then
        _FFPrefSet("network.proxy.http", $host) ; http proxy
        _FFPrefSet("network.proxy.http_port", Int($port)) ; http proxy port
    ElseIf $type = "socks5" Then
        _FFPrefSet("network.proxy.socks" ,$host) ; socks
        _FFPrefSet("network.proxy.socks_port", Int($port)) ; socks port
        _FFPrefSet("network.proxy.socks_version", 5) ; socks version
    ElseIf $type = "socks4" Then
        _FFPrefSet("network.proxy.socks" ,$host) ; socks
        _FFPrefSet("network.proxy.socks_port", Int($port)) ; socks port
        _FFPrefSet("network.proxy.socks_version", 4) ; socks version
    EndIf
EndFunc

Func _FFUnSetProxy()
    _FFPrefReset("network.proxy.type")
    _FFPrefReset("network.proxy.http")
    _FFPrefReset("network.proxy.http_port")
    _FFPrefReset("network.proxy.socks")
    _FFPrefReset("network.proxy.socks_port")
    _FFPrefReset("network.proxy.socks_version")
EndFunc

Example:

_FFSetProxy("localhost", 8080, "socks5") ; socks5 proxy (i.e.: Tor and Putty/SSH)
_FFSetProxy("localhost", 8080, "socks4") ; socks4 proxy
_FFSetProxy("localhost", 8080, "http") ; http proxy
_FFUnSetProxy() ; reset to defaults

3. Fixed _FFStart() not finding Firefox executable in some machines

The UDF was not findind Firefox if the user installed a x86 version on a x64 OS. This function will take care on this:

expandcollapse popup

Func __FFStartProcess($sURL = "about:blank", $bNewWin = False, $sProfile = "default", $bNoRemote = False, $bHide = False, $iPort = 4242, $iTimeOut = 30000)
    Local Const $sFuncName = "__FFStartProcess"

    Local $PID = -1
    Local $sNoRemote = "", $sNewWin
    Local $sProcName = $_FF_PROC_NAME

    If $sProfile = "default" Then
        $sProfile = ''
    Else
        $sProfile = ' -P "' & $sProfile & '"'
    EndIf
    If $bNoRemote Then $sNoRemote = "-no-remote"
    If $bNewWin Then $sNewWin = "-new-window"
    $sURL = '"' & $sURL & '"'
    If $iTimeOut < 2000 Then $iTimeOut = 2000


    ;Local $sHKLM = 'HKEY_LOCAL_MACHINE\SOFTWARE\'
       ;If @OSArch <> 'X86' Then $sHKLM &= 'Wow6432Node\'
       ;$sHKLM &= 'Mozilla\Mozilla Firefox'
       ;Local $sFFExe = RegRead($sHKLM & "\" & RegRead($sHKLM, "CurrentVersion") & "\Main", "PathToExe")

       #Region detect FF exe
       ; try to read x32 first
       Local $sHKLM = 'HKEY_LOCAL_MACHINE\SOFTWARE\Mozilla\Mozilla Firefox'
       Local $sFFExe = RegRead($sHKLM & "\" & RegRead($sHKLM, "CurrentVersion") & "\Main", "PathToExe")

       If @error Then
           ; try to read amd64
            Local $sHKLM = 'HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Mozilla\Mozilla Firefox'
            Local $sFFExe = RegRead($sHKLM & "\" & RegRead($sHKLM, "CurrentVersion") & "\Main", "PathToExe")
        EndIf
       #EndRegion

       If @error Then
       SetError(__FFError($sFuncName, $_FF_ERROR_GeneralError, "Error reading registry entry for FireFox." & @CRLF & _
        $sHKLM&"\*CurrentVersion*\Main\PathToExe" & @CRLF & _
        "Error from RegRead: " & @error))
        Return 0
       EndIf

    ; Updated per http://www.autoitscript.com/forum/topic/95595-ffau3-v0600b/page__st__380#entry958812
    ;Local $sCommand = StringFormat('"%s" %s %s %s "-repl %i %s"', $sFFExe, $sNewWin, $sURL, $sNoRemote, $iPort, $sProfile)
    ;$sCommand = StringFormat('"%s" %s %s %s -repl %i %s', $sFFExe, $sNewWin, $sURL, $sNoRemote, $iPort, $sProfile)
    ; UpdTED per http://www.kohberg.net/cms/pages/posts/autoit-ff.au3-oeffnet-immer-4242.com-beim-aufrufen-111.php
    Local $sCommand = StringFormat('"%s" %s %s %s -repl %s', $sFFExe, $sNewWin, $sURL, $sNoRemote, $sProfile)

    $PID = Run($sCommand)
    If $bHide Then BlockInput(1)

    Local $iTimeOutTimer = TimerInit()
    While 1
        Sleep(2000)
        If ProcessExists($sProcName) Then ExitLoop
        If (TimerDiff($iTimeOutTimer) > $iTimeOut) Then
            SetError(__FFError($sFuncName, $_FF_ERROR_Timeout, "Browser process not exists: " & $sProcName))
            BlockInput(0)
            Return 0
        EndIf
    WEnd

    If $bHide Then
        Local $WINTITLE_MATCH_MODE = AutoItSetOption("WinTitleMatchMode", 4)
        WinWaitActive("[CLASS:MozillaWindowClass]")
        Sleep(500)
        WinSetState("[CLASS:MozillaWindowClass]", "", @SW_MINIMIZE)
        BlockInput(0)
        AutoItSetOption("WinTitleMatchMode", $WINTITLE_MATCH_MODE)
    Else
        Sleep(1000)
    EndIf

    If $_FF_COM_TRACE Then _consolewrite('__FFStartProcess: "' & $sCommand & @CRLF)

    SetExtended($PID)
    Return 1
EndFunc   ;==>__FFStartProcess

Perhaps we should go to Github 

[careca]

nice one! will this be added to the udf?

[Stilgar]

Sorry for the long downtime.

Can anyone tell me what's the difference between my current version 0.6.0.2b and all the functions here in the forum?

[Danp2]

16 minutes ago, Stilgar said:

Sorry for the long downtime.

Can anyone tell me what's the difference between my current version 0.6.0.2b and all the functions here in the forum?

Generally, minor fixes / enhancements. I'd be happy to work with you to identify the changes.

[Jefrey]

Perhaps we should go to Github? 

Is it ok for the original author? Would he want to create the repo so we could PR?

[mLipok]

So far I had no need to seriously use this UDF.
However, this has changed.
I need to use FF UDF in one of my projects.
Defacto I have to migrate from IE to FF in this particular project.

For now, I have only one short question, is here available any list , presenting equivalents for function names in FF with relation to IE

something like:
_IECreate >> _FF....
_IEAttach >> _FF....
_IEAction >> _FF....
.......

 

or:

_FF... >> _IE....

 

Regards
mLipok

 

Edited April 20, 2017 by mLipok

[Guy_]

I've been testing the simple ...

$sVar = _FFAction("copy")

a few times to copy a simple active text selection...

Often it seems to be copying "other stuff" on the back of it?

(1) Am I understanding this function wrongly? Not interesting as a more reliable Ctrl+c substitute?

(2) Why the Delimiter parameter? Is that in case you select multiple form fields, and it will then separate the contents with the delimiter?

(3) Does anyone know if you can get just the 'View Selection Source' (Firefox context menu) data from a selected piece of text into a variable? (I know you can get the *full* source)

Edited April 20, 2017 by Guy_

[Danp2]

2 hours ago, mLipok said:

 is here available any list , presenting equivalents for function names in FF with relation to IE

Not that I'm aware of. The English docs can be found here.

[Danp2]

2 hours ago, Guy_ said:

(2) Why the Delimiter parameter? Is that in case you select multiple form fields, and it will then separate the contents with the delimiter?

I took a quick look at the code, but I don't see where this parameter is even used.