Input placeholder instead of raw text

[Glutch]

Hello!

I'm trying to figure out how to get a placeholder instead of raw text on the Koda inputs.

'>
$key = GUICtrlCreateInput("Keys to press (optional)", 16, 160, 145, 21)

I dont want the text to stay in the box if i click inside it. I want a solution like this in html: <input type="text" placeholder="Keys to press (optional)"/>

Would greatly appreciate some advice

[UEZ]

You can do something like this here:

 

 

#Include <GUIConstantsEx.au3>
#include <EditConstants.au3>
#include <WindowsConstants.au3>

$hGUI = GUICreate("Test", 300, 200)
$iLabel = GUICtrlCreateLabel("Test", 10, 10)
$iBtn = GUICtrlCreateButton("Exit", 200, 100, 60, 60)
$key = GUICtrlCreateInput("Keys to press (optional)", 16, 160, 145, 21)
ControlFocus($hGUI, "", $iLabel)
GUISetState()

GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

Do
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE, $iBtn
            GUIDelete()
            Exit
    EndSwitch
Until False

Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    Switch $hWnd
        Case $hGUI
            Switch BitAND($wParam, 0xFFFF)
                Case $key
                    Switch BitShift($wParam, 16)
                        Case $EN_KILLFOCUS
                            If GUICtrlRead($key) = "" Then GUICtrlSetData($key, "Keys to press (optional)")
                        Case $EN_SETFOCUS
                            If GUICtrlRead($key) = "Keys to press (optional)" Then GUICtrlSetData($key, "")
                    EndSwitch
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND

 

 

Br,

UEZ

[Glutch]

Oh... That was a tedious solution. I'll probably put a label above the input instead.
Thanks for the help though!

PS: Koda should implement this feature

[Melba23]

Glutch (and UEZ),

No need to be quite so complicated - use a cuebanner:

#include <GUIConstantsEX.au3>
#include <EditConstants.au3>

$hGui = GUICreate("", 500, 500)

$cInput = GUICtrlCreateInput("", 10, 10, 200, 20)
GUICtrlSendMsg($cInput, $EM_SETCUEBANNER, False, "Keys to press (optional)")

$cButton = GUICtrlCreateButton("Test", 10, 100, 80, 30)
GUICtrlSetState($cButton, $GUI_FOCUS)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

I hope that helps.

M23

[UEZ]

Indeed, I forgot about cuebanner...

Br,

UEZ

[Loc]

Looks like using Style $ ES_READONLY it cannot be displayed. Is there any way?

@Melba23

Edited February 2, 2021 by Loc

[Nine]

$cInput = GUICtrlCreateInput("Text you want here", 10, 10, 200, 20, $ES_READONLY)

?

[Melba23]

MrRow,

The cuebanner is designed to vanish when text is entered. If you cannot enter any text then why do you need a cuebanner? Just use a label instead.

M23

[Deathdn]

_GUICtrlEdit_SetCueBanner(-1, "placeholder", True) ; placeholder

How about it?

[Andreik]

How about not grave digging old threads without adding any real value? Sending EM_SETCUEBANNER to input control has been already suggested.