Replace text that does not match a givin RegExp

[EKY32]

Hello, I have a text that I need to do some replacment to it's characters, lets say I need to replace the dashes "-" with spaces, but I do not want the dashes inside the anchor tag to be replaced, only the ones outside it.

$text = "here is the link http://www.my-li-nk.com that should stay as is, and here are-the-dashes-that-need-to-be replaced with spaces"

I've previously used >somoke_n's code to identify the anchor tag.

Func _replaceURLWithHTMLLinks($sText)
    Local Const $sExp = "(?i)(\b(https?|ftp|file):\/\/[-A-Z0-9+&@#\/%?=~_|!:,.;]*[-A-Z0-9+&@#\/%=~_|])"
    Return StringRegExpReplace($sText, $sExp, "<a href='$1'>$1</a>")
EndFunc

Thanks in advance.

Edited January 26, 2015 by EKY32

[Valuater]

$split = stringsplit( $string, ".com")

Stringreplace($split[0], "-", " ")

for $x = 1 to $split[0] -1

$newstring &= $spli[$x]

next

msgbox(0,0,$newstring)

---------------------------------------------

written on screen... not testd... but you gat the idea

8) 

[EKY32]

Thanks, I don't think this helps in my situation, In fact, I do not know the real URL, I'm filtering a long amount of text, converting the plain text URLs to real HTML coded ones, and then replace some other characters (like smiles for example..) with image codes .. so I do not want the smile filtering function to approach to the URLs and replace any of their text.

Thanks.

Edited January 26, 2015 by EKY32

[SmOke_N]

1.  get an array of urls with regex

2.  replace urls with unique strings that also represent the index of the url in your array

3.  replace all the characters you need to

4.  replace the unique strings with the array of urls based on index

[Melba23]

EKY32.

How about this:

$sFiller = "###"

$sText = "here is the link http://www.my-li-nk.com that should stay as is, and here are-the-dashes-that-need-to-be replaced with spaces"

; Extract the link
$sExtract = StringRegExpReplace($sText, "^.*(http\S*)\s.*$", "$1")

; Replace the link by the filler, get rid of the dashes and then replace the link
$sNewText = StringReplace(StringReplace(StringReplace($sText, $sExtract, $sFiller), "-", " "), $sFiller, $sExtract)

ConsoleWrite($sNewText & @CRLF)

M23

[jguinch]

SmOke_N's way can be something like this :

#Include <Array.au3> ; just for _ArrayDisplay

$text = "here is the link http://www.my-li-nk.com that should stay as is, and here are-the-dashes-that-need-to-be replaced with spaces."

; Extract all links
$aLinks = StringRegExp($text, "(?i)(\b(?:https?|ftp|file):\/\/[-A-Z0-9+&@#\/%?=~_|!:,.;]*[-A-Z0-9+&@#\/%=~_|])", 3)
_ArrayDisplay($aLinks, "All links") 

; Replace all links by a mark : <link{x}>
For $i = 0 To UBound($aLinks) - 1
    $text = StringReplace($text, $aLinks[$i], "<link{" & $i & "}>", 1)
Next
ConsoleWrite($text & @CRLF)

; replace all dashes between two words by a blank
$text = StringRegExpReplace($text, "(?<=\w)-(\w+)", " $1")
ConsoleWrite($text & @CRLF)

; Replace each mark by its variable name
$text = StringReplace($text, '"', '""')
$text = StringRegExpReplace('"' & $text & '"', "<link\{(\d+)\}>", '" & \$aLinks[$1] & "')
ConsoleWrite($text & @CRLF)

; Replace each variable by its value
$text = Execute($text)
ConsoleWrite($text & @CRLF)

[EKY32]

You people are all geniuses, i'm very thankful to all of you. All the methods worked fine but the one jguinch posted was perfect to my need.

Thank you all again.

[Malkey]

And another one.

Local $sText = "here is the link http://www.my-li-nk.com and another http://www.his-li-nk.com that should stay as is, and here are-the-dashes-that-need-to-be replaced with spaces"

Local $sStr = '"' & StringRegExpReplace($sText, "([\w.,/:]+(?:\-[\w.,/:-]+))", '" & (StringRegExp("${1}","^http") ? "${1}" : (StringRegExpReplace("${1}","-"," ")))  & "') & '"'

;ConsoleWrite($sStr & @LF)
ConsoleWrite(Execute($sStr) & @LF)

[jguinch]

Nice use of the ternary operator in an Execute sequence...