Need some help understanding this Ternary operator

[Morthawt]

I have seen the example and I saw a thread on here but it was all very confusing. Could someone give me a brief description of why and how it is useful and a few simple examples that demonstrate different uses of it? I saw somewhere using message boxes as part of it but when I tried using consolewrites nothing worked. I tried to do:

$a = 1
$b = False
$c = 123
$d = 2

$timer = TimerInit()
($a + $d = 3) ? (ConsoleWrite('True' & TimerDiff($timer) & @LF)) : (ConsoleWrite('False' & TimerDiff($timer) & @LF))

I just do not understand it yet, I would appreciate some clarification. Thanks.

[guinness]

First disable Au3Check and you will see the error disappear, since Au3Check is flagging as an error that it should be used to assign back to a variable (read the error). Use #AutoIt3Wrapper_Run_Au3Check=N at the top of your script.

Now read this...

#cs
    People tend to use ternary as a replacement for If...Else...Then, which can be wrong and is something I am guilty of myself in the past.
    Take for example what you posted above (see the "tided" code below), it's wrong because when you look at it was is different between both ConsoleWrite() calls?
    Correct, only the true and false strings. Now I know someone is going to come in and say well you can do this...

    ConsoleWrite((($iNum1 + $iNum2) = 3) & TimerDiff($hTimer) & @CRLF)

    and while that's correct, what if the output is not true and false? Perhaps it is wind and water, what then? So let me continue with what I was saying.
#ce

Local $iNum1 = 1
Local $iNum2 = 2

Local $hTimer = TimerInit()
Local $vReturn = (($iNum1 + $iNum2) = 3) ? ConsoleWrite('True ' & TimerDiff($hTimer) & @CRLF) : ConsoleWrite('False ' & TimerDiff($hTimer) & @CRLF) ; The error was Au3Check, so just assign the return value of ConsoleWrite() to a variable.

; This is the correct approach with ternary and your example.
ConsoleWrite('My approach: ' & ((($iNum1 + $iNum2) = 3) ? 'True' : 'False') & ' '  & TimerDiff($hTimer) & @CRLF)

; Another usage is assigning on declaration. Which is easier to understand and code? (As coders less typing is always a good thing.)
Local $sEarthOrWind
If ($iNum1 + $iNum2) = 3 Then ; Notice how I encapsulate the expression in parentheses. !IMPORTANT!
    $sEarthOrWind = 'Wind'
Else
    $sEarthOrWind = 'Fire'
EndIf
ConsoleWrite('Variable declaration pt. 1: ' & $sEarthOrWind & @CRLF)

; Or is this?
Local $sEarthOrWindEx = (($iNum1 + $iNum2) = 3 ? 'Wind' : 'Fire')
ConsoleWrite('Variable declaration pt. 2: ' & $sEarthOrWindEx & @CRLF)


; But I digress, as all of this is documented within the Forum plus the Internet. 

Edited October 11, 2014 by guinness

[jchd]

#AutoIt3Wrapper_Run_AU3Check=n
#AutoIt3Wrapper_UseX64=n

Global Const $g__PreferredBitSize = (@AutoItX64 ? 64 : 32)
ConsoleWrite($g__PreferredBitSize & @LF)

[Morthawt]

So the only thing I was getting wrong is that if I do not want to disable the checker, I have to assign the whole thing to a variable? Thats not a problem, I would rather have a variable just make it work than have to go disabling some checking feature.

Thanks

[guinness]

So the only thing I was getting wrong is that if I do not want to disable the checker, I have to assign the whole thing to a variable? Thats not a problem, I would rather have a variable just make it work than have to go disabling some checking feature.

 

Thanks

No. Please read carefully what I wrote, as you said you wanted to understand its usage. Even if you do use that "workaround" it's still wrong and thus there has been a misunderstanding of the usage of ternary. Otherwise you might as well just use If...Else...Then, which if you say is not for you, then I am curious as to why this is? Edited October 11, 2014 by guinness

