Remove Script Paused

[behdadsoft]

Hi.

I want Remove or hide Script Paused when right click on icon in taskbar.mean only exist Exit button.how can do it?

 

[AutID]

Opt("TrayMenuMode", 1)

Edit: sorry this will not set a default menu but play with it. See also TrayItemDelete maybe

Edited October 30, 2014 by AutID

[Zedna]

Partial solution:

Opt("TrayAutoPause",0)

For removing use:

Opt("TrayMenuMode",1) ; no default menu (Paused/Exit)

If you want your own tray menu items then use

TrayCreateItem()

TraySetState()

TraySetClick()

and in main loop use TrayGetMsg()

You can look here at my Frame example using it

'?do=embed' frameborder='0' data-embedContent>>

Edited October 30, 2014 by Zedna

[behdadsoft]

Thanks. I create a Function that create tray Item but there is a Problem, that when run script and right click on tray icon do't show any thing. Please Guide Me.

expandcollapse popup

#RequireAdmin
#include <GUIConstantsEx.au3>
#include <TrayConstants.au3>

Opt("TrayMenuMode",3) ; no default menu (Paused/Exit)

; Functions
Example ()
_CreateTrayItem ()

Func Example ()

$GUI = GUICreate ("Autoit")
GUISetState(@SW_SHOW, $GUI)

    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
        EndSwitch
    WEnd

   ; Delete the previous GUI and all controls.
   GUIDelete($GUI)

  EndFunc

 ; Function for Create custom Tray Item
 Func _CreateTrayItem ()

   Local $TrayExit = TrayCreateItem ("Exit", -1, -1, 1)
   TraySetState($TRAY_ICONSTATE_SHOW) ; Show the tray menu.

   While 1
      Switch TrayGetMsg()
         Case $TrayExit
            GUIDelete ()
            ExitLoop
      EndSwitch
   WEnd

EndFunc

[BrewManNH]

That's because the function Example is stuck in an endless loop and the CreateTrayItem function never gets run until you exit the GUI.

[behdadsoft]

how can fix it?

i'm Weak in loop and array.

Edited October 31, 2014 by behdadsoft

[kylomas]

i'm Weak in loop and array

 

This has more to do with GUI management.  You should read the GUI Management section in the Help file and Wiki.

kylomas   

[behdadsoft]

 

This has more to do with GUI management.  You should read the GUI Management section in the Help file and Wiki.

 

OK, but now I need fix it.

[BrewManNH]

#RequireAdmin
#include <GUIConstantsEx.au3>
#include <TrayConstants.au3>

Opt("TrayMenuMode", 3) ; no default menu (Paused/Exit)

; Functions
Example()

Func Example()

    $GUI = GUICreate("Autoit")
    GUISetState(@SW_SHOW, $GUI)
    Local $TrayExit = TrayCreateItem("Exit", -1, -1, 1)
    TraySetState($TRAY_ICONSTATE_SHOW) ; Show the tray menu.

    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
        EndSwitch
        Switch TrayGetMsg()
            Case $TrayExit
                GUIDelete()
                ExitLoop
        EndSwitch
    WEnd

    ; Delete the previous GUI and all controls.
    GUIDelete($GUI)

EndFunc   ;==>Example

Use one While loop, check for both GUI and Tray messages within it.

[behdadsoft]

Thanks BrewManNH

[Chimaera]

Is there a way to just have Exit with no Pause?

Or a way to hide pause?

Pause often confuses people who use my scripts

[AdmiralAlkex]

Is there a way to just have Exit with no Pause?

Or a way to hide pause?

Pause often confuses people who use my scripts

 

What's wrong with the already presented solutions?

[Melba23]

Chimaera,

As far as I know you have both the default items or neither - but it is simple to add your own "Exit" trayitem:

#include <GUIConstantsEx.au3>

Opt("TrayMenuMode", 1)

$cTrayExit = TrayCreateItem("Exit")

$hGUI = GUICreate("Test", 500, 500)
GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

    Switch TrayGetMsg()
        Case $cTrayExit
            Exit
    EndSwitch
WEnd

Or, as I usually prefer:

#include <GUIConstantsEx.au3>

Opt("TrayMenuMode", 1)
Opt("TrayOnEventMode", 1)

$cTrayExit = TrayCreateItem("Exit")
TrayItemSetOnEvent($cTrayExit, "_Exit")

$hGUI = GUICreate("Test", 500, 500)
GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func _Exit()
    Exit
EndFunc

M23