GUICtrlCreateCombo to and mouse scroll wheel problem

[KEHT]

Hello again guys!

I ran into another problem I am trying to solve.  I have a ComboBox control with a long list of names.  When one of them is selected its value is added to a List control below.  The problem I am having is that when a name is selected in a combobox and mouse wheel is scrolled all the names that are scrolled through get added to a List control below.  My users indicated this as undesirable behavior.  I am not sure whether it is a default or not, but I'm trying to get rid of it.  I tried shifting focus after the name is selected, but it did not work too well.  I am now trying to figure out a way to only allow selection when ComboBox is extended or only allow selection specifically by clicking left mouse button.  Can anybody provide any suggestions??? 

[jdelaney]

You can add a button, and only add the selected 'combo' value when the 'add' button is clicked.

Edited September 23, 2014 by jdelaney

[KEHT]

You can add a button, and only add the selected 'combo' value when the 'add' button is clicked.

Unfortunately, that's not an option in my case as I am limited by the requirements to have the same number and type of elements as the previous version of software I am recreating.  

[jdelaney]

Then you have to key off the click, and not the change in text.  Maybe loss of focus will do you.

Edited September 23, 2014 by jdelaney

[Melba23]

KEHT,

I would do it like this:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiComboBox.au3>

; Flag to show if combo has dropped
Global $bSelected = False

$hGUI = GUICreate("Test", 500, 500)

$cCombo = GUICtrlCreateCombo("", 10, 10, 200, 20)
GUICtrlSetData($cCombo, "1|2|3|4|5|6|7|8|9")

$cList = GUICtrlCreateList("", 10, 100, 200, 200, BitOR($WS_BORDER, $WS_VSCROLL))

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cCombo
            ; If combo has dropped
            If $bSelected Then
                ; Clear flag
                $bSelected = False
                ; Add data
                GUICtrlSetData($cList, GUICtrlRead($cCombo))
            EndIf
    EndSwitch

    ; look for combo dropping
    If _GUICtrlComboBox_GetDroppedState($cCombo) Then
        ; Set flag
        $bSelected = True
    EndIf

WEnd

You could probably look for a message that the combo has been dropped rather then polling in the loop - but I leave that to you to code.

Please ask if anything is unclear.

M23

Edit:

Actually the message code is really easy, so here it is:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiComboBox.au3>

; Flag to show if combo has dropped
Global $bSelected = False

$hGUI = GUICreate("Test", 500, 500)

$cCombo = GUICtrlCreateCombo("", 10, 10, 200, 20)
GUICtrlSetData($cCombo, "1|2|3|4|5|6|7|8|9")

$cList = GUICtrlCreateList("", 10, 100, 200, 200, BitOR($WS_BORDER, $WS_VSCROLL))

GUISetState()

GUIRegisterMsg($WM_COMMAND, "_WM_COMMAND")

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cCombo
            ; If combo has dropped
            If $bSelected Then
                ; Clear flag
                $bSelected = False
                ; Add data
                GUICtrlSetData($cList, GUICtrlRead($cCombo))
            EndIf
    EndSwitch

WEnd

Func _WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)

    If _WinAPI_HiWord($wParam) = $CBN_DROPDOWN Then
        ; Set flag
        $bSelected = True
    EndIf

EndFunc

Edited September 23, 2014 by Melba23

[KEHT]

Thanks, @Melba23 !!! That did the trick perfectly!!!