SRE: how to find '12' and '23' from $sString = '123'

[mLipok]

I want to use code like this:

Local $sString = '123'
Local $aTest = StringRegExp($sString,'\d{2}',3)

But I want to do 'recursive' search I mean I want to get array with two items '12' and '23'

I think this is easy but my language skills (English) is my trouble in reading docs.

Can some body show me an solution ?

Thanks

mLipok

[guinness]

I would guess backtracking in the string would be key. One way I can think of is create a while loop or for loop (a loop) and set the offset by 1 on each iteration.

[Kovacic]

#include <MsgBoxConstants.au3>

; Retrieve the character position of where the string 'white' first occurs in the sentence.
Local $iPosition = StringInStr("This is a sentence with whitespace.", "white")
MsgBox($MB_SYSTEMMODAL, "", "The search string 'white' first appears at position: " & $iPosition)

StringinStr is what ya need.

[Kovacic]

Bonus function... Check to see if the spooler is running

$sccmpid = Run('sc query spooler', '', @SW_HIDE, 2)
local  $dataz = ""
do
 $dataz &= StdOutRead($sccmpid)
Until @error
If StringInStr($dataz, ' 4  RUNNING') then
   Msgbox(0,"Debug","spooler is running")
else
    Msgbox(0,"Debug","spooler is not running")
EndIf

Edited September 10, 2014 by Kovacic

[mLipok]

#include <MsgBoxConstants.au3>

; Retrieve the character position of where the string 'white' first occurs in the sentence.
Local $iPosition = StringInStr("This is a sentence with whitespace.", "white")
MsgBox($MB_SYSTEMMODAL, "", "The search string 'white' first appears at position: " & $iPosition)

StringinStr is what ya need.

 

No because in fact I need to search a group of 11 digits (EDIT: any sets of 11 digits.)

In OP i use

\d{2}

as an example.

Edited September 10, 2014 by mLipok

[mLipok]

I would guess backtracking in the string would be key.

I'll check it.

 

One way I can think of is create a while loop or for loop (a loop) and set the offset by 1 on each iteration.

Is not an option - too big source file, I think it would be inefficient method.

[Kovacic]

No because in fact I need to search a group of 11 digits (EDIT: any sets of 11 digits.)

In OP i use

\d{2}

as an example.

 

Yeah sorry, I guess I'm just not understanding what you are looking for. Best of luck on your endeavors

[jdelaney]

#include <array.au3>
Local $sString = '123'
Local $aTest = StringRegExp($sString,'(\d{2})',3)
Local $aTest2 = StringRegExp($sString,'\d(\d{2})',3)

_ArrayConcatenate($aTest,$aTest2)
_ArrayDisplay($aTest)

this is limitted to only work for 3 digits though...looks like a stringinstr loop is needed...or you have to do additional regexps until no more results, with increasingly odd counts of leading d.

Edited September 10, 2014 by jdelaney

[mLipok]

Ok i describe this in another way

Local $sSourceString = 'ab1234567890cd'

Func _Search($sSourceString, $iHowManyDigits)
.......
EndFunc

if  I use _Search($sSourceString, 2)  then I expect this results:

12
23
34
56
78
89
90

 

 

if  I use _Search($sSourceString, 3)  then I expect this results:

123
234
345
456
567
678
789
890

 

if  I use _Search($sSourceString, 9)  then I expect this results:

123456789
234567890

[guinness]

I understand your issue at least, no clue how people think StringInStr() could be used? I am thinking backtracking offset as a good keyword.

If mLipok uses _Search($sSourceString, 4) then the results...

1234
2345
3456
...

Edited September 10, 2014 by guinness

[guinness]

 

Bonus function... Check to see if the spooler is running

$sccmpid = Run('sc query spooler', '', @SW_HIDE, 2)
local  $dataz = ""
do
 $dataz &= StdOutRead($sccmpid)
Until @error
If StringInStr($dataz, ' 4  RUNNING') then
   Msgbox(0,"Debug","spooler is running")
else
    Msgbox(0,"Debug","spooler is not running")
EndIf

Interesting idea...

[UEZ]

Try this:

Local $sSourceString = 'ab1234567890cd'

_Search($sSourceString)
_Search($sSourceString, 4)
_Search($sSourceString, 6)
_Search($sSourceString, 9)

