ImageSearch Incompatible with latest AutoIt?

[Hyflex]

Hey,

I'm trying to use ImageSearch but it's playing up and I don't know how to fix >

The code I'm using is: 

#include "C:\ImageSearch.au3"

Dim $XCoords, $YCoords
Local $ImageSearch = _ImageSearch("C:\PickList.png", 1, $XCoords, $YCoords, 25)

; Search Results
If $ImageSearch = 1 Then
MsgBox(16, "FOUND", "" & $XCoords & ", " & $YCoords)
Else
MsgBox(16, "ERROR", ":(", 300)
EndIf

This throws up the error:

 

"C:ImageSearch.au3"(34,73) : error: missing separator character before keyword.

Func _ImageSearchArea($findImage,$resultPosition,$x1,$y1,$right,$bottom,ByRef

If I delete the ByRefs then it doesn't error out and it correctly knows when the image is correct but is then unable to get the correct coordinates instead it uses 0, 0 

Original Imagesearch:

expandcollapse popup

#include-once
; ------------------------------------------------------------------------------
;
; AutoIt Version: 3.0
; Language:       English
; Description:    Functions that assist with Image Search
;                 Require that the ImageSearchDLL.dll be loadable
;
; ------------------------------------------------------------------------------

;===============================================================================
;
; Description:      Find the position of an image on the desktop
; Syntax:           _ImageSearchArea, _ImageSearch
; Parameter(s):
;                   $findImage - the image to locate on the desktop
;                   $tolerance - 0 for no tolerance (0-255). Needed when colors of
;                                image differ from desktop. e.g GIF
;                   $resultPosition - Set where the returned x,y location of the image is.
;                                     1 for centre of image, 0 for top left of image
;                   $x $y - Return the x and y location of the image
;
; Return Value(s):  On Success - Returns 1
;                   On Failure - Returns 0
;
; Note: Use _ImageSearch to search the entire desktop, _ImageSearchArea to specify
;       a desktop region to search
;
;===============================================================================
Func _ImageSearch($findImage,$resultPosition,ByRef $x, ByRef $y,$tolerance)
   return _ImageSearchArea($findImage,$resultPosition,0,0,@DesktopWidth,@DesktopHeight,$x,$y,$tolerance)
EndFunc

Func _ImageSearchArea($findImage,$resultPosition,$x1,$y1,$right,$bottom,ByRef $x, ByRef $y, $tolerance)
    ;MsgBox(0,"asd","" & $x1 & " " & $y1 & " " & $right & " " & $bottom)
    if $tolerance>0 then $findImage = "*" & $tolerance & " " & $findImage
    $result = DllCall("C:\ImageSearchDLL.dll","str","ImageSearch","int",$x1,"int",$y1,"int",$right,"int",$bottom,"str",$findImage)

    ; If error exit
    if $result[0]="0" then return 0

    ; Otherwise get the x,y location of the match and the size of the image to
    ; compute the centre of search
    $array = StringSplit($result[0],"|")

   $x=Int(Number($array[2]))
   $y=Int(Number($array[3]))
   if $resultPosition=1 then
      $x=$x + Int(Number($array[4])/2)
      $y=$y + Int(Number($array[5])/2)
   endif
   return 1
EndFunc

;===============================================================================
;
; Description:      Wait for a specified number of seconds for an image to appear
;
; Syntax:           _WaitForImageSearch, _WaitForImagesSearch
; Parameter(s):
;                   $waitSecs  - seconds to try and find the image
;                   $findImage - the image to locate on the desktop
;                   $tolerance - 0 for no tolerance (0-255). Needed when colors of
;                                image differ from desktop. e.g GIF
;                   $resultPosition - Set where the returned x,y location of the image is.
;                                     1 for centre of image, 0 for top left of image
;                   $x $y - Return the x and y location of the image
;
; Return Value(s):  On Success - Returns 1
;                   On Failure - Returns 0
;
;
;===============================================================================
Func _WaitForImageSearch($findImage,$waitSecs,$resultPosition,ByRef $x, ByRef $y,$tolerance)
    $waitSecs = $waitSecs * 1000
    $startTime=TimerInit()
    While TimerDiff($startTime) < $waitSecs
        sleep(100)
        $result=_ImageSearch($findImage,$resultPosition,$x, $y,$tolerance)
        if $result > 0 Then
            return 1
        EndIf
    WEnd
    return 0
EndFunc

;===============================================================================
;
; Description:      Wait for a specified number of seconds for any of a set of
;                   images to appear
;
; Syntax:           _WaitForImagesSearch
; Parameter(s):
;                   $waitSecs  - seconds to try and find the image
;                   $findImage - the ARRAY of images to locate on the desktop
;                              - ARRAY[0] is set to the number of images to loop through
;                                ARRAY[1] is the first image
;                   $tolerance - 0 for no tolerance (0-255). Needed when colors of
;                                image differ from desktop. e.g GIF
;                   $resultPosition - Set where the returned x,y location of the image is.
;                                     1 for centre of image, 0 for top left of image
;                   $x $y - Return the x and y location of the image
;
; Return Value(s):  On Success - Returns the index of the successful find
;                   On Failure - Returns 0
;
;
;===============================================================================
Func _WaitForImagesSearch($findImage,$waitSecs,$resultPosition,ByRef $x, ByRef $y,$tolerance)
    $waitSecs = $waitSecs * 1000
    $startTime=TimerInit()
    While TimerDiff($startTime) < $waitSecs
        for $i = 1 to $findImage[0]
            sleep(100)
            $result=_ImageSearch($findImage[$i],$resultPosition,$x, $y,$tolerance)
            if $result > 0 Then
                return $i
            EndIf
        Next
    WEnd
    return 0
EndFunc

 

Imagesearch that doesn't throw up the error:

expandcollapse popup

#include-once
; ------------------------------------------------------------------------------
;
; AutoIt Version: 3.0
; Language:       English
; Description:    Functions that assist with Image Search
;                 Require that the ImageSearchDLL.dll be loadable
;
; ------------------------------------------------------------------------------

;===============================================================================
;
; Description:      Find the position of an image on the desktop
; Syntax:           _ImageSearchArea, _ImageSearch
; Parameter(s):
;                   $findImage - the image to locate on the desktop
;                   $tolerance - 0 for no tolerance (0-255). Needed when colors of
;                                image differ from desktop. e.g GIF
;                   $resultPosition - Set where the returned x,y location of the image is.
;                                     1 for centre of image, 0 for top left of image
;                   $x $y - Return the x and y location of the image
;
; Return Value(s):  On Success - Returns 1
;                   On Failure - Returns 0
;
; Note: Use _ImageSearch to search the entire desktop, _ImageSearchArea to specify
;       a desktop region to search
;
;===============================================================================
Func _ImageSearch($findImage,$resultPosition, $x,  $y,$tolerance)
   return _ImageSearchArea($findImage,$resultPosition,0,0,@DesktopWidth,@DesktopHeight,$x,$y,$tolerance)
EndFunc

Func _ImageSearchArea($findImage,$resultPosition,$x1,$y1,$right,$bottom, $x,  $y, $tolerance)
    ;MsgBox(0,"asd","" & $x1 & " " & $y1 & " " & $right & " " & $bottom)
    if $tolerance>0 then $findImage = "*" & $tolerance & " " & $findImage
    $result = DllCall("C:\ImageSearchDLL.dll","str","ImageSearch","int",$x1,"int",$y1,"int",$right,"int",$bottom,"str",$findImage)

    ; If error exit
    if $result[0]="0" then return 0

    ; Otherwise get the x,y location of the match and the size of the image to
    ; compute the centre of search
    $array = StringSplit($result[0],"|")

   $x=Int(Number($array[2]))
   $y=Int(Number($array[3]))
   if $resultPosition=1 then
      $x=$x + Int(Number($array[4])/2)
      $y=$y + Int(Number($array[5])/2)
   endif
   return 1
EndFunc

;===============================================================================
;
; Description:      Wait for a specified number of seconds for an image to appear
;
; Syntax:           _WaitForImageSearch, _WaitForImagesSearch
; Parameter(s):
;                   $waitSecs  - seconds to try and find the image
;                   $findImage - the image to locate on the desktop
;                   $tolerance - 0 for no tolerance (0-255). Needed when colors of
;                                image differ from desktop. e.g GIF
;                   $resultPosition - Set where the returned x,y location of the image is.
;                                     1 for centre of image, 0 for top left of image
;                   $x $y - Return the x and y location of the image
;
; Return Value(s):  On Success - Returns 1
;                   On Failure - Returns 0
;
;
;===============================================================================
Func _WaitForImageSearch($findImage,$waitSecs,$resultPosition, $x,  $y,$tolerance)
    $waitSecs = $waitSecs * 1000
    $startTime=TimerInit()
    While TimerDiff($startTime) < $waitSecs
        sleep(100)
        $result=_ImageSearch($findImage,$resultPosition,$x, $y,$tolerance)
        if $result > 0 Then
            return 1
        EndIf
    WEnd
    return 0
EndFunc

;===============================================================================
;
; Description:      Wait for a specified number of seconds for any of a set of
;                   images to appear
;
; Syntax:           _WaitForImagesSearch
; Parameter(s):
;                   $waitSecs  - seconds to try and find the image
;                   $findImage - the ARRAY of images to locate on the desktop
;                              - ARRAY[0] is set to the number of images to loop through
;                                ARRAY[1] is the first image
;                   $tolerance - 0 for no tolerance (0-255). Needed when colors of
;                                image differ from desktop. e.g GIF
;                   $resultPosition - Set where the returned x,y location of the image is.
;                                     1 for centre of image, 0 for top left of image
;                   $x $y - Return the x and y location of the image
;
; Return Value(s):  On Success - Returns the index of the successful find
;                   On Failure - Returns 0
;
;
;===============================================================================
Func _WaitForImagesSearch($findImage,$waitSecs,$resultPosition, $x,  $y,$tolerance)
    $waitSecs = $waitSecs * 1000
    $startTime=TimerInit()
    While TimerDiff($startTime) < $waitSecs
        for $i = 1 to $findImage[0]
            sleep(100)
            $result=_ImageSearch($findImage[$i],$resultPosition,$x, $y,$tolerance)
            if $result > 0 Then
                return $i
            EndIf
        Next
    WEnd
    return 0
EndFunc

ImageSearchDLL.zip

Edited November 12, 2014 by Hyflex

[TheSaint]

3 Things.

[1] Don't edit Include files, unless you really understand their code.

[2] Global is much preferred over Dim.

[3] The error, is a missing separator (probably a comma), on Line 34, Character 73 in the Include file (ImageSearch.au3).

I haven't looked beyond that, but it seems it could be the result of your meddling.

I have also never used that function, UDF.

[Hyflex]

3 Things.

 

[1] Don't edit Include files, unless you really understand their code.

[2] Global is much preferred over Dim.

[3] The error, is a missing separator (probably a comma), on Line 34, Character 73 in the Include file (ImageSearch.au3).

 

I haven't looked beyond that, but it seems it could be the result of your meddling.

I have also never used that function, UDF.

Re:

1) The UDF wasn't working as it was (yet it did back on older autoit versions) so like the error says "missing separator" should in theory fix it if I remove the ByRef because it's clear that the ByRef is causing the problem due to it somehow thinking ByRef is a variable.

