_GUICtrlRichEdit_Create question

[Merchants]

is it possible to disable the user from typing or editing or selecting items?

basically a log box..

$hRichEdit = _GUICtrlRichEdit_Create($hGui, "", 7,45,235,80, BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))

Edited October 2, 2014 by Merchants

[Melba23]

Merchants,

If you look at the list of styles on the GUICtrlRichEdit_Create page in the Help file do you not see one which might fit the bill?

M23

[Merchants]

  On 10/2/2014 at 6:33 PM, Melba23 said:

Merchants,

If you look at the list of styles on the GUICtrlRichEdit_Create page in the Help file do you not see one which might fit the bill?

M23

 

i can only find this one

$ES_READONLY 0x0800 Prevents the user from typing or editing text in the edit control.

 

if i add this the user can still select the text

[Melba23]

Merchants,

To prevent the user from selecting the text, you can place a child GUI over the RichEdit like this:

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

$hGui = GUICreate("Test", 500, 500)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL, $ES_READONLY))

GUISetState(@SW_SHOW)

$hChildGUI = GUICreate("", 300, 220, 10, 10, $WS_POPUP, $WS_EX_MDICHILD, $hGui)
WinSetTrans($hChildGUI, "", 10)
GUISetState()

While True
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            _GUICtrlRichEdit_Destroy($hRichEdit)
            Exit
    EndSwitch
WEnd

M23

[Merchants]

is not the best solution..

there is not a style for it?

[Melba23]

Merchants,

As far as I know there is no style to prevent text selection or I would have suggested it. What is wrong with the child GUI overlay idea? I thought it worked very nicely.

M23

[Merchants]

it was a good idea but with some clicking i can still select the text

but al will leave it as it is

i just have to live with it

[Melba23]

Merchants,

 

  Quote

i just have to live with it

Note to self: Do not bother next time. >

M23

[BrewManNH]

You could use ControlDisable and disable the control, that would prevent someone from selecting the text as well.

Using Melba's script as a base, here's how that would work.

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

$hGui = GUICreate("Test", 500, 500)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "", 10, 10, 300, 220, BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL, $ES_READONLY))
ControlDisable($hGui, "", $hRichEdit)
ControlSetText($hGui, "", $hRichEdit, "This is a test.")
GUISetState(@SW_SHOW)

;~ $hChildGUI = GUICreate("", 300, 220, 10, 10, $WS_POPUP, $WS_EX_MDICHILD, $hGui)
;~ WinSetTrans($hChildGUI, "", 10)
;~ GUISetState()

While True
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            _GUICtrlRichEdit_Destroy($hRichEdit)
            Exit
    EndSwitch
WEnd

You'll notice that I used _GUICtrlRichEdit_AppendText to demonstrate that even when it's disabled you can still add text to it.

[Merchants]

this was enough

ControlDisable($hGui, "", $hRichEdit)

Thank you

it works but when i have more text then i can't see it then i wana scroll down but it is...it is disable...

got a command to turn only the scroll bar on?

Edited October 2, 2014 by Merchants

[BrewManNH]

Here's how you'd do it without using the scroll bar, but scrolling with a mouse. I don't believe you can turn on the scroll bar on a disabled control, but someone will probably prove me wrong.

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>
$hGui = GUICreate("Test", 500, 500)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "", 10, 10, 300, 220, BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL, $ES_READONLY))
ControlDisable($hGui, "", $hRichEdit)
For $i = 1 To 10000
    _GUICtrlRichEdit_AppendText($hRichEdit, "This is a test.")
Next
GUIRegisterMsg($WM_MOUSEWHEEL, "_WM_MOUSEWHEEL") ; Monitors mouse wheel to move +/- the text in the edit control
GUISetState(@SW_SHOW)
GUISetState(@SW_MINIMIZE)
GUISetState(@SW_RESTORE)

;~ $hChildGUI = GUICreate("", 300, 220, 10, 10, $WS_POPUP, $WS_EX_MDICHILD, $hGui)
;~ WinSetTrans($hChildGUI, "", 10)
;~ GUISetState()

While True
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            _GUICtrlRichEdit_Destroy($hRichEdit)
            Exit
    EndSwitch
WEnd

Func _WM_MOUSEWHEEL($hWnd, $iMsg, $wParam, $lParam)
;~  The code here is by Mat, from forum post: http://www.autoitscript.com/forum/topic/124346-wheel-detection/page__view__findpost__p__863690
    #forceref $hWnd, $iMsg, $wParam, $lParam
    Local $iLen = _WinAPI_HiWord($wParam) / 120
    ; I used each of these 4 times because it scrolls very slowly if you do it one line at a time
    If $iLen > 0 Then
        _GUICtrlRichEdit_ScrollLineOrPage($hRichEdit, "lu")
        _GUICtrlRichEdit_ScrollLineOrPage($hRichEdit, "lu")
        _GUICtrlRichEdit_ScrollLineOrPage($hRichEdit, "lu")
        _GUICtrlRichEdit_ScrollLineOrPage($hRichEdit, "lu")
    Else
        _GUICtrlRichEdit_ScrollLineOrPage($hRichEdit, "ld")
        _GUICtrlRichEdit_ScrollLineOrPage($hRichEdit, "ld")
        _GUICtrlRichEdit_ScrollLineOrPage($hRichEdit, "ld")
        _GUICtrlRichEdit_ScrollLineOrPage($hRichEdit, "ld")
    EndIf
    Return 0 ; If you return zero, then the message will not be sent to any more windows.
EndFunc   ;==>_WM_MOUSEWHEEL

[Merchants]

  On 10/2/2014 at 8:26 PM, BrewManNH said:

Here's how you'd do it without using the scroll bar, but scrolling with a mouse. I don't believe you can turn on the scroll bar on a disabled control, but someone will probably prove me wrong.

 

will it works..

i think someone will prove you wrong don't know who will be first