AutoIt v3.3.13.6 Beta

[Jon]

File Name: AutoIt v3.3.13.6 Beta

File Submitter: Jon

File Submitted: 18 Jul 2014

File Category: Beta

3.3.13.6 (18th, 2014) (Beta)
AutoIt:
- Changed: Tables now called Maps. IsTable() now IsMap()
- Changed: All Is... functions and UBound() now using internal ByRef optimization.
- Changed: Numerous internal rewrites for Dim, Local, Global, Static. Function param passing. Testing needed!

- Added: Test versions for MapAppend(), MapExists(), MapKeys() - dot notation versions still available for now.

- Fixed: Regression with Dim $var = [1,2] syntax.

UDFs:
- Fixed: Undeclared variable in File.au3 due to internal changes.

Click here to download this file

[guinness]

A quick test...all seems in order.

expandcollapse popup

#AutoIt3Wrapper_Version=B
#AutoIt3Wrapper_Run_Au3Check=N

#include <Array.au3>

; Sleep(1000)

Dim $hTimer = TimerInit()
Local $aArray[10000]
For $i = 1 To 1000000
    UBound($aArray)
Next
ConsoleWrite(TimerDiff($hTimer) & @CRLF)

Local $mInternal[] ; Declare a Map
$mInternal["Internal"] = "AutoIt3" ; Assign an element

Local $mMain[] ; OK
$mMain["Bin"] = $mInternal ;  OK

For $i = 1 To 1000
    MapAppend($mMain, $i) ; OK
Next

ConsoleWrite('IsMap >> ' & IsMap($mInternal) & @CRLF) ; OK
ConsoleWrite('IsMap >> ' & IsMap($mMain["empty"]) & @CRLF) ; OK
ConsoleWrite('IsMap >> ' & IsMap($mMain["Bin"]) & @CRLF) ; OK

ConsoleWrite('MapExists >> ' & MapExists($mMain, "bin") & @CRLF) ; OK
ConsoleWrite('MapExists >> ' & MapExists($mMain, "Bin") & @CRLF) ; OK
ConsoleWrite('MapExists >> ' & MapExists($mMain["Bin"], "Bin") & @CRLF) ; OK
ConsoleWrite('MapExists >> ' & MapExists($mMain["Bin"], "Internal") & @CRLF) ; OK

Local $aMap = MapKeys($mMain)
_ArrayDisplay($aMap)

; MapAppend(), MapExists(), MapKeys() - dot notation versions still available for now.

[mLipok]

HelpFile 3.3.13.6 Issue #2802

Related
(), (), (), (), (), WinWaitDelay (Option), ()

[guinness]

 

HelpFile 3.3.13.6 Issue #2802

Related
(), (), (), (), (), WinWaitDelay (Option), ()

I broke it and fixed it.

[FaridAgl]

MapAppend() can be changed to MapPush(), also MapPop() and MapPeek() can be added.

In the following snippet there is no easy way to get value of the last element:

Global $map[]
MapAppend($map, "1")
$map["a"] = "a"
$map["b"] = "b"
MapAppend($map, "2")
MapAppend($map, "3")
$map["c"] = "c"

With MapPush/MapAppend, MapPop, MapPeek, this new type will be a hybrid Stack/Table/Map/AssociativeArray/KeyItemPair/Dictionary/Whatever!

[FaridAgl]

Also some new keywords can be added, something like MapEmpty which will be returned by MapPop and MapPeek when the map is empty, and something like MapInvalid when the variable passed to Map* function is not a valid map, and even MapNotFound when a not existing key's value has been requested.

Edited July 18, 2014 by FaridAgl

[oceanwaves]

just quick find:

Local $a = []
$a["tesing"] = 1

ConsoleWrite("= " & VarGetType($a) & " =" & @CRLF)
ConsoleWrite("= " & $a["testing"] & " =" & @CRLF)

so now the array = old array tpye + new map type? or just misunderstanding...

Edited July 18, 2014 by oceanwaves

[Mat]

MapAppend() can be changed to MapPush(), also MapPop() and MapPeek() can be added.

