Using UP/DOWN in Listview

[sonofalion]

DllStructCreate is so hard for newbies like me. There are many posts here and there that go about treating up/down keys in listviews but nothing does the simple thing I need.

I need a variable that is updated with the selected/focused item of the listview every time UP or DOWN key is used to move within the listview. Any easy solutions?

My function so far only treats clicked items:

Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView, $tInfo
    $hWndListView = $ClauseList

    If Not IsHWnd($ClauseList) Then                                                ;(NEW LINE)
        $hWndListView = GUICtrlGetHandle($ClauseList)                            ;(NEW LINE)
    EndIf                                                                        ;(NEW LINE)

    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $hWndListView
            Switch $iCode
                Case $NM_CLICK ; Sent by a list-view control when the user clicks an item with the left mouse button
                    $tInfo = DllStructCreate($tagNMITEMACTIVATE, $lParam)
                    $j = _GUICtrlListView_GetSelectedIndices($ClauseList) ;get index of clicked item
                    _ActiveClause(Number($j)) ;this is a function I call
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc

Edited November 3, 2014 by sonofalion

[orbs]

not tested - i think you can just use GUICtrlRead on the list, in periodic intervals (i'd put it in the main loop of my script). it returns the selected item.

(one thing i like about this technique, is that it also returns the selected item of a combobox - even if you are just hovering, before you actually selected it!)

if you insist on a hook instead of polling, then i can't help with that.

[Melba23]

sonofalion,

This works for me:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GUIListView.au3>

Global $bChanged = False

$hGUI = GUICreate("Test", 500, 500)

$cLV = GUICtrlCreateListView("Column 1", 10, 10, 200, 200)
$hLV = GUICtrlGetHandle($cLV)
For $i = 0 To 19
    GUICtrlCreateListViewItem("Item " & $i, $cLV)
Next

GUISetState()

GUIRegisterMsg($WM_NOTIFY, "_WM_NOTIFY")

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

    If $bChanged Then
        $j = _GUICtrlListView_GetSelectedIndices($hLV)
        ConsoleWrite($j & @CRLF)
        $bChanged = False
    EndIf

WEnd

Func _WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView, $tInfo
    $hWndListView = $hLV

    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $hWndListView
            Switch $iCode
                Case $LVN_KEYDOWN
                    $tStruct = DllStructCreate($tagNMLVKEYDOWN, $lParam)
                    $iKey = DllStructGetData($tStruct, "VKey")
                    Switch $iKey
                        Case 38, 40 ; Up, Down
                            $bChanged = True
                    EndSwitch
                Case $NM_CLICK
                    $bChanged = True
            EndSwitch

    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

You need to look for the selection change in the idle loop as you must wait for the key press to take effect before reading the selected item - doing it in the handler is too soon.

M23

[LarsJ]

And you can get them all (click, up, down) in $LVN_ITEMCHANGED notifications.