Func _Search($sSourceString, $iHowManyDigits = 2)
    Local $sNumbers = StringRegExpReplace($sSourceString, "[\D+]", "$1"), $iStringLen = StringLen($sNumbers), $i = 1
    Do
        $iNumber = StringMid($sNumbers, $i, $iHowManyDigits)
        If StringLen($iNumber) = $iHowManyDigits Then ConsoleWrite($iNumber & @CRLF)
        $i += 1
        If $i = $iStringLen + 1 Then ExitLoop
    Until False
    ConsoleWrite(@CRLF)
EndFunc

Br,

UEZ

Edited September 10, 2014 by UEZ

[kylomas]

and another partial SRE solution...

Local $sSourceString = 'ab1234567890cd'

ConsoleWrite(_interleave($sSourceString,7) & @CRLF)

func _interleave($str,$num=2)

    local $sRET = ''

    $str = stringregexpreplace($str,'\D','')

    for $1 = 1 to stringlen($str)

        if stringlen($str) - $1 < $num then return $sRET & stringmid($str,$1,$num) & @crlf

        $sRET &= stringmid($str,$1,$num) & @crlf

    Next

endfunc

[jguinch]

The question of this topic is very interesting...

I'm curious to know if there is a solution based on regexp only.

Something similar to kylomas code :

#Include <Array.au3>


$aResult = _ExtractNumbers('123456789101112131417', 2)
_ArrayDisplay($aResult)


Func _ExtractNumbers($sString, $iCount)
    If $iCount > StringLen($sString) Then Return SetError(1, 0, 0)
    If NOT StringRegExp($sString, "^\d+$") Then Return SetError(2, 0, 0)
    
    Local $aReturn[StringLen($sString) - $iCount + 1]
    
    For $i = 0 To UBound($aReturn) - 1
        $aReturn[$i] = StringMid($sString, $i + 1, $iCount)
    Next
    
    Return $aReturn
EndFunc

jchd, I see you are ready this topic I'm sure you have a great idea, no ?

[jchd]

For now I just have the idea to finish my dinner.

[guinness]

My initial idea I proposed in which I was too busy to create. Learning C right this very second.

#include <Array.au3>

Local $aResult = _ExtractNumbers('123456789101112131417', 5)
_ArrayDisplay($aResult)

Func _ExtractNumbers($sString, $iCount)
    Local $aReturn[StringLen($sString)], $aSRE = 0, _
            $iIndex = 0, $iOffSet = 1
    Do
        $aSRE = StringRegExp($sString, '\d{' & $iCount & '}', 3, $iOffSet)
        If @error Then ExitLoop
        $aReturn[$iIndex] = $aSRE[0]
        $iOffSet += 1
        $iIndex += 1
    Until False
    ReDim $aReturn[$iIndex]
    Return $aReturn
EndFunc   ;==>_ExtractNumbers

Edited September 10, 2014 by guinness

[mikell]

?

Local $sString = '12345'

Msgbox(0,"", _Search($sString, 3) )

Func _Search($sSource, $n)
    Local $sRET = ''
    For $i = 0 to StringLen($sSource)-$n
       $sRET &= StringRegExp(StringTrimLeft($sString, $i),'\d{' & $n & '}', 1)[0] & @crlf
    Next
    Return $sRET
EndFunc

[kylomas]

Ha, I got it...

#include <array.au3>

Local $sSourceString = 'ab1234567890cd'
local $cnt = 4

local $aRET = stringregexp($sSourceString,'(?=(\d{' & $cnt & '}))',3)
ConsoleWrite($aRET & @CRLF)
_arraydisplay($aRET)

[mLipok]

Very intresting.

But now one make this correct:, here are comparition:

expandcollapse popup

#include <Array.au3>



#Region mikell
Local $sString = 'ab1234567890cd'

;~ Subscript used on non-accessible variable.:
;~ Msgbox(0,"", _Search_mikell($sString, 3) )

Func _Search_mikell($sSource, $n)
    Local $sRET = ''
    For $i = 0 To StringLen($sSource) - $n
        $sRET &= StringRegExp(StringTrimLeft($sString, $i), '\d{' & $n & '}', 1)[0] & @CRLF
    Next
    Return $sRET
EndFunc   ;==>_Search_mikell

#EndRegion mikell


