last return value of a function(not return code)

[AndrewClim]

Hello ! I have an issue about capturing the last returned value from a function into another script (not the return code ( 0 for success or higher than 0 if failure)).

I looked up about any way to solve this and didn't find on this forum or other. I have 2 scripts - Script 1 and Script 2. Script 1 is a function that return a variable. I put a basic example (which contains a value - that value I want to catch ). I compile the script and this way an .exe is generated. In the second script I do something like : x= Run ("full path of exescript1.exe) and I display x. Apparently x has the value of an id which I don't understand where it comes from. It is the PID but I don't need this. With RunWait I capture the return code.

Is any way I could do this (in my case the value is 15)? I figured I can take RUN or RUNWAIT's UDF and get the code from here,copy it in my own place, modify in my own function RUN1 for example and modify it to capture the last return value, but I don't find the UDF for RUN or RUNWAIT. Any thoughts?

I attached an example of what I want to do. ...I want $x from Script 2 to be equal with 15.

Script1.au3

Script2.au3

Edited December 15, 2014 by Melba23
Fixed formatting

[Melba23]

AndrewClim,

Please pay attention to where you post - the "Dev Chat" section where you started this thread is not for general support questions. I have moved it for you (and fixed the formatting) but would ask you to be more careful in future.

M23

[TouchOdeath]

Theres a few ways to do this but the best is something like:

Run("cmd.exe /c script2.exe " & Returnval())

Func returnval()

;some code

Local $val = 1

Return $val

Endfunc

In script2.exe you say:

$CmdLine[0]

I'm typing from my phone so there's prob some mistakes. $CmdLine variable is reserved in auto it for this kind of stuff.

[Melba23]

AndrewClim,

The easiest way to do this would be to use a temporary ini file to store the return value - but you must use RunWait on the compiled file to give it a chance to write the file before the second script tries to read it. Otherwise you are into "inter process communication" - there are lots of ways to do this if you search, but they are all considerably more trouble to code than a simple ini file.

M23

[AndrewClim]

 I did this : 

Func _Main()

 

local $a=45

if $cmdline[0] >0 then

   if $cmdline[1] <>@ScriptName Then

$a= $cmdline[1]

   EndIf

EndIf

MsgBox(0,"" ,$a)

return $a

 

EndFunc

_Main()

 

 

I compiled this .Now I have an .exe that I run from CMD .What should I do in the other script where I have to capture that $a value ? I can't make the connection.

 

Melba23 ,I am not allowed from specifications to make a ini file,text file ,or other file to store that returned value that's why I searched for any other way around it . Thank you anyway for suggestion and sorry for posting in other section in the first place . 

Edited December 16, 2014 by AndrewClim

[Melba23]

AndrewClim,

 

,I am not allowed from specifications to make a ini file,text file ,or other file to store that returned value

Then IPC is the way to go - my personal favourite is trancexx's MailSlot.

M23

[orbs]

apparently, Windows does keep the exit code of a process in memory after the process terminated - although i can't tell for how long. you can query the exit code of a terminated process if you have it's PID:

;===============================================================================
;
; Function Name:    _ProcessExitCode()
; Description:      Returns a handle/exitcode from use of Run().
; Parameter(s):     $i_Pid        - ProcessID returned from a Run() execution
;                   $h_Process    - Process handle
; Requirement(s):   None
; Return Value(s):  On Success - Returns Process handle while Run() is executing
;                                (use above directly after Run() line with only PID parameter)
;                              - Returns Process Exitcode when Process does not exist
;                                (use above with PID and Process Handle parameter returned from first UDF call)
;                   On Failure - 0
; Author(s):        MHz (Thanks to DaveF for posting these DllCalls in Support Forum)
;
;===============================================================================
Func _ProcessExitCode($i_Pid, $h_Process_input = 0)
    ; 0 = Return Process Handle of PID else use Handle to Return Exitcode of a PID
    Local $v_Placeholder
    If $h_Process_input=0 Then
        ; Return the process handle of a PID - this is for the initial check
        $h_Process = DllCall('kernel32.dll', 'ptr', 'OpenProcess', 'int', 0x400, 'int', 0, 'int', $i_Pid)
        If Not @error Then Return $h_Process[0]
    Else
        ; Return Process Exitcode of PID - this is for ending check
        $h_Process = DllCall('kernel32.dll', 'ptr', 'GetExitCodeProcess', 'ptr', $h_Process_input, 'int*', $v_Placeholder)
        If Not @error Then Return $h_Process[2]
    EndIf
    Return 0
