How to make a toggle button? - I'm newbie :C

[Shikuri]

Hello guys.

I want to make toggle button C(ON/OFF), but im totally green there.

[JLogan3o13]

Did you try searching the forum?? A simple search of toggle button or on/off button returns a number of threads.

[Melba23]

Shikuri,

Welcome to the AutoIt forums.

You could do it like this:

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <ButtonConstants.au3>

$hGUI = GUICreate("Test", 500, 500)

$cButton = GUICtrlCreateCheckbox("On", 10, 10, 80, 30, $BS_PUSHLIKE)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cButton
            Switch GUICtrlRead($cButton)
                Case $GUI_CHECKED
                    GUICtrlSetData($cButton, "Off")
                    MsgBox($MB_SYSTEMMODAL, "Button", "ON")
                Case Else
                    GUICtrlSetData($cButton, "On")
                    MsgBox($MB_SYSTEMMODAL, "Button", "OFF")
            EndSwitch
    EndSwitch
WEnd

As you are a complete beginner to AutoIt (and we all were at one point, so no problem at all) reading the Help file (at least the first few sections - Using AutoIt, Tutorials and the first couple of References) will help you enormously. You should also look at this excellent tutorial - you will find other tutorials in the Wiki (the link is at the top of the page).

M23

[Cynagen]

M23, I'm assuming because they admit they're new you didn't want to blow their mind with a Ternary setup?

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <ButtonConstants.au3>

$hGUI = GUICreate("Test", 500, 500)

$cButton = GUICtrlCreateCheckbox("OFF", 10, 10, 80, 30, $BS_PUSHLIKE)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cButton
            GUICtrlSetData($cButton,(GUICtrlRead($cButton) = $GUI_CHECKED) ? "ON" : "OFF")
    EndSwitch
WEnd

[Melba23]

Cynagen,

Not entirely - my suggested solution also allows for other code to be run when the button is actioned. Whereas merely allowing the script to rename the button makes the whole thing a bit of a "self-licking lollipop".

M23

[SadBunny]

Cynagen,

Not entirely - my suggested solution also allows for other code to be run when the button is actioned. Whereas merely allowing the script to rename the button makes the whole thing a bit of a "self-licking lollipop".

M23

 

?

[Cynagen]

Cynagen,

Not entirely - my suggested solution also allows for other code to be run when the button is actioned. Whereas merely allowing the script to rename the button makes the whole thing a bit of a "self-licking lollipop".

M23

 

I get that M23, you can still include an IF afterwards, it's just switching the button's display can be a simple 1-liner with the way I've done mine.

?

 

What M23 means by "self-licking lollipop" is that my code does nothing more than actually change the button text (which is what the user was originally asking for) in the simplest means using a Ternary operation. M23's breaks down what mine does into the basics (Ternary operations are effectively self-contained IF statements) for how it actually works on the inside and allows for extra code to be inserted to react to the change not only visually but with any other code that is inserted into the IF statement. For somebody just learning AutoIt, mine is pretty and takes care of the visuals, but doesn't address how you want the button to react, M23's does. I just like to minimize the amount of code I actually write to do something is all.

Edited February 12, 2015 by Cynagen