[guinness]

A good discussion on the subject >> '?do=embed' frameborder='0' data-embedContent>>

[Morthawt]

Thanks guinness.

[guinness]

You're welcome.

[Morthawt]

I have a weird thing with this I hope you can help me understand the difference between the two:

This one works and shows the whole path and filename:

ConsoleWrite(@ScriptDir & ((StringMid(@ScriptDir, StringLen(@ScriptDir), 1) <> '\') ? ('\') : ('')) & 'IDCdebug.txt' & @CRLF)

This one only shows the ternary result (either or nothing) even though there is a macro preceeding it with an &:

ConsoleWrite(@ScriptDir & (StringMid(@ScriptDir, StringLen(@ScriptDir), 1) <> '\') ? ('\') : ('') & 'IDCdebug.txt' & @CRLF)

On the help file it does not show that you must enclose the whole over all ternary structure inside brackets, yet in my case it only works when I put the entire thing in brackets. I put each individual component in brackets as shown on the helpfile, so I do not know why I could only get it working by putting the whole thing in brackets additionally.

I would appreciate some clarification on this.

[trancexx]

^^ It's the default operator precedence kicking-in when you fail to be explicit about order in which you want to evaluate the expression. For example, here:

$x = 13 & 4 * 3 / 2 + 7 - 6 / 3 - 4 / 2 * 3 + 32
ConsoleWrite($x & @CRLF)

What's printed to console?

It's simple, be explicit if implicit confuses you.

[jchd]

The issue with operator's priority.

[Morthawt]

^^ It's the default operator precedence kicking-in when you fail to be explicit about order in which you want to evaluate the expression. For example, here:

$x = 13 & 4 * 3 / 2 + 7 - 6 / 3 - 4 / 2 * 3 + 32
ConsoleWrite($x & @CRLF)

What's printed to console?

It's simple, be explicit if implicit confuses you.

Your example does not help me to understand why my failed (first) attempt does not even show the first macro.

The issue with operator's priority.

Could you explain the concept to me based on my particular example so that I understand why my failed attempt did not even show the initial macro and was replaced only with the ternary result?

[trancexx]

Your example does not help me to understand why my failed (first) attempt does not even show the first macro.

Then maybe you should try more.

 

This:

ConsoleWrite(@ScriptDir & (StringMid(@ScriptDir, StringLen(@ScriptDir), 1) <> '\') ? ('\') : ('') & 'IDCdebug.txt' & @CRLF)

...is shorthand version of this:

If @ScriptDir & (StringMid(@ScriptDir, StringLen(@ScriptDir), 1) <> '\') Then
    ConsoleWrite('\')
Else
    ConsoleWrite(('') & 'IDCdebug.txt' & @CRLF)
EndIf

...which in simplified form, after semantic analysis, can be reduced to (and written as):

ConsoleWrite('\')

Edited October 13, 2014 by trancexx

[Morthawt]

Then maybe you should try more.

 

This:

ConsoleWrite(@ScriptDir & (StringMid(@ScriptDir, StringLen(@ScriptDir), 1) <> '\') ? ('\') : ('') & 'IDCdebug.txt' & @CRLF)

...is shorthand version of this:

If @ScriptDir & (StringMid(@ScriptDir, StringLen(@ScriptDir), 1) <> '\') Then
    ConsoleWrite('\')
Else
    ConsoleWrite(('') & 'IDCdebug.txt' & @CRLF)
EndIf

...which in simplified form, after semantic analysis, can be reduced to (and written as):

ConsoleWrite('\')

 

Thank you. I believe what you are saying is the initial part @ScriptDir & was being treated as part of the first component of the ternary operation, so the brackets isolate it to the desired components only. This is exactly what I needed. And for the record I do "try" which is why I figured out how to make it work, I just did not understand why it worked and that drove me here to try and get answers so that I know why to do something instead of just what. I hate "Just do it this way" if I do not know the background on the reason why to do things a particular way. So thank you for this latest example, I believe I understand now.