DriveGetDrive() and _ArrayDelete()

[dewcansam]

I started out trying to make a function to read USB drives to array to generate a Combo or List box control. 

I followed this post '?do=embed' frameborder='0' data-embedContent>>

Did not really like the way they did things, but i realized that i did not need to make an array to generate the items in a Combo or List box control. 

The question is this: This is the function that I did come up with. But I really wanted to return the array with only the 'Fixed' and 'Removable' drive items. My code reflects the _ArrayDelete() call commented out. If you un-comment it the function returns an error saying the subscript is out-of-bounds. And that makes sense because _ArrayDelete() removes a element and so the array is really one less then it started out to be. Since the For loop started out with X elements and now it is X-1. So, what can be done to fix this ?? I thought that the answer lies somewhere in creating a new array and stores the elements that you want to keep in the new array and returns that array (if that makes sense). 

Code (working code that returns string):

expandcollapse popup

#comments-start
/***********************************************************************
@name   function  getUsbDrives

vers:   0.03
date:   2014-10-28 19:25:08
created on:   2014-10-14 22:28:22
created by:   Christopher L. Smith

gets all drives then removes anything that is not of type 'fixed' or of
type 'removable' then returns a string formated for a GUICtrlCreateList
or GUICtrlCreateCombo.

@return string      formated for List / Combo controls

@access public
***********************************************************************/
#comments-end
Func getUsbDrives()
    Local $drv = DriveGetDrive("all");used $drv because $drives and $drive were getting hard to distinguish
    Local $rtn

    If @error Then
        MsgBox(4096, "DriveGetDrive", "It appears an error occurred.")
    Else
        For $i = 1 To $drv[0]
            ;;; loops through the drives and finds only 'Fixed' or 'Removable'
            If DriveGetType($drv[$i]) = "Fixed" Or DriveGetType($drv[$i]) = "Removable" Then
                ;;; and then gets rid of the local drive.
                If Not ($drv[$i] = "c:") Then
                    ;;; returns array of drives (could not get it to work)
                    ;_ArrayDelete( $drv ,$i)
                    ;;; returns string formated for List / Combo controls
                    $rtn &= $drv[$i] & '|'
                EndIf
            EndIf
        Next
    EndIf
    Return $rtn
EndFunc   ;==>getUsbDrives

comment out the "$rtn &= $drv[$i] & '|'" line (34) and un-comment the "_ArrayDelete( $drv ,$i)" line (32) to get the error that I am referring to. 

Edited October 29, 2014 by dewcansam

[Luigi]

Use _ArrayDel() on-the-fly or iterate a loop and delete an item of the same array... Not good for me.
I always use @error immediately after the function. I never let anything between function and @error.

Nowadays, I avoid using nested conditionals (before I used a lot).
Those are my practices.

Maybe this?

#include <Array.au3>

Local $var = getUsbDrives()
_ArrayDisplay($var)

Func getUsbDrives()
    Local $aDel[1]
    Local $aDrives = DriveGetDrive("all")
    If @error Then
        MsgBox(4096, "DriveGetDrive", "It appears an error occurred.")
    Else
        For $ii = 1 To $aDrives[0]
            Switch DriveGetType($aDrives[$ii])
                Case "Fixed", "Removable"
                    If Not ($aDrives[$ii] == @HomeDrive) Then _ArrayAdd($aDel, $ii)
            EndSwitch
        Next
        For $ii = 1 To UBound($aDel, 1) - 1
            _ArrayDelete($aDrives, $aDel[$ii])
        Next
    EndIf
    If UBound($aDel, 1) Then _ArrayDelete($aDrives, 0)
    Return $aDrives
EndFunc   ;==>getUsbDrives

Edited October 29, 2014 by Detefon

[BrewManNH]

When deleting things from an array, loop through the array in reverse.

So instead of:

For $i = 1 To $drv[0]

Use this:

For $i = $drv[0] To 1 Step -1

This way whatever you delete will always be above the next number in the loop.

[dewcansam]

Good idea. Would not have thought of that. I will try it out it in a bit. Thanks.

[Luigi]

I never try with reverse iteration... Hummmmmm....

[dewcansam]

I never try with reverse iteration... Hummmmmm....

Yeah, I was thinking more along the lines of what you displayed. Where you created a new array, populated it with what you were keeping then rewrote the original array. 

[dewcansam]

 

I avoid using nested conditionals (before I used a lot).

Yeah, I did NOT like the nested conditions either. Could not think of a cleaner way. Thanks for the point out.

What exactly do you mean by

I always use @error immediately after the function. I never let anything between function and @error.

 

Could you clear that up a little bit.

[Luigi]

Yes! 

I see you use this...

Local $drv = DriveGetDrive("all");used $drv because $drives and $drive were getting hard to distinguish
Local $rtn
If @error Then

You left a "Local $rtn" between "Local $drv..." and "If @error..."

I use this

 Local $rtn
 Local $drv = DriveGetDrive("all");used $drv because $drives and $drive were getting hard to distinguish
 If @error Then

Nothing between "The function" and "The @error"... I see in the Help File, Logal, Global Or Dim not return @error (this is not the case).

But I don't like this.

If was another function can return set an @error? Possible a false @error or not!

Use @error is very good.

Regards, Detefon

obs: @dewcansam, I have this topics in my favorites and always consult:

• https://www.autoitscript.com/wiki/Best_coding_practices
• '?do=embed' frameborder='0' data-embedContent>>

Edited October 29, 2014 by Detefon

[dewcansam]

 

I use this

 Local $rtn
 Local $drv = DriveGetDrive("all");used $drv because $drives and $drive were getting hard to distinguish
 If @error Then

Nothing between "The function" and "The @error"... I see in the Help File, Logal, Global Or Dim not return @error (this is not the case).

 

Ohhhhh. I got ya. 

And nice point out on the coding practices. Will have to try to implement some of them. 

Edited October 29, 2014 by dewcansam

[guinness]

I would also argue that it's best to declare and assign when required, i.e. lowest scope possible.

I see I need to update the wiki at some point.