Is my syntax correct on a ping request?

[computergroove]

Im onsite at a restaurant where they are using IPAD POS machines. 3 Ipad's and 4 Network wired receipt printers. I have all the ip's and I want to know when one of the devices stops communicating to a ping. Is the following correct?

While 1
Local $Prn1 = Ping("192.168.1.200", 250)
Local $Prn2 = Ping("192.168.1.201", 250)
Local $Prn3 = Ping("192.168.1.202", 250)
Local $Prn4 = Ping("192.168.1.203", 250)
Local $Trm1 = Ping("192.168.1.207", 250)
Local $Trm2 = Ping("192.168.1.116", 250)
Local $Trn3 = Ping("192.168.1.14", 250)

If Not $Prn1 or $Prn2 or $Prn3 or $Prn4 or $Trm1 or $Trm2 or $Trm3 Then; also possible:  If @error = 0 Then ...
    Sleep(5000)
Else
    $sms = _SMS_Start($server,$email,$username,$password,$port,$ssl)
_SMS_Send($sms,$number,$service,$message)
send("{pause}")
EndIf
Wend

Can I identify which item caused the failing ping with the above code?

[computergroove]

I just removed the not in the if statement and I didnt get a response with msgbox. Something is not working

[computergroove]

expandcollapse popup

#include <MsgBoxConstants.au3>

While 1
Local $Prn1 = Ping("192.168.1.200", 250)
Local $Prn2 = Ping("192.168.1.201", 250)
Local $Prn3 = Ping("192.168.1.202", 250)
Local $Prn4 = Ping("192.168.1.203", 250)
Local $Trm1 = Ping("192.168.1.207", 250)
Local $Trm2 = Ping("192.168.1.116", 250)
Local $Trm3 = Ping("192.168.1.15", 250)

If $Prn1 Then; also possible:  If @error = 0 Then ...
    Sleep(5000)
Else
    MsgBox(0,"","Prn1 Stopped Communicating")
EndIf

If $Prn2 Then; also possible:  If @error = 0 Then ...
    Sleep(5000)
Else
    MsgBox(0,"","Prn2 Stopped Communicating")
EndIf

If $Prn3 Then; also possible:  If @error = 0 Then ...
    Sleep(5000)
Else
    MsgBox(0,"","Prn3 Stopped Communicating")
EndIf

If $Prn4 Then; also possible:  If @error = 0 Then ...
    Sleep(5000)
Else
    MsgBox(0,"","Prn4 stopped Communicating")
EndIf

If $Trm1 Then; also possible:  If @error = 0 Then ...
    Sleep(5000)
Else
    MsgBox(0,"","Waitstation by Kitchen Stopped Communicating")
EndIf

If $Trm2 Then; also possible:  If @error = 0 Then ...
    Sleep(5000)
Else
    MsgBox(0,"","Bar Terminal Stopped Communicating")
EndIf

If $Trm3 Then; also possible:  If @error = 0 Then ...
    Sleep(5000)
Else
    MsgBox(0,"","Terminal By Back Door Stopped Communicating")
EndIf
WEnd

This gave me what I wanted

[guinness]

Don't declare variables in loops. Declare outside a loop.

[jchd]

And maybe that with 520+ posts you could have taken the time and pain to learn how to store data in an array and iterate processing on its elements.

Local $aDevices = [ _
    ["192.168.1.200", "Prn1"], _
    ["192.168.1.201", "Prn2"], _
    ["192.168.1.202", "Prn3"], _
    ["192.168.1.203", "Prn4"], _
    ["192.168.1.207", "Waitstation by Kitchen"], _
    ["192.168.1.116", "Bar Terminal"], _
    ["192.168.1.15",  "Terminal By Back Door"] _
]

While 1
    For $i = 0 To UBound($aDevices) - 1
        If Ping($aDevices[$i][0], 250) Then
            Sleep(5000)
        Else
            MsgBox(0, "", $aDevices[$i][1] & " Stopped Communicating")
        EndIf
    Next
WEnd

[Gianni]

also,
if a device stops to comunicate for few seconds, will stop the entire loop and the msgbox stay on screen also if device returns on line,
another variant could be like this, so the msgbox stays on screen few seconds then will continue check and report again on next loop indicating all devices that are offline (if any), otherwise nothing is reported.

Local $aLan[7][2] = [ _
        ['192.168.1.200', 'Prn1'], _
        ['192.168.1.201', 'Prn2'], _
        ['192.168.1.202', 'Prn3'], _
        ['192.168.1.203', 'Prn4'], _
        ['192.168.1.207', 'Waitstation by Kitchen'], _
        ['192.168.1.216', 'Bar Terminal'], _
        ['192.168.1.15', 'Terminal By Back Door']]
Local $sMsg
While 1
    $sMsg = "" ; reset message
    For $i = 0 To UBound($aLan) - 1
        If Not Ping($aLan[$i][0], 250) Then $sMsg &= $aLan[$i][1] & @CRLF
    Next
    If $sMsg Then MsgBox(48, "Allert!", "Following devices are OFFLine:" & @CRLF & @CRLF & $sMsg, 5)
WEnd