gui not responsive while in SLEEP

[Mike25de]

Hi,

I have a gui and a function that has a sleep of 20 sec.

While the script is in the SLEEP period,  i can not close the gui (exit).

I have created my own exit button .. or the window close button... neither of them work.

How can i  trigger another action while the script is sleeping?

Thanks in advance

[water]

Something like this?

HotKeySet("{F7}", _Exit)

Sleep(10000)

Func _Exit()
    Exit
EndFunc   ;==>_Exit

[BrewManNH]

Easiest way to accomplish this would be to not use sleep, use TimerInit and TimerDiff to do it instead and then you won't have to worry about it. There are dozens of examples of how to do this on the forum.

[Mike25de]

Thank you all .. i will try to use timer functions.

[Mike25de]

Guys... i might just be retarded ... but i have the same problem with timerinit... i can not click other button.. while i am waiting for 17 sec.

Please check the code below.. When i press the $GUI_Button_Test button.. the timer starts - it works just fine... BUT while this timer is active... pressing the Exit button... doesn't stop/Exit....  until the Timer is done. Even if i press the Exit after 2 seconds.. the timer will wait until the WHILE loop finishes and only then the exit action is activated.

I want to know if there is a way to break the timer.. to trigger another button while the timer is still active.  Am i doing something wrong? 

Case $msg = $GUI_Button_Exit
         Exit 0

Case $msg = $GUI_Button_Test
            Local $max = 17  ;wait this many seconds
            Local $hTimer = TimerInit() ; Begin the timer
            While 1
                  Local $fDiff = TimerDiff($hTimer) / 1000 ; transform into sec
                  If $fDiff >= $max Then
                     ExitLoop
                  EndIf
                  Sleep(200)
            WEnd
            MsgBox($MB_SYSTEMMODAL, "Time Difference", $fDiff)

Edited November 23, 2014 by IAHIM

[water]

Why do you use Sleep at all? What is you script waiting for?

[Mike25de]

Why do you use Sleep at all? What is you script waiting for?

My script is waiting for some files/feeds from a remote server. I don't want to connect to that server every second... but wait for half a minute. And i want to be able to trigger a second function while the script is sleeping....

[bogQ]

you declared loop in a loop so you are traped inside it

one of the many wayes to do what you need can be like this

 

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
Local $hGUI = GUICreate("Example", 400, 100)
Local $GUI_Button_Exit = GUICtrlCreateButton("Exit", 10, 10, 85, 25)
Local $GUI_Button_Test = GUICtrlCreateButton("test", 120, 10, 85, 25)
GUISetState()

$isITclicked = False
$FirstLoop = False
Local $hTimer, $max = 18;wait this many seconds

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $GUI_Button_Exit
            Exit 0
        Case $GUI_Button_Test
;~          If Not $isITclicked And Not $FirstLoop Then;enable to dont restart counting seconds if it already started
                $isITclicked = True
                $FirstLoop = True
;~          EndIf
    EndSwitch

    If $isITclicked Then
        If $FirstLoop Then
            $FirstLoop = False
            $hTimer = TimerInit() ; Begin the timer
        EndIf
        Local $fDiff = TimerDiff($hTimer) / 1000 ; transform into sec
        If $fDiff >= $max Then
            MsgBox($MB_SYSTEMMODAL, "Time Difference", $fDiff)
            $isITclicked = False
            ToolTip('')
        Else
            ToolTip($fDiff)
        EndIf
    EndIf
WEnd

there is ofc AdlibRegister func that can do similar things you need

[Mike25de]

bogQ :  thanks a lot mate!!

[kylomas]

just for grins, another way...

expandcollapse popup

#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <date.au3>

local $gui010   =   guicreate('')
local $aSize    =   wingetclientsize($gui010)
local $edt010   =   guictrlcreateedit('',10,20,$aSize[0]-20,300,bitor($es_readonly,$WS_VSCROLL))
local $lbl010   =   guictrlcreatelabel('',10,$aSize[1]-70,$aSize[0]-20,20,$ss_center)
local $btn010   =   guictrlcreatebutton('Start Timer',10,$aSize[1]-40,$aSize[0]-20,20)
                    guisetstate()

local $st = 0, $started = false

while 1
    switch guigetmsg()
        case $gui_event_close
            Exit
        case $btn010
            switch guictrlread($btn010)
                case 'Start Timer'
                    $st = timerinit()
                    $started = not $started
                    guictrlsetdata($edt010,'Timer Started at ' & _now() & @CRLF,1)
                    guictrlsetdata($btn010,'Stop Timer')
                case 'Stop Timer'
                    $started = not $started
                    guictrlsetdata($edt010,'Timer Stopped at ' & _now() & @CRLF,1)
                    guictrlsetdata($btn010,'Start Timer')
            endswitch
    EndSwitch

    if $started then
        if int(timerdiff($st)/1000) > 17 then
            if FileExists('some.file') then
                ;
                ; go do something
                ;
            EndIf
            $st = timerinit()
            guictrlsetdata($edt010,'Timer Restarted at ' & _now() & @CRLF,1)
        endif
        if guictrlread($lbl010) <> int(timerdiff($st/1000)) then guictrlsetdata($lbl010,int(timerdiff($st)/1000))
    endif

WEnd

Edited November 23, 2014 by kylomas