how to check if a remote device is SNMP enabled?

[Gianni]

how can I know if an unknown device that responds to the PING command is SNMP enabled?

Thanks

Edited July 26, 2014 by Chimp

[jguinch]

Not sure at all, but maybe by checking the connection to the UDP ports 161 and 162 ?

[Gianni]

Hi jguinch, thanks for answer,

just tried to use UDPBind(IP, 161)  to a LAN printer that is SNMP enabled, but I get "Could not bind, code: 10049" error.

Also tried with UDPOpen(IP, 161) but with this command I always get "Connection successful." even with not pingable or wrong IP addresses

.... think there should be a better (and bulletproof  ) way

[mLipok]

Do you check here:

http://www.autoitscript.com/wiki/User_Defined_Functions#Internet_protocol_suite

and exactly here

[Gianni]

Hi mLipok, thanks for the answer

already tested that "Reading toner status", but it doesn't run on my system,

I get this error:

...wmi_toner_status.au3 (4) : ==> The requested action with this object has failed.:
$objWmiServices = $objWmiLocator.ConnectServer("", "rootsnmplocalhost")
$objWmiServices = $objWmiLocator.ConnectServer("", "rootsnmplocalhost")^ ERROR

anyway, it could be interesting, but I do not know if could be used to just check if a remote device is SNMP enabled.

[jguinch]

Try with rootsnmplocalhost  instead of rootsnmplocalhost

[Gianni]

Try with rootsnmplocalhost  instead of rootsnmplocalhost

 

Thanks  jguinch,

with your suggested syntax the above script now works, so now I can elaborate on it.

anyway, despite to that topic title ">Reading toner status from SNMP device" it seems instead that the script by ptrex show various of the device properties but the toner level. Also seems indeed that the posts on that topic are discussing about another script of that one  in the first post. However it's an interesting script that shows how to use SNMP via WMI.

I'm still searching an easy way on how to check if a network device is enabled to SNMP ....

Edited July 22, 2014 by Chimp

[Gianni]

according to what stated here, what I am in search of, should be an "SNMP Ping"

following the answer suggested here and taking this as example, I come out with this draft that first will scan your entire LAN for any IP device and then will try to get an snmp response from all the IP devices found alive . If an snmp response is returned, it is printed by ConsoleWrite().

Any improvements are welcome.

expandcollapse popup

#include <multiping.au3> ; <- download this from here: http://www.autoitscript.com/forum/topic/156395-versatile-multi-ping
#include <snmp_UDF-v1.7.4.au3> ; <- download this from here: http://www.autoitscript.com/forum/topic/81687-snmp-udf-for-snmpv1-and-snmpv2c
; #include <array.au3>

Global $Community[1]
; ------------------------------------------
; read community names from file if it exists
; ------------------------------------------
Local $line
Local $file = FileOpen(".\community.txt", 0) ; open file in read mode
If $file <> -1 Then ; Check if file opened for reading OK
    While 1 ; Read in lines of text until the EOF is reached
        $line = FileReadLine($file)
        If @error = -1 Then ExitLoop
        ReDim $Community[UBound($Community) + 1]
        $Community[UBound($Community) - 1] = $line
    WEnd
Else ; Error, unable to open file
    ReDim $Community[UBound($Community) + 1]
    $Community[1] = "public"
EndIf
$Community[0] = UBound($Community) - 1
FileClose($file)
; -------------------------------------
; discover all IP devices in local LAN
; and populate the $ipResults array
; -------------------------------------
ConsoleWrite(@CRLF & "searching all IP devices" & @CRLF)
Local $ipResults = _nPing()
ConsoleWrite("Found " & $ipResults[0][0] & " devices alive" & @CRLF)
; _ArrayDisplay($ipResults)

Global $Port = 161 ; UDP 161  = SNMP port
Global $SNMP_ReqID = 1
Global $SNMP_Command
Global $Result

; set $verbose to True to see snmp calls activity
Global $verbose = False ; output to consolewrite only devices responding to the snmp call

; -------------------------------
; search for snmp enabled devices
; -------------------------------
UDPStartup()
ConsoleWrite("now searching for snmp enabled devices" & @CRLF)
For $i = 1 To $ipResults[0][0] ; check for snmp on all IP devices
    $dest_IP = $ipResults[$i][0]
    $Socket = UDPOpen($dest_IP, $Port)
    Global $SNMP_OID = "1.3.6.1.2.1.1.1.0" ; ask to the device "What is your name?"
    For $ii = 1 To $Community[0] ; try with different community names (if more are available)
        If Not $verbose Then ConsoleWrite(".")
        $SNMP_Community = $Community[$ii]
        $SNMP_Version = 1
        $SNMP_Command = _SNMPBuildPacket($SNMP_OID, $SNMP_Community, $SNMP_Version, $SNMP_ReqID, "A0")
        UDPSend($Socket, $SNMP_Command)
        _StartListener()
        If @error Then ; try again with snmp V2
            If $verbose Then ConsoleWrite(@CRLF & $dest_IP & @TAB & "error: no snmp response with community name " & $SNMP_Community & @TAB & "snmp_V" & $SNMP_Version & @CRLF)
            $SNMP_Version = 2
            $SNMP_Command = _SNMPBuildPacket($SNMP_OID, $SNMP_Community, $SNMP_Version, $SNMP_ReqID, "A0")
            UDPSend($Socket, $SNMP_Command)
            _StartListener()
            If @error Then
                If $verbose Then ConsoleWrite(@CRLF & $dest_IP & @TAB & "error: no snmp response with community name " & $SNMP_Community & @TAB & "snmp_V" & $SNMP_Version & @CRLF)
            Else
                ConsoleWrite(@CRLF & $dest_IP & @TAB & "community name " & $SNMP_Community & @TAB & "snmp_V" & $SNMP_Version & @TAB & $SNMP_Util[1][1] & @CRLF) ; snmp v2
                ExitLoop
            EndIf
        Else
            ConsoleWrite(@CRLF & $dest_IP & @TAB & "community name " & $SNMP_Community & @TAB & "snmp_V" & $SNMP_Version & @TAB & $SNMP_Util[1][1] & @CRLF) ; snmp v1
            ExitLoop
        EndIf
    Next ; try wit another community name
Next ; next IP
ConsoleWrite(@CRLF & "end of scan" & @CRLF)

Func _StartListener($timeout = 250)
    Local $Timer = TimerInit(), $error = 1
    While TimerDiff($Timer) < $timeout
        $srcv = UDPRecv($Socket, 2048)
        If ($srcv <> "") Then
            $Result = _ShowSNMPReceived($srcv)
            $error = 0 ; no error, received data before the timeout
            ExitLoop
        EndIf
        Sleep(100)
    WEnd
    Return SetError($error)
EndFunc   ;==>_StartListener

Func OnAutoItExit()
    UDPCloseSocket($Socket)
    UDPShutdown()
EndFunc   ;==>OnAutoItExit

Edited July 26, 2014 by Chimp