With MapPush/MapAppend, MapPop, MapPeek, this new type will be a hybrid Stack/Table/Map/AssociativeArray/KeyItemPair/Dictionary/Whatever!

 

You could have ordered maps, but you can't have ordered maps AND efficient lookups, and given that lookups is what maps are for, forget about using maps as stacks. Use an array, it's not hard and it would be faster and more appropriate.

[Melba23]

Jon,

Testing if a non-existent Map value is a Map seems to append the value to the Map:

#AutoIt3Wrapper_Run_Au3Check=N

#include <Array.au3>

Local $mMain[]
Local $mInternal[]

$mMain["Map"] = $mInternal

For $i = 1 To 10
    MapAppend($mMain, $i)
Next

$iRet = IsMap($mMain["Map"])            ; Test if there is a map in an existing key
ConsoleWrite($iRet & @CRLF)             ; There is

$iRet = IsMap($mMain[3])                ; Test if there is a map in an existing key
ConsoleWrite($iRet & @CRLF)             ; There is

$iRet = IsMap($mMain["I_do_not_exist"]) ; Test if there is a map in a non-existent key
ConsoleWrite($iRet & @CRLF)             ; There is not...

Local $aMap = MapKeys($mMain)
_ArrayDisplay($aMap)                    ; ...but look at the last entry <<<<<<<<<<<<<<<<<<

Given my >past record can someone else confirm this please!

M23

[guinness]

M23,

I guess you meant that second comment of IsMap() to read "; There is not" not "; There is"? But I can confirm there is an issue there with IsMap().

#AutoIt3Wrapper_Run_Au3Check=N

#include <Array.au3>

Local $mMain[]
Local $mInternal[]

$mInternal["Main"] = $mMain

$mMain["Map"] = $mInternal

For $i = 1 To 10
    MapAppend($mMain, $i)
Next

$iRet = IsMap($mMain["Map"]) ; Test if there is a map in an existing key
ConsoleWrite($iRet & @CRLF) ; There is

$iRet = IsMap($mMain[3]) ; Test if there is a map in an existing key
ConsoleWrite($iRet & @CRLF) ; There is not...

$iRet = IsMap($mMain["Map"]["Main"]) ; Test if there is a map in an existing key
ConsoleWrite($iRet & @CRLF) ; There is...

$iRet = IsMap($mMain["I_do_not_exist"]) ; Test if there is a map in a non-existent key
ConsoleWrite($iRet & @CRLF) ; There is not...

Local $aMap = MapKeys($mMain)
_ArrayDisplay($aMap) ; ...but look at the last entry <<<<<<<<<<<<<<<<<<

[jchd]

IsMap($vVar) is a sugar for (VarGetType($vVar) = "Map") but indeed it shouldn't cause the creation of a new entry in the map.

$iRet = IsMap($mMain[3]) actually returns 0 (the entry is the integer value 4, hence not a Map) (I just see guinness has a faster keyboard).

You can try my _VarDump function in separate post here to display complex varaible content... and report bugs.

[Jon]

Super subtle bug.

[Jon]

See if this fixes the map problem. Lots of significant changes...

http://www.autoitscript.com/autoit3/files/beta/autoit/AutoIt3_MapAppend.exe

[guinness]

That's fixed it.

[Melba23]

Jon,

 

See if this fixes the map problem

Fixed.

Lots of significant changes...

Anything in particular you want tested?

M23

[Jon]

The code touched all of arrays/for and function calls to all the Is... functions

[guinness]

Well they seem to be working well.

#AutoIt3Wrapper_Run_Au3Check=N
#include <MsgBoxConstants.au3>

Local $aArray[2] = [1, "Example"]
Local $dBinary = Binary("0x00204060")
Local $bBoolean = False
Local $hFunc = ConsoleWrite
Local $pPtr = Ptr(-1)
Local $hWnd = WinGetHandle(AutoItWinGetTitle())
Local $iInt = 1
Local $fFloat = 2.1
Local $mMap[]
Local $oObject = ObjCreate("Scripting.Dictionary")
Local $sString = "Some text"
Local $tStruct = DllStructCreate("wchar[256]")
Local $vKeyword = Default