#Region guinness
MsgBox(0, 'guinness', '')
Local $aResult = _ExtractNumbers_guinness('ab1234567890cd', 9)
_ArrayDisplay($aResult)
$aResult = _ExtractNumbers_guinness('ab1234567890cd', 2)
_ArrayDisplay($aResult)
$aResult = _ExtractNumbers_guinness('ab 1234567890 cd', 3)
_ArrayDisplay($aResult)
$aResult = _ExtractNumbers_guinness('1234 ab 1234567890 cd 56878', 9)
_ArrayDisplay($aResult)

Func _ExtractNumbers_guinness($sString, $iCount)
    Local $aReturn[StringLen($sString)], $aSRE = 0, _
            $iIndex = 0, $iOffSet = 1
    Do
        $aSRE = StringRegExp($sString, '\d{' & $iCount & '}', 3, $iOffSet)
        If @error Then ExitLoop
        $aReturn[$iIndex] = $aSRE[0]
        $iOffSet += 1
        $iIndex += 1
    Until False
    ReDim $aReturn[$iIndex]
    Return $aReturn
EndFunc   ;==>_ExtractNumbers_guinness
#EndRegion guinness

#Region jguinch
MsgBox(0, 'jguinch', '')
Local $aResult = _ExtractNumbers_jguinch('ab1234567890cd', 9)
_ArrayDisplay($aResult)
$aResult = _ExtractNumbers_jguinch('ab1234567890cd', 2)
_ArrayDisplay($aResult)
$aResult = _ExtractNumbers_jguinch('ab 1234567890 cd', 3)
_ArrayDisplay($aResult)
$aResult = _ExtractNumbers_jguinch('1234 ab 1234567890 cd 56878', 9)
_ArrayDisplay($aResult)

Func _ExtractNumbers_jguinch($sString, $iCount)
    If $iCount > StringLen($sString) Then Return SetError(1, 0, 0)
    If Not StringRegExp($sString, "^\d+$") Then Return SetError(2, 0, 0)

    Local $aReturn[StringLen($sString) - $iCount + 1]

    For $i = 0 To UBound($aReturn) - 1
        $aReturn[$i] = StringMid($sString, $i + 1, $iCount)
    Next

    Return $aReturn
EndFunc   ;==>_ExtractNumbers_jguinch
#EndRegion jguinch

#Region kylomas
MsgBox(0, 'kylomas', '')

ConsoleWrite(_interleave('ab1234567890cd', 9) & @CRLF)
ConsoleWrite(_interleave('ab1234567890cd', 2) & @CRLF)
ConsoleWrite(_interleave('ab 1234567890 cd', 3) & @CRLF)
ConsoleWrite(_interleave('1234 ab 1234567890 cd 56878', 9) & @CRLF)

Func _interleave($str, $num = 2)

    Local $sRET = ''

    $str = StringRegExpReplace($str, '\D', '')

    For $1 = 1 To StringLen($str)

        If StringLen($str) - $1 < $num Then Return $sRET & StringMid($str, $1, $num) & @CRLF

        $sRET &= StringMid($str, $1, $num) & @CRLF

    Next

EndFunc   ;==>_interleave

#EndRegion kylomas


#Region UEZ
MsgBox(0, 'UEZ', '')
Local $sSourceString = 'ab1234567890cd'

_Search('ab1234567890cd', 9)
_Search('ab1234567890cd', 2)
_Search('ab 1234567890 cd', 3)
_Search('1234 ab 1234567890 cd 56878', 9)

Func _Search($sSourceString, $iHowManyDigits = 2)
    Local $sNumbers = StringRegExpReplace($sSourceString, "[\D+]", "$1"), $iStringLen = StringLen($sNumbers), $i = 1
    Do
        $iNumber = StringMid($sNumbers, $i, $iHowManyDigits)
        If StringLen($iNumber) = $iHowManyDigits Then ConsoleWrite($iNumber & @CRLF)
        $i += 1
        If $i = $iStringLen + 1 Then ExitLoop
    Until False
    ConsoleWrite(@CRLF)
EndFunc   ;==>_Search

#EndRegion UEZ

because as a results I still expect results which I show in post #9

EDIT: so I go back to studying and analyzing RegExp

Edited September 10, 2014 by mLipok

[mLipok]

and the winner is kylomas

edit:

thank you very much.

As I see it was probably the best puzzle today

Edited September 10, 2014 by mLipok