Array help

[stoavio]

Hey guys - 

I'm new to working with arrays and am going through a small exercise for fun. If I want to create an array of all the environment variables on my system without explicitly defining vars for each one using EnvGet, how do I get the variable in one column and the value for that variable in another column in an array using the following code which simply reads the STDOutput from a command line command?

#include <Array.au3>

$iPid = Run(@ComSpec & " /c" & 'set', 'C:\', @SW_HIDE, 8)
Sleep(2000)
ProcessWaitClose($iPid)

$output = StdoutRead($iPid)

$envvars = StringSplit($output, "=", 2)

_ArrayDisplay($envvars, "Env Vars")

Is the array I am trying to create called multi-dimensional because I want rows AND columns? Right now I am just getting back everything in a single column which doesn't help much.

Next steps...?

Thanks!

[guinness]

For simplicity, create a 2 dimensional array that is half the size of the $envvars array and with 2 columns, then loop through the $envvars array with the step set to 2. I have purposely not created it for you, as it seems you want to learn.

Edit: Wait, it seems that the output is a little unexpected from what I first thought.

Edited October 11, 2014 by guinness

[Gianni]

here one of possible ways:

#include <Array.au3>

$iPid = Run(@ComSpec & " /c" & 'set', 'C:\', @SW_HIDE, 8)
Sleep(2000)
ProcessWaitClose($iPid)

$output = StdoutRead($iPid)

$envvars = _VarTo2D($output, "=")

_ArrayDisplay($envvars, "Env Vars")

Func _VarTo2D($var, $sSeparator = @TAB)
    Local $aRows = StringSplit(StringStripCR($var), @LF), $aColumns, $aResult[$aRows[0]][1]
    For $iRow = 1 To $aRows[0]
        $aColumns = StringSplit($aRows[$iRow], $sSeparator)
        If $aColumns[0] > UBound($aResult, 2) Then ReDim $aResult[$aRows[0]][$aColumns[0]]
        For $iColumn = 1 To $aColumns[0]
            $aResult[$iRow - 1][$iColumn - 1] = $aColumns[$iColumn]
        Next
    Next
    Return $aResult
EndFunc   ;==>_VarTo2D

[guinness]

Seems Chimp gave you code for free, so I will too.

#include <Array.au3>

Local $iPID = Run(@ComSpec & ' /c set', @HomeDrive, @SW_HIDE, $STDOUT_CHILD)
ProcessWaitClose($iPID)
Local $sOutput = StringTrimRight(StdoutRead($iPID), StringLen(@CRLF))
Local $aSplit = StringSplit($sOutput, @CRLF, BitOR($STR_ENTIRESPLIT, $STR_NOCOUNT))
Local $aEnvVars[UBound($aSplit)][2], $aTempSplit = 0, _
        $iIndex = 0
For $i = 0 To UBound($aSplit) - 1
    $aTempSplit = StringSplit($aSplit[$i], '=', $STR_NOCOUNT)
    If Not @error Then
        $aEnvVars[$iIndex][0] = $aTempSplit[0]
        $aEnvVars[$iIndex][1] = $aTempSplit[1]
        $iIndex += 1
    EndIf
Next

_ArrayDisplay($aEnvVars, 'Env Vars')

[guinness]

Or keep it simple...

#include <Array.au3>

Local $iPID = Run(@ComSpec & ' /c set', @HomeDrive, @SW_HIDE, $STDOUT_CHILD)
ProcessWaitClose($iPID)
Local $aEnvVars[0][2]
_ArrayAdd($aEnvVars, StringTrimRight(StdoutRead($iPID), StringLen(@CRLF) * 2), Default, '=', @CRLF)
_ArrayDisplay($aEnvVars, "Env Vars")

#include <Array.au3>

; Works in the latest AutoIt beta.
Local $iPID = Run(@ComSpec & ' /c set', @HomeDrive, @SW_HIDE, $STDOUT_CHILD)
ProcessWaitClose($iPID)
Local $aEnvVars[0][2]
_ArrayAdd($aEnvVars, StringTrimRight(StdoutRead($iPID), StringLen(@CRLF)), Default, '=', @CRLF)
_ArrayDisplay($aEnvVars, "Env Vars")

Edited October 11, 2014 by guinness

[stoavio]

Wow, you guys are awesome. Love the different approaches and especially love the easiest of all of the solutions:

#include <Array.au3>

Local $iPID = Run(@ComSpec & ' /c set', @HomeDrive, @SW_HIDE, $STDOUT_CHILD)
ProcessWaitClose($iPID)
Local $aEnvVars[0][2]
_ArrayAdd($aEnvVars, StringTrimRight(StdoutRead($iPID), StringLen(@CRLF) * 2), Default, '=', @CRLF)
_ArrayDisplay($aEnvVars, "Env Vars")

Thanks for the education Chimp and guinness! I'm sure I'll be back with more questions on arrays eventually. Much appreciated.

[JLogan3o13]

I prefer the WMI method, personally:

#include <Array.au3>
 
Local $aVars[0]
$oWMI = ObjGet("winmgmts:\\.\root\cimv2")
$cEnvVars = $oWMI.ExecQuery("Select * from Win32_Environment")
 
For $element in $cEnvVars
 _ArrayAdd($aVars, $element.Name)
Next
 
_ArrayDisplay($aVars)

Edit: Scratch that - on WIN8 this no longer returns all the environment variables, when compared to the set command. Odd.

Edited October 12, 2014 by JLogan3o13