MsgBox($MB_SYSTEMMODAL, "", "Variable Types" & @CRLF & "$aArray is an " & IsArray($aArray) & " variable type." & @CRLF & _
        "$dBinary is a " & IsBinary($dBinary) & " variable type." & @CRLF & _
        "$bBoolean is a " & IsBool($bBoolean) & " variable type." & @CRLF & _
        "$hFunc is a " & IsFunc($hFunc) & " variable type." & @CRLF & _
        "$pPtr is a " & IsPtr($pPtr) & " variable type." & @CRLF & _
        "$hWnd is a " & IsHWnd($hWnd) & " variable type." & @CRLF & _
        "$iInt is an " & IsInt($iInt) & " variable type." & @CRLF & _
        "$fFloat is a " & IsFloat($fFloat) & " variable type." & @CRLF & _
        "$mMap is a " & IsMap($mMap) & " variable type." & @CRLF & _
        "$oObject is a " & IsObj($oObject) & " variable type." & @CRLF & _
        "$sString is a " & IsString($sString) & " variable type." & @CRLF & _
        "$tStruct is a " & IsDllStruct($tStruct) & " variable type." & @CRLF & _
        "$vKeyword is a " & IsKeyword($vKeyword) & " variable type." & @CRLF)

[guinness]

Func _AssociativeArray_Startup(ByRef $aArray, $bIsCaseSensitive = False) ; Idea from MilesAhead.
    Local $bReturn = False
    $aArray = ObjCreate('Scripting.Dictionary')
    If IsObj($aArray) Then
        $aArray.CompareMode = ($bIsCaseSensitive ? 0 : 1)
        $bReturn = True
    EndIf
    Return $bReturn
EndFunc   ;==>_AssociativeArray_Startup

; This is broken in the current beta.
Local $hAssoc = 0
_AssociativeArray_Startup($hAssoc)
$hAssoc.Item('TestKey') = 'Test' ; It's added...but doesn't display when you remove the default method.
$hAssoc('TestKey_2') = 'Test_2' ; It's not added when using the default method.
MsgBox(4096, '', $hAssoc('TestKey') & @CRLF)  ; Workaround is to use $hAssoc.Item()
MsgBox(4096, '', $hAssoc.Item('TestKey_2') & @CRLF)
MsgBox(4096, '', $hAssoc.Item('TestKey') & @CRLF) ; OK when using .Item()

Edited July 20, 2014 by guinness

[jvanegmond]

Local $a[]
Local $b[]
Local $c[]

$a.Val = "a"
$b.Val = "b"
$c.Val = "c"

$a.Next = $b
$b.Next = $c

ConsoleWrite($a.Val & @CRLF)
ConsoleWrite($a.Next.Val & @CRLF)
ConsoleWrite($a.Next.Next.Val & @CRLF)

What's going on here? Why does this not print a, b and c but only a, b?

Also why is ConsoleWrite(($a.Next).Next.Val & @CRLF) allowed, but ConsoleWrite((($a.Next).Next).Val & @CRLF) gives me an error: (14) : ==> Missing right bracket ')' in expression.

Using AutoIt3_MapAppend.exe

Edited July 21, 2014 by Manadar

[jchd]

I ran this:

Local $a[]
Local $b[]
Local $c[]

$a.Val = "a"
$b.Val = "b"
$c.Val = "c"
ConsoleWrite(_VarDump($a) & @CRLF)

$a.Next = $b
ConsoleWrite(_VarDump($a) & @CRLF)
$b.Next = $c
ConsoleWrite(_VarDump($b) & @CRLF)

which displays:

Map[1]
      ['Val']          => String       (1) 'a'
Map[2]
      ['Val']          => String       (1) 'a'
      ['Next']         => Map[1]
            ['Val']          => String       (1) 'b'
Map[2]
      ['Val']          => String       (1) 'b'
      ['Next']         => Map[1]
            ['Val']          => String       (1) 'c'

Hope this makes the behavior clearer.