auto-overwrite content of input control?

[Sven]

I've set up a control with

GUICtrlCreateInput("", $x, $y, $width, $height)

GUICtrlSetLimit(-1, 1)

 

Is there a way to erase the current content automatically when new data is entered? I know of GUICtrlSendMsg() and $EM_SETSEL, but this causes flickering in the input control when placed in a while loop.

 

Enter "1" in the input control, "1" stays. Try entering "2", and "1" is replaced by it.

[jdelaney]

Logically only set the value when it's NOT what you are changing it to.  No flashing that way.

[johnmcloud]

; Johnmcloud - 2014
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>

$hGUI = GUICreate("Johnmcloud Test Code", 200, 70, -1, -1)
$sInput = GUICtrlCreateInput("", 10, 20, 180, 20)
GuiSetState()

GUIRegisterMsg($WM_COMMAND, "_WM_COMMAND")

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func _WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    Local $iIDFrom = BitAND($wParam, 0xFFFF);LoWord
    Local $iCode = BitShift($wParam, 16) ;HiWord
    If $iIDFrom = $sInput And $iCode = $EN_CHANGE Then
       GUICtrlSetData($sInput, StringRight(GUICtrlRead($sInput),1))
    EndIf
    Return $GUI_RUNDEFMSG
EndFunc   ;==>_WM_COMMAND

Edited November 3, 2014 by johnmcloud

[Melba23]

Sven,

Fun little problem that one!

How about this as a solution:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GUIEdit.au3>

; Create a flag
Global $iFocused = 0

$hGUI = GUICreate("Test", 500, 500)

$cInput = GUICtrlCreateInput("", 10, 10, 200, 20)
GUICtrlSetLimit($cInput, 1)

$cButton = GUICtrlCreateButton("Test", 10, 100, 80, 30)
GUICtrlSetState($cButton, $GUI_FOCUS)

GUISetState()

GUIRegisterMsg($WM_COMMAND, "_WM_COMMAND")

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

    If $iFocused = 1 Then
        _GUICtrlEdit_SetSel($cInput, 0, -1)
        ; Set flag for focused and selected
        $iFocused = 2
    EndIf

WEnd

Func _WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)

    Switch _WinAPI_HiWord($wParam) ; Code
        Case $EN_SETFOCUS
            If Not $iFocused Then
                ; Set flag for initial focus
                $iFocused = 1
            EndIf
        Case $EN_KILLFOCUS
            ; Clear flag
            $iFocused = 0
    EndSwitch
    Return $GUI_RUNDEFMSG

EndFunc   ;==>_WM_COMMAND

Now you only select the content when you initially focus on the input. Any use?

M23

[Sven]

There I was, thinking the solution would just be a flag or command that I don't know about

johnmcloud's solution is working is pretty ideal for my purposes. Thank you. Looking at your example, I ended up putting three more lines into the while loop of my code:

If StringLen(GUICtrlRead($id) > 1 Then
    GUICtrlSetData($id, StringRight(GUICtrlRead($id), 1))
EndIf