question about listview item identification!

[Celtic88]

How Do I Determine the index Item by Control Id of a ListView ? 

 

this is my way 

 

func _Find_ItemIndexbyCtrlid($sCtrlid)
For $i = 0 To _GUICtrlListView_GetItemCount($hlv) - 1
    _GUICtrlListView_GetItemParam($hlv, $i) if $sCtrlid then return $i
Next
endfunc

that there is another solution and thank you for your work

[Melba23]

FinishHim,

I would do it like this:

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <GuiListView.au3>

$hGUI = GUICreate("Test", 500, 500)

$cLV = GUICtrlCreateListView("Items", 10, 10, 400, 400)
For $i = 0 To 19
    GUICtrlCreateListViewItem("Item " & $i, $cLV)
Next

$cRead = GUICtrlCreateButton("Get Index", 10, 450, 80, 30)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cRead
            $cID = GUICtrlRead($cLV)
            $iIndex = _GUICtrlListView_FindParam($cLV, $cID) ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
            MsgBox($MB_SYSTEMMODAL, "Selected", "Index = " & $iIndex)
    EndSwitch
WEnd

M23

[Celtic88]

ahhh "_GUICtrlListView_FindParam" I have not seen this function 1000 thank you @Melba23