global variable or function?

[Melba23]

gil900,

Au3Check errors on that snippet, but the interpreter will not as you are merely redeclaring a variable that already exists in the same scope.

You can rewrite it thus:

SomeFunc()
Func SomeFunc()
    Local $var = 1 ; Declare AND assign a Local variable
    Local $var ; Declare a Local variable - but it is already declared and so the line has no effect
    ConsoleWrite($var & @CRLF) ; As the variable has been declared and assigned the value is shown
EndFunc
MsgBox(0,'','WORKING!!')

M23

[Guest]

I'm still surprised that $var did not changed to '' in Local $var

This is new information for me.
I thought in the past this:

Global $var = 1
Global $var
ConsoleWrite($var&@CRLF)

Will print '' but it is not.

So in order to clean the data in $var I must to Assign to it '' or 0.

This is something new to me and this is important information

[Melba23]

gil900,

 

So in order to clean the data in $var I must to Assign to it '' or 0.

That is what "assign" means.

M23

Edited January 19, 2015 by Melba23
Typo

[TheSaint]

I know I'm probably pushing the limits of patience here, but please bear with me.

Scenario

[1] I declare a lot of variables Globally at the top of my script, but with no values set in them yet.

[2] If I use one of those variables to hold a significant amount of data (i.e. a file read), then clear it after use, and the rest of my variables are treated the same or only hold a number or a word (i.e. something small), then how much of an imposition am I imposing on memory? Is it significant enough to be an issue?

[3] Many of the variables I declare, are just controls anyway, and cannot be avoided for the life of the script.

[4] I'm in the habit of setting a control state to a variable, rather than having to use GuiCtrlRead or GuiCtrlGetSate all the time, which if for no other reason just looks ugly and more complex (and more code text), and requires more brain power when troubleshooting, if nested.

Edited January 19, 2015 by TheSaint

[guinness]

That still doesn't solve the issue, because an "empty" string still takes up space e.g. 2 bytes, whereas a variable that is destroyed once out of scope takes up 0 bytes,

I think you need to fully understand what we mean when we say "lowest possible scope", because declaring "a lot of global variables" is not the correct approach to coding. I really don't want to get into the internals of AutoIt to fully validate the point that czardas and I are trying to make, as this is something which shouldn't be taken into consideration by the end developer.

[Guest]

gil900,

 

That is what "assign" means.

M23

 

Why no one thought to invent something more elegant. for me it look better

Global $aArray[10000000]
MsgBox(0,'','') ; This take 43MB memory
CleanVar($aArray) ; Now if we want to clean the var, we use this
MsgBox(0,'','') ; Now it take about 4MB memory


; #FUNCTION# ====================================================================================================================
; Name ..........: CleanVar
; Description ...: Instead of using the ugly method - $var = '' in order to clean variable, you can use CleanVar($var)
; Syntax ........: CleanVar(Byref $var)
; Parameters ....: $var                 - [in/out] The variable to clean.
; Return values .: None
; Author ........: gil900
; Example .......: Yes
; ===============================================================================================================================
Func CleanVar(ByRef $var)
    $var = ''
EndFunc

[guinness]

That's just really unnecessary, as you've introduced three additional lines code for a function call that does what exactly? Something that can be done in one likes and is obvious to most. You also missed my point about one variable per datatype, so $var holds a string?

[Guest]

That's just really unnecessary, as you've introduced three additional lines code for a function call that does what exactly? Something that can be done in one likes and is obvious to most. You also missed my point about one variable per datatype, so $var holds a string?

 

 

You're right.

But it was good if it was an internal function or something like that.

 

 

for a function call that does what exactly?

Makes it easier to understand and it looks better

You also missed my point about one variable per datatype, so $var holds a string?

The goal is to clear memory and the string does it well. but i have not checked if 0 uses less memory.

What uses less memory? 0 or "" ?

Edited January 19, 2015 by Guest

[czardas]

[2] If I use one of those variables to hold a significant amount of data (i.e. a file read), then clear it after use, and the rest of my variables are treated the same or only hold a number or a word (i.e. something small), then how much of an imposition am I imposing on memory? Is it significant enough to be an issue?

 

Probably not so much in most cases.

[3] Many of the variables I declare, are just controls anyway, and cannot be avoided for the life of the script.

 

I tend to dump all controls into arrays which I pass as ByRef parameters to various functions which read and modify the controls. Controls can be created in local scope so that when you destroy a GUI, such as a child window, you can get out of that part of the script and all the associated variables will dissapear after returning from the function - back to the main script. This is one of several possible ways.

[4] I'm in the habit of setting a control state to a variable, rather than having to use GuiCtrlRead or GuiCtrlGetSate all the time, which if for no other reason just looks ugly and more complex (and more code text), and requires more brain power when troubleshooting, if nested.

 

For a one off event, I think it's okay to omit the variable if it does not compromise readability. In most cases the same variable will be used again and it will frequently make sense to keep the data in memory.

Edited January 19, 2015 by czardas

[guinness]

 

The goal is to clear memory and the string does it well. but i have not checked if 0 uses less memory.

What uses less memory? 0 or "" ?

 

This is not about AutoIt now, but in general an integer is 32 bits long and a byte is 4 bits long, so 8 bits for the empty string.

[TheSaint]

That still doesn't solve the issue, because an "empty" string still takes up space e.g. 2 bytes, whereas a variable that is destroyed once out of scope takes up 0 bytes,

I think you need to fully understand what we mean when we say "lowest possible scope", because declaring "a lot of global variables" is not the correct approach to coding. I really don't want to get into the internals of AutoIt to fully validate the point that czardas and I are trying to make, as this is something which shouldn't be taken into consideration by the end developer.