EndFunc   ;==>_ProcessExitCode

credits go to MHz here, although i can't seem to locate the original post (this code is a bugfix of mine over his function).

how to use:

1) call Run and save the PID

2) immediately call _ProcessExitCode using the PID to retrieve a process handle

3) whenever you wish, use ProcessExists() to check... well... if your process exists. if it does not exist, call _ProcessExitCode again with the PID and the handle to get the exit code.

note: if you get exit code = 1 then it means either that the process returned 1, or it was terminated by external means (e.g. killed via Task Manager). so, make sure your process does not ever return 1 as a valid exit code, and you're good to go.

EDIT: you'll need to close the handle when you're done:

DllCall('kernel32.dll', 'ptr', 'CloseHandle', 'ptr', $h_Process)

$h_Process is the handle you got in step 2

Edited December 16, 2014 by orbs

[TheSaint]

Melba23 ,I am not allowed from specifications to make a ini file,text file ,or other file to store that returned value that's why I searched for any other way around it . Thank you anyway for suggestion and sorry for posting in other section in the first place . 

I'm guessing read and write to the Registry is also a no no.

[AndrewClim]

I tried with MailSlots I receive a blank message .any thoughts on my mistakes ? I attached the code .

Script 1 became the Receiver ,Script 2 became the Sender.

MailSlot.au3

ProcessHandle.au3

Script1.au3

Script2.au3

[Melba23]

AndrewClim,

This works fine for me.

Script 1:

#include "MailSlot.au3"

; Create mailslot name
$sMailSlotname = "mymailslot"
$sMailSlotName_Receive = "\\.\mailslot\" & $sMailSlotname

; Cretae MailSlot
$hMailSlot = _MailSlotCreate($sMailSlotName_Receive)
If @error Then
    MsgBox(48, "MailSlot Script 1", "Failed to create MailSlot account")
    Exit
EndIf

; Run second script - passing MailSlot to use
RunWait("Script2.exe " & $sMailSlotName_Receive)

; Read message passed
$iSize = _MailSlotCheckForNextMessage($hMailSlot)
If $iSize Then
    $sData = _MailSlotRead($hMailSlot, $iSize, 1)
    If $sData Then
        MsgBox(48, "MailSlot Script 1", "MOMENT OF TRUTH" & @CRLF & $sData)
    Else
        MsgBox(48, "MailSlot Script 1", "No data returned")
    EndIf
Else
    MsgBox(48, "MailSlot Script 1", "MailSlot is empty")
EndIf

; Close MailSlot
_MailSlotClose($hMailSlot)

Script 2:

#include "MailSlot.au3"

$a = 45

; Get mailslot address for calling script
$sMailSlotSend = $CmdLine[1]

; If address passed - send mail
If $sMailSlotSend = "" Then
    MsgBox(48, "MailSlot Script 2", "No MailSlot passed")
Else
    _MailSlotWrite($sMailSlotSend, String($a)) ; Send as string <<<<<<<<<
EndIf

M23

[AndrewClim]

It worked .Apparently I had a different older version of Autoit because when I tried a method with cmdline ,it gave me an error,always the same:    "Array variable has incorrect number of subscripts or subscript dimension range exceeded.($sMailSlotSend = $CmdLine[1]

$sMailSlotSend = ^ ERROR)" ,also when I run your script Melba23 it gives me the same error   So that part was missing from my MailSlot script because of this error so it was normal not work . But now it does ,thank you very much all of you ,especially Melba23 ! Topic can now be closed