Natural Sort Order (StrCmpLogicalW) Call Help

[kylomas]

I am trying to call StrCmpLogicalW which compares strings in what some people call "natural sort order".  This means that the numeric portion of a string is compared seperately from the alpha portion.  This is useful for sorting filename lists.  However, I am not getting the results that I expect.

This is the MS doc for StrCmpLogicalW.  This function wants pointers to null terminated unicode strings for input.  The following code is my attempt at that but is returning invalid comparisons.

#include <array.au3>

local $SHLWapi = dllopen('shlwapi.dll'), $rslt, $aFL = ['File50','File10','File12','File38','File00100','File001']

for $1 = 0 to ubound($aFL) - 2

    $rslt = LC($aFL[$1],$aFL[$1+1])
    ConsoleWrite(stringformat('%-15s %3s %-15s', _
                    $aFL[$1], _
                    $rslt, _
                    $aFL[$1+1]) _
                    & @CRLF & @CRLF)

next

dllclose($SHLWapi)

func LC($str1, $str2)

    local $tagLC = DllStructCreate('char S1[1024];char S2[1024]')
    dllstructsetdata($tagLC,'S1',$str1)
    dllstructsetdata($tagLC,'S2',$str2)

    ConsoleWrite($tagLC.S1 & ' is being compared to ' & $tagLC.S2 & @CRLF)

    Local $Ret = DllCall($SHLWapi, 'int', 'StrCmpLogicalW', 'ptr', DllStructGetPtr($tagLC,'S1'), 'ptr', DllStructGetPtr($tagLC,'S2'))
    return (@error) ? msgbox(0,'ERROR','Error returned from DLLCall = ' & $Ret) : $Ret[0]

endfunc

I am suspicious of the way I am setting up the structure and pointing to each element in the function call.

kylomas 

 

[jguinch]

Why not Local $Ret = DllCall($SHLWapi, 'int', 'StrCmpLogicalW', 'wstr', $str1, 'wstr', $str2) ? (i'm not very familiar with this but it seems to work...)

[BrewManNH]

You can change that or change the DLLStructCreate line to this:

Local $tagLC = DllStructCreate('wchar S1[1024];wchar S2[1024]')

If you want to use Unicode strings, use Unicode data types in your structs and your DLLCalls.

Edited January 21, 2015 by BrewManNH

[kylomas]

Thanks guys, that works so far.

[guinness]

Shouldn't that 1024 be StringLen(var) + 1?

[kylomas]

Yes, I am just getting past the "does it even do what I think it does" part.

[Malkey]

Using the actual strings to be compared in the export function appears to work even though msdn says the parameters of "StrCmpLogicalW" are pointers to a null-terminated string.

; See 'StrCmpLogicalW'  https://msdn.microsoft.com/en-us/library/windows/desktop/bb759947%28v=vs.85%29.aspx
#include <array.au3>

Local $aFL = ["3string", "2string", "20string", "st3ring", "st2ring", "st20ring", "string3", "string2", "string20"]

_ArraySort1D($aFL, 1, 1) ; Sort array ascending, recognise digits in string elements
_ArrayDisplay($aFL, "Ascend, Digits")

_ArraySort1D($aFL, 1, 0) ; Sort array ascending, recognise all characters as string.
_ArrayDisplay($aFL, "Ascend, String Only")


; Sort a one dimensional array
; Default parameters all zero for descending, string only.
Func _ArraySort1D(ByRef $aArray, $iAsc = 0, $iDigits = 0)
    Local $SHLWapi = DllOpen('shlwapi.dll'), $Temp, $Flag = 0
    Do
        $Flag = 0
        For $i = 0 To UBound($aArray) - 2
            If (($iAsc = 0 And ($aArray[$i] < $aArray[$i + 1]) And $iDigits = 0) Or _          ; Sort strings, descending
                ($iAsc = 1 And ($aArray[$i] > $aArray[$i + 1]) And $iDigits = 0) Or _          ; Sort strings, ascending
                ($iAsc = 0 And (DllCall($SHLWapi, 'int', 'StrCmpLogicalW', 'wstr', $aArray[$i], 'wstr', $aArray[$i + 1])[0] = -1) And $iDigits = 1) Or _  ; Sort strings with digits in the strings considered as numerical content rather than text, descending.
                ($iAsc = 1 And (DllCall($SHLWapi, 'int', 'StrCmpLogicalW', 'wstr', $aArray[$i], 'wstr', $aArray[$i + 1])[0] = 1) And $iDigits = 1)) Then ; Sort strings with digits in the strings considered as numerical content rather than text, ascending.
                ; Swap routine
                $Temp = $aArray[$i + 1]
                $aArray[$i + 1] = $aArray[$i]
                $aArray[$i] = $Temp
                $Flag = 1
            EndIf
        Next
    Until $Flag = 0
    DllClose($SHLWapi)
EndFunc   ;==>_ArraySortiD

Edited January 22, 2015 by Malkey

[kylomas]

Yes, that's exactly where I've been going with this.  @jguinch - appears you are right about calling with the strings directly.  Looking at how to incorporate this to a quick sort algorithm.  The bubble (insertion) sort is too slow.

If someone knows how this QSort thing works feel free to jump in.  This seems like it might be a good candidate for a UDF based on recent demand in GH&S.

edit: The doc seems to make a point of using "null terminated strings".  As opposed to what?  And how do you know if the string is null terminated?

Edited January 22, 2015 by kylomas

[SmOke_N]

All of autoit "strings" are null terminated (essentially c-strings (array of characters with a null terminator)), meaning they stop at the first chr(0).

Local $sStr = "apple"

Local $sStr2 = "ap" & Chr(0) & "ple"

You will get "apple" for $sStr 1, where the null char is at the end of the string and "ap" for $sStr2.

Essentially, when working with pointers, you can return a value that doesn't have a null char.

[guinness]

OK. Didn't really test this in the past. Good to know.

#include <Array.au3>

Local $sStr = "apple"
Local $sStr2 = "ap" & Chr(0) & "ple"
ConsoleWrite($sStr2)
ConsoleWrite(@CRLF)
ConsoleWrite(StringLen($sStr2) & @CRLF)
_ArrayDisplay(StringToASCIIArray($sStr2)) ; I wouldn't have expected this.