how to format the output of the @AutoItVersion macro?

[Gianni]

I would transform the string returned by the @autoitversion macro in a progressive number like this:
3.3.8.1 --> 003003008001
any digit between dots should be formatted in 3 digits, so that any new version will return a number > of the previous version and could be easly compared numerically.

the snippet below do the job, but maybe with regex or with another pattern in StringFormat could be done in just one line?
could someone smarter than me give an help to shrink it in only one line
thanks

Local $AutoIt = StringSplit(@AutoItVersion, "."), $nAutoItVersion = ""
For $i = 1 To $AutoIt[0]
    $nAutoItVersion &= StringFormat("%03s", $AutoIt[$i])
Next
MsgBox(0, "AutoIt Version", "Autoit Version: " & @TAB & @AutoItVersion & @CRLF & "Formatted: " & @TAB & $nAutoItVersion)

[UEZ]

1liner but longer code:
 

ConsoleWrite(StringFormat("%03i%03i%03i%03i", StringRegExp(@AutoItVersion, "(\d+?)\.", 3)[0], StringRegExp(@AutoItVersion, "\d+\.(\d+?)\.", 3)[0], StringRegExp(@AutoItVersion, "\d+\.\d+\.(\d+?)\.", 3)[0], StringRegExp(@AutoItVersion, ".*\.(\d+)", 3)[0]) & @CRLF)

Br,

UEZ

[Gianni]

  On 1/8/2015 at 7:21 PM, UEZ said:

1liner but longer code:

 

ConsoleWrite(StringFormat("%03i%03i%03i%03i", StringRegExp(@AutoItVersion, "(\d+?)\.", 3)[0], StringRegExp(@AutoItVersion, "\d+\.(\d+?)\.", 3)[0], StringRegExp(@AutoItVersion, "\d+\.\d+\.(\d+?)\.", 3)[0], StringRegExp(@AutoItVersion, ".*\.(\d+)", 3)[0]) & @CRLF)

Br,

UEZ

 

nice, this could be ok

thanks UEZ!

.... maybe something of even shorter

[UEZ]

2liner:

Local $AutoIt = StringSplit(@AutoItVersion, ".", 2)
ConsoleWrite(StringFormat("%03i%03i%03i%03i", $AutoIt[0], $AutoIt[1], $AutoIt[2], $AutoIt[3]) & @CRLF)

Br,

UEZ

Edited January 8, 2015 by UEZ

[Gianni]

thanks again, this is even better for my purpose.
I see that it do not uses the sintax allowed in recent versions of autoit, (as you done your previous post).
since it should be used also on older versions of AutoIt, it is preferable, just for compatibility,

this second snippet that avoids the use of recent sintax enhancements.

Thanks a lot!

[mLipok]

An example of this came to my mind today:

;~ http://www.autoitscript.com/forum/topic/166692-gdiplus-bitmapcreatebitmapwithalpha/#entry1218022
;~ http://www.autoitscript.com/forum/topic/166640-how-to-format-the-output-of-the-autoitversion-macro/?p=1217544

If _AutoIt_RequiredVersion('3.3.12.0') Then
    MsgBox(16, 'Error', 'This program Require AutoIt 3.3.12.0 or later.' & @CRLF & 'Actually you are using: ' & @AutoItVersion)
Else
    ; make some stuff
EndIf

Func _AutoIt_RequiredVersion($sAutoItRequiredVersion)
    ; set $aAutoItRequiredVersion as Array
    Local $aAutoItRequiredVersion = StringSplit($sAutoItRequiredVersion, ".", 2)

    ; set $iAutoItRequiredVersion as Integer
    Local $iAutoItRequiredVersion = Number(StringFormat("%03i%03i%03i%03i", $aAutoItRequiredVersion[0], $aAutoItRequiredVersion[1], $aAutoItRequiredVersion[2], $aAutoItRequiredVersion[3]))

    ; Return results: compare AutoItRequiredVersion with "ActualAutoItVersion" as two variables of type Integer
    Return _AutoItVersion() < $iAutoItRequiredVersion
EndFunc   ;==>_AutoIt_RequiredVersion

Func _AutoItVersion()
    ; set $aAutoItVersion as Array
    Local $aAutoItVersion = StringSplit(@AutoItVersion, ".", 2)

    ; Return AutoItVersion as Integer
    Return Number(StringFormat("%03i%03i%03i%03i", $aAutoItVersion[0], $aAutoItVersion[1], $aAutoItVersion[2], $aAutoItVersion[3]))

EndFunc   ;==>_AutoItVersion

Edited January 12, 2015 by mLipok

[Yashied]

; Pattern written by MrCreatoR.
If StringRegExpReplace(@AutoItVersion, '(?<!\d)(\d)(?!\d)', '0\1') < '03.03.12.00' Then
    MsgBox(16, 'Error', 'Require AutoIt 3.3.12.0 or later.')
EndIf