I already understand most of that, but I don't feel you answered my question fully.

In a way, I'm asking how many bytes are too many?

Probably not what you want to answer though, and I understand, you want me to do best practice regardless.

My wife wants me to do a lot of things too.

Always the rebel me.

[guinness]

I don't in AutoIt due to possible optimisation, but see post above yours for standard values.

Edit: Spelling. Was in a rush today.

Edited January 19, 2015 by guinness

[guinness]

TheSaint,

 

This demonstrates using the latest version of AutoIt, what we have been talking about. You might want a Global variable when you have a filehandle open, but then people could argue even this can be done without a global variable, which they would be right in saying.

 

expandcollapse popup

#include <File.au3>
#include <StringConstants.au3>

Global $g_sSomeBigString = "" ; As this is only used in the Example function, why is it declared here?
Global $g_hFile = FileOpen(_TempFile(), BitOR($FO_READ, $FO_OVERWRITE)) ; This is okay, as it's referenced in more than one place.

OnAutoItExitRegister(OnClose) ; Register a function to call on AutoIt exit.

Example()
Write()
ReadAndReplace()

Func Example()
    ; $g_sSomeBigString should be called $sSomeBigString and declared using Local.
    For $i = 0 To 100
        $g_sSomeBigString &= String($i)
    Next
    ConsoleWrite($g_sSomeBigString & @CRLF) ; Since this is only used here.
    Return Null ; Like void.
EndFunc   ;==>Example

Func OnClose()
    FileClose($g_hFile) ; Tidy resources on exit.
    Return Null ; Like void.
EndFunc   ;==>OnClose

Func ReadAndReplace()
    FileSetPos($g_hFile, 0, $FILE_BEGIN)
    Local $sFileRead = FileRead($g_hFile) ; Assign to a local variable.
    FileSetPos($g_hFile, 0, $FILE_BEGIN)

    $sFileRead = StringReplace($sFileRead, "1", "", 0, $STR_NOCASESENSE) ; Manipulate the data in the variable.
    ConsoleWrite($sFileRead & @CRLF)
    $sFileRead = "" ; Pointless as this will be destroyed once this function is returned from.
    Return Null ; Like void.
EndFunc   ;==>ReadAndReplace

Func Write()
    FileSetPos($g_hFile, 0, $FILE_BEGIN)
    For $i = 0 To 1000
        FileWrite($g_hFile, $i & @CRLF)
    Next
    FileSetPos($g_hFile, 0, $FILE_BEGIN)
EndFunc   ;==>Write

Does anyone have a valid example?

[Guest]

Hello, I have another question about Static. it is inside the script:

SomeFunc(True)
Func SomeFunc($Start = False)
    Local Static $var1, $var2, $var3
    If $Start Then
        ; Here I want to assign some values to $var1, $var2, $var3 ... at one line. Normally I could do it this way:
        ; Local $var1 = 1, $var2 = 2, $var3 = 3 <-- but this will not work because I used Static.
        ; So I have to do this in more then one line in this way:
        $var1 = 1
        $var2 = 2
        $var3 = 3
        ; ...
        ; How it can be done in one line with Static?
        Return
    EndIf
    ; Some code that use these vars...
EndFunc

Edited January 19, 2015 by Guest

[BrewManNH]

Local Static $var1 = 1, $var2 = 2, $var3 = 3

Static isn't something magical, it's just another way of using a local variable.

[guinness]

You can declare it there, but I would suggest that you do that only if they are visible inside the if block. So you don't end up with an error of undeclared.

I don't see the difficulty. When I learnt this for the first time you t made sense after I played around with the example. Which at the time were difficult to follow.

[Guest]

You can declare it there, but I would suggest that you do that only if they are visible inside the if block. So you don't end up with an error of undeclared.

I don't see the difficulty. When I learnt this for the first time you t made sense after I played around with the example. Which at the time were difficult to follow.

 

Can you give me an example of what can happen if I declare them that way?

I do not understand why is it can go wrong that way.

 

 

Local Static $var1 = 1, $var2 = 2, $var3 = 3

Static isn't something magical, it's just another way of using a local variable.

 

It will not work more than once (it is related to how Static work)

that this is not an option...

 

Edited January 20, 2015 by Guest

[guinness]

Just leave it as it is. I think there has been too much learning as of recent.

[BrewManNH]

It will not work more than once (it is related to how Static work)

that this is not an option...

 

It's not supposed to work more than once, that's the point of using Static instead of Local.

You declare the variable, and you give it a value,

• Local Static $var = 1

You may change that value in the variable later

• $var += 1 ; $var now equals 2

Function exits

• $var is equal to 2

Run the function again and $var remembers its last value.

• $var is equal to 2

 

If you want the variables to be reinitialized every time you run the function, don't use static. In other words if you need $var to equal 1 every time the function starts, then you shouldn't use Static to declare it.

Edited January 20, 2015 by BrewManNH

[Guest]

 

Thank you.
I learned a lot of useful things in this thread and others.

I was doing a lot of things differently if I had this knowledge.
But it's never too late. The things I use them the most are:
Local Static , ByRef , AdlibRegister()

^ this knowledge(Local Static , ByRef) give me the ability to always win (if I want to) the need to use glabal variables - very significant progress

 

The knowledge how to reset variables when it needed - Assign them 0 or "" (Unlike what I thought before)

No doubt I have learned some new things here and very useful

Thank you

 

BrewManNH,

I fully understand what it is Local Static (its limitations and benefits).

I tried to do something else and you did not understand what I asked.
Thanks anyway

Edited January 20, 2015 by Guest