Update to 3.3.12.0 giving Errors to old script

[Tum]

Hi,

Ive been using this script for a while now to send emails from my script.

This script was working fine when using AutoIt version 3.3.8.1

But now I have updated to 3.3.12.0 am getting errors.

Could any please explain what's causing the error ?

expandcollapse popup

#include <file.au3>
Global $oMyRet[2]
Global $oMyError = ObjEvent("AutoIt.Error", "MyErrFunc")
;=========================================================================
; Description : Send Emails using smtp servers, with username/password   =
;=========================================================================

Func _smtpEmail($s_SmtpServer, $s_FromName, $s_FromAddress, $s_ToAddress, $s_Subject = "", $as_Body = "", $s_AttachFiles = "", $s_CcAddress = "", $s_BccAddress = "", $s_Username = "", $s_Password = "",$IPPort=25, $ssl=0)
    $objEmail = ObjCreate("CDO.Message")
    $objEmail.From = '"' & $s_FromName & '" <' & $s_FromAddress & '>'
    $objEmail.To = $s_ToAddress
    Local $i_Error = 0
    Local $i_Error_desciption = ""
    If $s_CcAddress <> "" Then $objEmail.Cc = $s_CcAddress
    If $s_BccAddress <> "" Then $objEmail.Cc = $s_BccAddress
    $objEmail.Subject = $s_Subject
    If StringInStr($as_Body,"<") and StringInStr($as_Body,">") Then
        $objEmail.HTMLBody = $as_Body
    Else
        $objEmail.Textbody = $as_Body & @CRLF
    EndIf
    If $s_AttachFiles <> "" Then
        Local $S_Files2Attach = StringSplit($s_AttachFiles, ";")
        For $x = 1 To $S_Files2Attach[0]
            $S_Files2Attach[$x] = _PathFull ($S_Files2Attach[$x])
            If FileExists($S_Files2Attach[$x]) Then
                $objEmail.AddAttachment ($S_Files2Attach[$x])
            Else
                $i_Error_desciption = $i_Error_desciption & @lf & 'File not found to attach: ' & $S_Files2Attach[$x]
                SetError(1)
                return 0
            EndIf
        Next
    EndIf
    $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
    $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserver") = $s_SmtpServer
    $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = $IPPort
;Authenticated SMTP
    If $s_Username <> "" Then
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusername") = $s_Username
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendpassword") = $s_Password
    EndIf
    If $Ssl Then
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True
    EndIf
;Update settings
    $objEmail.Configuration.Fields.Update
; Sent the Message
    $objEmail.Send
    if @error then
        SetError(2)
        return $oMyRet[1]
    EndIf
EndFunc
;
;
; Com Error Handler
Func MyErrFunc()
    $HexNumber = Hex($oMyError.number, 8)
    $oMyRet[0] = $HexNumber
    $oMyRet[1] = StringStripWS($oMyError.description,3)
    ConsoleWrite("### COM Error !  Number: " & $HexNumber & "   ScriptLine: " & $oMyError.scriptline & "   Description:" & $oMyRet[1] & @LF)
    SetError(1); something to check for when this function returns
    Return
EndFunc ;==>MyErrFunc

This is the error that I keep getting.

"C:UsersDaveDesktopsmtpEmail.au3"(11,15) : error: missing separator character before keyword.
    $objEmail.To

 

I can see that the "$objEmail.To" is the problem, but it never use to be !

This was working fine when I was using 3.3.8.1

Edited August 9, 2014 by Tum

[guinness]

This is fixed in the betas. It was an issue with Au3Check and not AutoIt. You can disable Au3Check by placing #AutoIt3Wrapper_Run_Au3Check=N at the top of your script OR download the beta and copy across Au3Check. Your choice really.

Please mark as solved if it solved your issue. Thanks.

[Tum]

Hi,

Thanks for your quick reply.

Adding the code "#AutoIt3Wrapper_Run_Au3Check=N" to the top of my script fixed the issue.

But I did download the latest beta 3.3.13.16 (Beta), which didn't fix the issue.

The same issue is present in the latest beta.

[Jos]

So me you SciTE outputpane info to see what you do as au3check is really fixed.

Jos

[Tum]

 

>"C:\Program Files (x86)\AutoIt3\SciTE\AutoIt3Wrapper\AutoIt3Wrapper.exe" /run /prod /ErrorStdOut /in "C:UsersDaveDesktopsmtpEmail.au3" /UserParams   

+>11:28:33 Starting AutoIt3Wrapper v.2.1.0.33    Environment(Language:0409  Keyboard:00000809  OS:WIN_7/Service Pack 1  CPU:X64 OS:X64)

>Running AU3Check (3.3.12.0)  from:C:Program Files (x86)AutoIt3

"C:UsersDaveDesktopsmtpEmail.au3"(11,15) : error: missing separator character before keyword.

    $objEmail.To

~~~~~~~~~~~~~~^

C:UsersDaveDesktopsmtpEmail.au3 - 1 error(s), 0 warning(s)

!>11:28:33 AU3Check ended. Press F4 to jump to next error.rc:2

>Exit code: 0    Time: 0.313

 

 

Is this what you mean show you ?

This is from the latest beta version to.

Edited August 9, 2014 by Tum

[Jos]

You are running production probably done F5 here. Do Alt+F5 to run Beta.

You can also copy au3check from the Beta subdirectory to the AutoIt3 subdir so you can keep on using Production with a fixed au3check.

Jos

[Tum]

Ah, Thank you very much. Yes Alt F5 works fine.