RegExpReplace Count Incorrect

[Guy_]

I'll always feel a n00b and therefore hesitant to post what I think is a bug...

Having a first go with this one (that doesn't work in the release version either):

Manual for StringRegExpReplace states:

"Check @extended for the number of replacements performed"

However this seems not to be happening for my _WordCount( $text ) function

and I have to use _WordCount2( $text ) as a workaround.

"I hope this is a real bug"...?

Global $text = "Six word sentence for testing purposes."

MsgBox(0,"", "The sentence  '" & $text & "'  has  " & _WordCount( $text ) & "  words." & @CRLF & _
"The sentence  '" & $text & "'  has  " & _WordCount2( $text ) & "  words." )


; manual states: "Check @extended for the number of replacements performed" (but doesn't seem to work?)
Func _WordCount( $text )
    StringRegExpReplace( $text, "(\s){1,}[\W|_](\s){1,}|\R", " ", 0 )
    Return @extended + 1    ; nr of spaces + 1 = wordcount
EndFunc


; workaround
Func _WordCount2( $text )
    StringReplace( StringRegExpReplace( $text, "(\s){1,}[\W|_](\s){1,}|\R", " ", 0 ), " ", "x")
    Return @extended + 1    ; nr of spaces + 1 = wordcount
EndFunc

Edited September 15, 2014 by Guy_

[jchd]

Why make it hard?

Global $text = "A 8-word sentence for 365 testing purposes."

MsgBox(0,"", "The sentence  '" & $text & "'  has  " & _WordCount( $text ) & "  words.")

; manual states: "Check @extended for the number of replacements performed" (but doesn't seem to work?)
Func _WordCount( $text )
    StringRegExpReplace( $text, "\b([[:alnum:]]+)", "")
    Return @extended    ; nbr of words
EndFunc

EDIT: without uderscores allowed inside words.

Edited September 15, 2014 by jchd

[Melba23]

Guy_,

No bug - your RegEx just does not work and so it makes no replacements.

Just add some error checking and you can see what happens:

expandcollapse popup

Global $text = "Six word sentence for testing purposes."

MsgBox(0,"", "The sentence  '" & $text & "'  has  " & _WordCount( $text ) & "  words." & @CRLF & _
"The sentence  '" & $text & "'  has  " & _WordCount2( $text ) & "  words." & @CRLF & _
"The sentence  '" & $text & "'  has  " & _WordCount3( $text ) & "  words." & @CRLF & _
"The sentence  '" & $text & "'  has  " & _WordCount4( $text ) & "  words." )

; Your RegEx fails
Func _WordCount( $text )
    $sNewText = StringRegExpReplace( $text, "(\s){1,}[\W|_](\s){1,}|\R", "#", 0 )
    $iExtended = @extended
    ConsoleWrite($sNewText & @CRLF)
    Return $iExtended + 1    ; nr of spaces + 1 = wordcount
EndFunc

; This is functionally equivlent to...
Func _WordCount2( $text )
    $sNewText = StringReplace( StringRegExpReplace( $text, "(\s){1,}[\W|_](\s){1,}|\R", " ", 0 ), " ", "x")
    $iExtended = @extended
    ConsoleWrite($sNewText & @CRLF)
    Return $iExtended + 1    ; nr of spaces + 1 = wordcount
EndFunc

; ...this simple StringReplace
Func _WordCount3( $text )
    $sNewText = StringReplace($text, " ", "x")
    $iExtended = @extended
    ConsoleWrite($sNewText & @CRLF)
    Return $iExtended + 1    ; nr of spaces + 1 = wordcount
EndFunc

; But if you use a RegEx that actually works you get the count returned
Func _WordCount4( $text )
    $sNewText = StringRegExpReplace($text, "(\s+)", "#")
    $iExtended = @extended
    ConsoleWrite($sNewText & @CRLF)
    Return $iExtended + 1    ; nr of spaces + 1 = wordcount
EndFunc

As you can see in the SciTE console, no replacements are made with your RegEx, so the count is correct.

M23

Edit: In future please start a new thread rather than post in the Beta thread which is used to point out specific problems with the Beta rather than generic problems like this. I will split these posts off in a while.

Edit 2:

And split.

Edited September 15, 2014 by Melba23

[Guy_]

Thank you both.

This is a lesson to integrate error checking...

Why make it hard?

 

The codes are to filter out some specific stuff that I don't want to be counted as a real word.
And I thought it was working too... (maybe it is in part, just not in this example with only regular spaces)

Edited September 15, 2014 by Guy_

[Guy_]

Thx. This was my last bug report ever!    

[Melba23]

Guy_,

 

This was my last bug report ever!

By all means do report possible bugs - but as I said in your earlier thread, best to post in the forum first to get others to check.

And do some in depth errorchecking yourself as well, of course.

M23