2) For mine it doesn't make any difference but point taken

3) See 1.

It definitely isn't because of my "meddling".

[TheSaint]

The only way it would think ByRef is a variable, would be a missing or extra comma.

I think you need to look beyond ByRef, and it may very well be an AutoIt version issue.

What is certain though, is the content of the error message, to which you need to pay attention.

If it worked previously, then something else has changed.

Something is only making it appear as though ByRef is an issue.

You need to check values for any variables involved.

Where did you get the Include file?

Have you been back to the source, if it wasn't a default AutoIt file? I haven't got an install of AutoIt to check just now.

Sometimes, with newer versions of AutoIt, you get a different number of parameters for a function in an Include UDF.

[Melba23]

Hyflex,

The problem is not AutoIt, it is Au3Check - as a quick search of the forum for the many recent "missing separator" threads would have shown. The solution is to use Tidy on the UDF script to add the missing spaces between the function parameters - or update your SciTE4AutoIt3 to the latest Beta where Au3Check no longer regards that problem as an error.

As to TheSaint's point about modifying UDFs by removing ByRef - I am in complete agreement with his warning as doing something like that can completely alter the manner in which the code deals with the parameter, quite possibly making the code unusable (see the Variables - using Global, Local and ByRef tutorial in the Wiki to see why). So please be very careful about doing so.

M23

[TheSaint]

Ah, I didn't know that had become an enforced thing.

I must have missed the topics where this issue was discussed.

Luckily I always did make sure of spaces in my scripts, if only to make it more visually pleasing ... and easier troubleshooting.

[Hyflex]

Hyflex,

The problem is not AutoIt, it is Au3Check - as a quick search of the forum for the many recent "missing separator" threads would have shown. The solution is to use Tidy on the UDF script to add the missing spaces between the function parameters - or update your SciTE4AutoIt3 to the latest Beta where Au3Check no longer regards that problem as an error.

As to TheSaint's point about modifying UDFs by removing ByRef - I am in complete agreement with his warning as doing something like that can completely alter the manner in which the code deals with the parameter, quite possibly making the code unusable (see the Variables - using Global, Local and ByRef tutorial in the Wiki to see why). So please be very careful about doing so.

M23

Hey,

I actually fixed it by doing it myself (tidying up) lol didn't think it would tidy so I made it look pretty but yeah didn't know about au3check.

Thanks for your advice