How to add colon every 2 characters in string

[charon]

I am trying to turn this "00204070F48F" into this: "00:20:40:70:F4:8F". I thought I could use _StringInsert but doesn't seem to be working

#include <MsgBoxConstants.au3>
#include <String.au3>

;turn this "00204070F48F" into this: "00:20:40:70:F4:8F"
$x = "00204070F48F"
$StrLen = StringLen($x)
$sInsertString = ":"
$pos = 2

DIM $results[6]
For $i = 0 To 4
    $results[$i] = _StringInsert ( $x, $sInsertString, $pos )
    $pos = $pos + 2
    msgbox(0, "", $results[$i])
Next

[water]

Something like this:

#include <MsgBoxConstants.au3>
#include <String.au3>

;turn this "00204070F48F" into this: "00:20:40:70:F4:8F"
Global $sX = "00204070F48F"
Global $sResult, $iPos = 2, $sInsertString = ":"
For $i = 0 To 6
    $sResult = $sResult & StringMid($sX, $i * 2 + 1, 2) & $sInsertString
Next
$sResult = StringLeft($sResult, 17)
MsgBox(0, "", $sResult)

[Rockerfeller]

#include <String.au3>

$x = "00204070F48F"
$sInsertString = ":"

For $i = 10 To 2 Step -2
    $x = _StringInsert($x, $sInsertString, $i)
Next
MsgBox(0, "", $x)

Edited February 22, 2015 by Rockerfeller

[water]

I'm sure some RegExp gurus will chime in with a one-liner

[kylomas]

and yet another...

local $str = '00204070F48F'
ConsoleWrite(stringtrimright(stringregexpreplace($str,'(.{2})','$1:'),1) & @CRLF)

[water]

Ahh ... here they are

[mikell]

Obviously  

$str = '00204070F48F' 
MsgBox(0, "", StringRegExpReplace($str, "..\K(?!$)", ":") )

[kylomas]

and again...

local $aTmp = stringsplit($str,'',2), $out
for $1 = 0 to ubound($aTmp) - 1
    $out &= ( mod($1,2) ? $aTmp[$1] & ':' : $aTmp[$1])
Next

if stringright($out,1) = ':' then $out = stringtrimright($out,1)

ConsoleWrite($out & @CRLF)

[kylomas]

Hey mikell, I might be getting the hang of this Klingon...

local $str = '00204070F48F'
ConsoleWrite(stringregexpreplace($str,'(.{2})(?!$)','$1:') & @CRLF)

[mikell]

Nice  

StringRegExpReplace($str, "..(?!$)", "$0:")

But the code in post #7 is better because you get rid of backreferences 

Edited February 22, 2015 by mikell

[SadBunny]

Another way, a variant on kylomas' solution but with a positive lookahead assertion. Can't top mikell's solution in terms of leetness though.

$x = StringRegExpReplace($str, "(..)(?=.)", "$1:")

Edited February 22, 2015 by SadBunny

[SadBunny]

Or like this, with a recursive function and a shorthand if:

$str = fix('00204070F48F')

ConsoleWrite($str & @CRLF)

Func fix($x)
    Return StringLen($x) == 2 ? $x : StringLeft($x, 2) & ":" & fix(StringMid($x, 3))
EndFunc