ResourcesEx UDF.

[guinness]

Ideally what I want to happen is for people to go through the code and scrutinise it. I mean I want to know if there are memory leaks or improvements to be made with what I have implemented.

Thanks.

[Melba23]

guinness,

Could I suggest that you add to the Remarks section for _Resource_LoadSound that you need to load the 2 types of sound files differently:

- mp3 as RT_RCDATA

- wav as SOUND

Otherwise you are going to get a lot of bug reports!

M23

[guinness]

Done. This will appear in the next release. Thanks.

[mLipok]

a few proposal for better code reading:

expandcollapse popup

#Region ResourcesEx.au3 - #VARIABLES#
; #VARIABLES# ===================================================================================================================
; Error enumeration flags.
Global Enum _
        $RESOURCE_ERROR_NONE, _
        $RESOURCE_ERROR_FINDRESOURCE, _
        $RESOURCE_ERROR_INVALIDCONTROLID, _
        $RESOURCE_ERROR_INVALIDCLASS, _
        $RESOURCE_ERROR_INVALIDRESOURCENAME, _
        $RESOURCE_ERROR_INVALIDRESOURCETYPE, _
        $RESOURCE_ERROR_LOCKRESOURCE, _
        $RESOURCE_ERROR_LOADBITMAP, _
        $RESOURCE_ERROR_LOADCURSOR, _
        $RESOURCE_ERROR_LOADICON, _
        $RESOURCE_ERROR_LOADIMAGE, _
        $RESOURCE_ERROR_LOADLIBRARY, _
        $RESOURCE_ERROR_LOADSTRING, _
        $RESOURCE_ERROR_SETIMAGE
Global Const _
        $RESOURCE_SS_ENHMETAFILE = 0xF
Global Const _
        $RESOURCE_SS_REALSIZECONTROL = 0x40
Global Const _
        $RESOURCE_STM_GETIMAGE = 0x0173
Global Const _
        $RESOURCE_STM_SETIMAGE = 0x0172
Global Const _
        $RESOURCE_LANG_DEFAULT = 0
Global Enum _
        $RESOURCE_RT_BITMAP = 1000, _
        $RESOURCE_RT_ENHMETAFILE, _
        $RESOURCE_RT_FONT
Global Const _
        $RESOURCE_STORAGE_GUID = 'CA37F1E6-04D1-11E4-B340-4B0AE3E253B6'
Global Enum _
        $RESOURCE_STORAGE, _
        $RESOURCE_STORAGE_FIRSTINDEX
Global Enum _
        $RESOURCE_STORAGE_ID, _
        $RESOURCE_STORAGE_INDEX, _
        $RESOURCE_STORAGE_RESETCOUNT, _
        $RESOURCE_STORAGE_UBOUND
Global Enum _
        $RESOURCE_STORAGE_DLL, _
        $RESOURCE_STORAGE_PTR, _
        $RESOURCE_STORAGE_RESLANG, _
        $RESOURCE_STORAGE_RESNAMEORID, _
        $RESOURCE_STORAGE_RESTYPE, _
        $RESOURCE_STORAGE_CASTRESTYPE, _
        $RESOURCE_STORAGE_LENGTH, _
        $RESOURCE_STORAGE_MAX, _
        $RESOURCE_STORAGE_ADD, _
        $RESOURCE_STORAGE_DESTROY, _
        $RESOURCE_STORAGE_DESTROYALL, _
        $RESOURCE_STORAGE_GET

; ===============================================================================================================================
#EndRegion ResourcesEx.au3 - #VARIABLES#

and this part:

If $aStorage[$i][$RESOURCE_STORAGE_DLL] = $sDLL And _
        $aStorage[$i][$RESOURCE_STORAGE_RESNAMEORID] = $sResNameOrID And _
        $aStorage[$i][$RESOURCE_STORAGE_RESTYPE] = $iResType And _
        $aStorage[$i][$RESOURCE_STORAGE_CASTRESTYPE] = $iCastResType Then
    $bReturn = __Resource_Destroy($aStorage, $i)
    If $bReturn Then
        $iDestoryed += 1
        $aStorage[$RESOURCE_STORAGE][$RESOURCE_STORAGE_RESETCOUNT] += 1 ; Increase the reset count.
    EndIf
    $iDestoryCount += 1
EndIf

I prospose to change like here:

If _
        $aStorage[$i][$RESOURCE_STORAGE_DLL] = $sDLL And _
        $aStorage[$i][$RESOURCE_STORAGE_RESNAMEORID] = $sResNameOrID And _
        $aStorage[$i][$RESOURCE_STORAGE_RESTYPE] = $iResType And _
        $aStorage[$i][$RESOURCE_STORAGE_CASTRESTYPE] = $iCastResType _
        Then

    $bReturn = __Resource_Destroy($aStorage, $i)
    If $bReturn Then
        $iDestoryed += 1
        $aStorage[$RESOURCE_STORAGE][$RESOURCE_STORAGE_RESETCOUNT] += 1 ; Increase the reset count.
    EndIf
    $iDestoryCount += 1
EndIf

Edited July 14, 2014 by mLipok

[guinness]

Thanks. The second part is going to change anyway in the next version.

[mLipok]

Great.
However I hope that the proposed concept, has gained favor.

I mean concept of multi line      "If ... Then"    constructions.

EDIT: wording

Edited July 14, 2014 by mLipok

[mLipok]

  On 7/14/2014 at 8:56 PM, mLipok said:

 

a few proposal for better code reading

 

some more proposal:

expandcollapse popup

Func _Resource_GetAsString($sResNameOrID, $iResType = $RT_RCDATA, $iResLang = Default, $sDLL = Default)
    Local _
            $iError = $RESOURCE_ERROR_LOADSTRING, _
            $iLength = 0, _
            $sString = ''

    Switch $iResType
        Case $RT_RCDATA
            Local $dBytes = _Resource_GetAsBytes($sResNameOrID, $iResType, $iResLang, $sDLL)
            $iError = @error
            $iLength = @extended

            If $iError = $RESOURCE_ERROR_NONE And $iLength > 0 Then ; Parse the data by retrieving the correct encoding.
                Local Enum _
                        $BINARYTOSTRING_NONE, _
                        $BINARYTOSTRING_ANSI, _
                        $BINARYTOSTRING_UTF16LE, _
                        $BINARYTOSTRING_UTF16BE, _
                        $BINARYTOSTRING_UTF8
                Local _
                        $iStart = $BINARYTOSTRING_NONE, _
                        $iUTFEncoding = $BINARYTOSTRING_ANSI
                Local Const _
                        $sUTF8 = '0xEFBBBF', _
                        $sUTF16BE = '0xFEFF', _
                        $sUTF16LE = '0xFFFE', _
                        $sUTF32BE = '0x0000FEFF', _
                        $sUTF32LE = '0xFFFE0000'
                Local _
                        $iUTF8 = BinaryLen($sUTF8), _
                        $iUTF16BE = BinaryLen($sUTF16BE), _
                        $iUTF16LE = BinaryLen($sUTF16LE), _
                        $iUTF32BE = BinaryLen($sUTF32BE), _
                        $iUTF32LE = BinaryLen($sUTF32LE)

                Select
                    Case BinaryMid($dBytes, 1, $iUTF32BE) = $sUTF32BE
                        $iStart = $iUTF32BE
                        $iUTFEncoding = $BINARYTOSTRING_ANSI
                    Case BinaryMid($dBytes, 1, $iUTF32LE) = $sUTF32LE
                        $iStart = $iUTF32LE
                        $iUTFEncoding = $BINARYTOSTRING_ANSI
                    Case BinaryMid($dBytes, 1, $iUTF16BE) = $sUTF16BE
                        $iStart = $iUTF16BE
                        $iUTFEncoding = $BINARYTOSTRING_UTF16BE
                    Case BinaryMid($dBytes, 1, $iUTF16LE) = $sUTF16LE
                        $iStart = $iUTF16LE
                        $iUTFEncoding = $BINARYTOSTRING_UTF16LE
                    Case BinaryMid($dBytes, 1, $iUTF8) = $sUTF8
                        $iStart = $iUTF8
                        $iUTFEncoding = $BINARYTOSTRING_UTF8
                EndSelect
                $iStart += 1 ; Increase by 1 to strip the byte order mark.
                $iLength = $iLength + 1 - $iStart
                $sString = BinaryToString(BinaryMid($dBytes, $iStart), $iUTFEncoding)
            EndIf
            $dBytes = 0

        Case $RT_STRING
            $sString = __Resource_Get($sResNameOrID, $iResType, $iResLang, $sDLL, $iResType)
            $iError = @error
            $iLength = @extended

    EndSwitch
    Return SetError($iError, $iLength, $sString)
EndFunc   ;==>_Resource_GetAsString

[UEZ]

I modified the example with the font example:

expandcollapse popup

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6

; Binary/text resources.
#AutoIt3Wrapper_Res_File_Add=binary_1.dat, RT_RCDATA, BIN_1, 0
#AutoIt3Wrapper_Res_File_Add=text_1.txt, RT_RCDATA, TXT_1, 0

; Cursor resources.
#AutoIt3Wrapper_Res_File_Add=banana.ani, RT_ANICURSOR, ANI_CUR_1

; Image resources.
#AutoIt3Wrapper_Res_File_Add=bmp_1.bmp, RT_BITMAP, BMP_1, 0
#AutoIt3Wrapper_Res_File_Add=gif_1.gif, RT_RCDATA, GIF_1, 0
#AutoIt3Wrapper_Res_File_Add=jpg_1.jpg, RT_RCDATA, JPG_1, 0
#AutoIt3Wrapper_Res_File_Add=png_1.png, RT_RCDATA, PNG_1, 0

; Icon resources.
#AutoIt3Wrapper_Res_File_Add=icon_1.ico, RT_ICON, ICO_1, 0

; Sound resources.
#AutoIt3Wrapper_Res_File_Add=C:\WINDOWS\Media\tada.wav, SOUND, WAV_1, 0

; String resources.
#AutoIt3Wrapper_Res_File_Add=string_1.ini, RT_STRING

; Font resources.
#AutoIt3Wrapper_Res_File_Add=SF Square Head Bold.ttf, RT_FONT, TTF, 0

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

#include '..\ResourcesEx.au3' ; Improved by guinness.

Global $g_hCursor = 0, $g_hGUI = 0

; Display only if compiled.
If @Compiled Then
    If IsXP() Then
        MsgBox($MB_SYSTEMMODAL, '', 'This example has been created for Vista and above. Therefore it''s recommended you change your system or the example. You choose.')
    Else
        Example()
    EndIf
Else
    MsgBox($MB_SYSTEMMODAL, '', 'Please compile before running.')
EndIf

Func Example()
    Local Const $iHeight = 450, $iWidth = 400
    $g_hGUI = GUICreate('Resources Example', $iWidth, $iHeight, Default, Default, BitOR($GUI_SS_DEFAULT_GUI, $WS_MAXIMIZEBOX, $WS_SIZEBOX))

    Local $iText_1 = GUICtrlCreateLabel('', 5, 300, 195, 60)
    Local $iDimensions = GUICtrlCreateLabel('', 200, 300, 200, 60)
    Local $iFont = GUICtrlCreateLabel("Different font loaded from resources", 5, 380, $iWidth - 10, 20)

    Local $iPic_1 = GUICtrlCreatePic('', 0, 0, 200, 100)
    Local $iPic_2 = GUICtrlCreatePic('', 200, 0, 200, 100)
    Local $iPic_3 = GUICtrlCreatePic('', 0, 100, 200, 100)
    Local $iPic_4 = GUICtrlCreatePic('', 200, 100, 200, 100)
    Local $iPic_5 = GUICtrlCreatePic('', 0, 200, 200, 100)

    Local $iIcon_1 = GUICtrlCreateIcon(Null, 0, 200, 205, 32, 32)

    Local $iLoadCursor = GUICtrlCreateButton('Load Cursor', 5, $iHeight - 30, 85, 25)
    Local $iLoadIcon = GUICtrlCreateButton('Load Icon', 90, $iHeight - 30, 85, 25)
    Local $iLoadSound = GUICtrlCreateButton('Load Sound', 175, $iHeight - 30, 85, 25)
    Local $iSaveFile = GUICtrlCreateButton('Save File', 260, $iHeight - 30, 85, 25)

    GUISetState(@SW_SHOW, $g_hGUI)

    ; Get as a string from the executable's resources.
    Local $sString = _Resource_GetAsString('TXT_1')
    GUICtrlSetData($iText_1, $sString)

    ; Get a bitmap image resource.
    Local $hBmp = _Resource_GetAsBitmap('BMP_1', $RT_BITMAP)
    ; Set the bitmap image handle to the $iPic_2 controlid.
    _Resource_SetImageToCtrlID($iPic_1, $hBmp)

    ; Set a gif image resource to a picture controlid.
    _Resource_SetToCtrlID($iPic_2, 'GIF_1')

    ; Set a jpg image resource to a picture controlid.
    _Resource_SetToCtrlID($iPic_3, 'JPG_1')

    ; Set a png image resource to a picture controlid.
    _Resource_SetToCtrlID($iPic_4, 'PNG_1')

    ; Set an image to a picture controlid using an external dll.
    _Resource_SetToCtrlID($iPic_5, '#701', $RT_BITMAP, @SystemDir & '\shell32.dll')

    ; Set a font resource to a label
    _Resource_LoadFont('TTF')
    GUICtrlSetFont($iFont, 16, 800, 0, 'SF Square Head', 5)

    ; Custom function to display the size of a specific resource.
    GUICtrlSetData($iDimensions, GetImageSize('BMP_1', $RT_BITMAP) & @CRLF & _
            GetImageSize('GIF_1') & @CRLF & _
            GetImageSize('JPG_1') & @CRLF & _
            GetImageSize('PNG_1') & @CRLF)

    Local $bIsCursor = False
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop

            Case $iLoadCursor
                If $bIsCursor Then
                    ; Remove the cursor.
                    _WinAPI_SetCursor(0)

                    ; Unregister the WM_CURSOR message.
                    GUIRegisterMsg($WM_SETCURSOR, '')

                    ; Destroy the cursor handle.
                    _WinAPI_DestroyCursor($g_hCursor)
                    $g_hCursor = 0
                Else
                    ; Retrieve the animated cursor and set to the current instance.
                    $g_hCursor = _Resource_GetAsCursor('ANI_CUR_1', $RT_ANICURSOR)
                    _WinAPI_SetCursor($g_hCursor)

                    ; Register the WM_CURSOR message to reinstate the cursor after is passes over a static control.
                    GUIRegisterMsg($WM_SETCURSOR, WM_SETCURSOR)
                EndIf
                $bIsCursor = Not $bIsCursor

            Case $iLoadIcon
                _Resource_SetToCtrlID($iIcon_1, 'ICO_1', $RT_ICON)

            Case $iLoadSound
                ; Play a wav from the executable's resources (sync/async).
                _Resource_LoadSound('WAV_1')
                _Resource_LoadSound('WAV_1', $SND_ASYNC)

            Case $iSaveFile
                ; Save binary data stored in the executable's resources.
                _Resource_SaveToFile(@ScriptDir & '\binary_data_1.dat', 'BIN_1')
                ShellExecute(@ScriptDir)

        EndSwitch
    WEnd

    ; Destroy all the resource handles.
    _Resource_DestroyAll()

    ; Delete the GUI.
    GUIDelete($g_hGUI)
    Return True
EndFunc   ;==>Example

Func GetImageSize($sResName, $iResType = $RT_RCDATA)
    Local $sString = ''
    Local $hImage = _Resource_GetAsImage($sResName, $iResType)
    If Not @error Then
        Local $iSize = @extended
        Local $iWidth = _GDIPlus_ImageGetWidth($hImage)
        Local $iHeight = _GDIPlus_ImageGetHeight($hImage)
        $sString = $sResName & ' is: ' & $iWidth & 'x' & $iHeight & ' and ' & $iSize & ' byte' & (($iSize = 1) ? '' : 's') & '.'
    EndIf
    Return $sString
EndFunc   ;==>GetImageSize

Func IsXP()
    Return $__WINVER < 0x0600
EndFunc   ;==>IsXP

Func WM_SETCURSOR($hWnd, $iMsg, $wParam, $lParam)
    #forceref $iMsg, $wParam, $lParam
    If $hWnd = $g_hGUI And $g_hCursor Then
        Return _WinAPI_SetCursor($g_hCursor)
    EndIf
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_SETCURSOR

 

SF Square Head Bold.ttf must be in examples folder.

 

Br,

UEZ

Edited July 14, 2014 by UEZ

[guinness]

Is that font allowed to be re-distributed? Plus where can I find it?

Edit: Only free for personal use >> http://www.dafont.com/sf-square-head.font

Edited July 14, 2014 by guinness

[UEZ]

Look into C:\Program Files (x86)\AutoIt3\Examples\Helpfile\Extras folder.

I cannot tell you whether it can be re-distribute or not.

Br,

UEZ

[guinness]

Thanks. I have added using ...

#AutoIt3Wrapper_Res_File_Add=%AUTOITDIR%\Examples\Helpfile\Extras\SF Square Head Bold.ttf, RT_FONT, TTF_1, 0

[mesale0077]

expandcollapse popup

#include <WindowsConstants.au3>
#include <APIGdiConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WinAPIGdi.au3>
#include "ResourcesEx.au3"

;#AutoIt3Wrapper_Res_File_Add=digital-7.ttf, RT_FONT, TTF, 0

Global $iWait = 500, $hDLL_User32 = DllOpen("user32.dll")
;~ _WinAPI_AddFontResourceEx(@ScriptDir & '\digital-7.ttf', $FR_PRIVATE)
;~ $sInternalFontname = _WinAPI_GetFontResourceInfo(@ScriptDir & '\digital-7.ttf', 1)
_Resource_LoadFont("TTF","",@ScriptDir & "\font.dll")
$Form1 = GUICreate("Form1", 300, 338, 192, 124, -1, BitOR($WS_EX_COMPOSITED, $WS_EX_LAYERED))
$Label1 = GUICtrlCreateLabel("", 72, 32, 120, 98)
GUICtrlSetFont(-1, 20, 800, 0, "digital-7")
GUICtrlSetColor(-1, 0x000000)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

GUIRegisterMsg($WM_TIMER, "CountDown")
DllCall($hDLL_User32, "int", "SetTimer", "hwnd", $Form1, "int", 0, "int", $iWait, "int", 0)

While 1

    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            GUIRegisterMsg($WM_TIMER, "")
            DllClose($hDLL_User32)
            GUIDelete($Form1)
;_WinAPI_RemoveFontMemResourceEx($hFont)
Exit
            Exit
    EndSwitch

WEnd


func CountDown()

GUICtrlSetData($Label1,@HOUR &":"& @MIN&":"&@SEC)
endfunc

dont read  font.dll      ,why?

_Resource_LoadFont("TTF","",@ScriptDir & "font.dll")

 bmp,icon, font ,,,,,,  read from dll,,,, example ?

http://www.mediafire.com/download/ch86v21a7fdyanc/font.dll

Edited July 15, 2014 by mesale0077

[guinness]

I can't download that font.dll for whatever reason. Sorry.

[guinness]

Updated the original post with a new version. This is a minor bug fix release.

Changelog:
2014/07/15
Added: Using _Resource_LoadFont() example. (Thanks UEZ)
Added: Option to to relevant functions to re-size the image based on the control's dimensions. (Requested by kinch: http://www.autoitscript.com/forum/topic/51103-resources-udf/?p=1147525)
Added: Comments about using SOUND for wav files and RT_RCDATA for mp3 files. (Thanks Melba23)
Changed: Constants and enums readability. (Thank mLipok)
Changed: Removed changes made from the previous version for loading resources multiple times. The design needs to be re-thought.
Changed: Certain example resources to now use those found in %AUTOITDIR%\Examples\Helpfile\Extras.
Changed: Setting styles of controls using native AutoIt functions.
Changed: Internal functions for destroying resources.
Fixed: Destroying control resource images would fail to show if reinstated again.
Fixed: Documentation comments.
Fixed: Missing certain users who helped with creating this UDF.
Fixed: Outdated SciTE files.

Edited July 15, 2014 by guinness

[guinness]

mesale0077,

I forgot to mention. About your suggestion for SWF, thanks, but it goes beyond the scope of the UDF.

[Bench]

What am I doing wrong?

#AutoIt3Wrapper_Res_File_Add=Resources\lite.png,rt_rcdata,LITE
#AutoIt3Wrapper_Res_File_Add=Resources\dark.png,rt_rcdata,DARK

Opt("GUIOnEventMode", 1)

#include <ButtonConstants.au3>
#include <GUIConstants.au3>

#include "ResourcesEx.au3"

If @Compiled Then
    $dll = @ScriptFullPath
Else
    $dll = "Resources.dll"
EndIf

$main = GUICreate("Test", 270, 140)
GUISetOnEvent($GUI_EVENT_CLOSE, "EndProgram")
$but1 = GUICtrlCreateButton("", 20, 20, 100, 100, BitOR($GUI_SS_DEFAULT_BUTTON, $BS_FLAT, $BS_BITMAP))
_Resource_SetToCtrlID($but1, "LITE", 10, $dll)
$but2 = GUICtrlCreateButton("", 150, 20, 100, 100, BitOR($GUI_SS_DEFAULT_BUTTON, $BS_FLAT, $BS_BITMAP))
_Resource_SetToCtrlID($but2, "DARK", 10, $dll)
GUISetState(@SW_SHOW, $main)

While True
    Sleep(100)
WEnd

Func EndProgram()
    GUIDelete($main)
    Exit
EndFunc

I used 2 differents pictures for 2 different buttons. I got just one button (second one on the place of first one, or maybe they are both there - stacked).

Size of any picture doesn't exactly fit buttons. Is it bug, feature or is problem in me?

Thx 4 answer.

[guinness]

New version. See the first post for more details.

Changelog:
2014/07/17
Added: Commented workaround in the example for re-sizing an icon control.
Added: ResourcesEx_PE.au3 created by PreExpand for all you constant variable haters out there!!!
Fixed: Changelog comments and source code comments.
Fixed: Re-sizing icons when the control was different to the icon's size. (Thanks czardas for the MSDN link and Jon.)
Fixed: Re-sizing cursors and icons in general.

[guinness]

Bench,

Could you test _GUICtrlButton_SetImage() and the try with a bitmap image instead. Would you also mind trying the old Resources UDF for me. Thanks.

[guinness]

Bench,

This works for me...

#AutoIt3Wrapper_Res_File_Add=%AUTOITDIR%\Examples\GUI\Advanced\Images\Red.bmp, RT_BITMAP, RED
#AutoIt3Wrapper_Res_File_Add=%AUTOITDIR%\Examples\GUI\Advanced\Images\Green.bmp, RT_BITMAP, GREEN

#include <ButtonConstants.au3>
#include <GUIConstants.au3>

#include "ResourcesEx.au3"

Example()

Func Example()
    Local $hGUI = GUICreate("Test", 270, 140)
    Local $iButton_1 = GUICtrlCreateButton("", 20, 20, 100, 100, $BS_BITMAP)
    Local $iButton_2 = GUICtrlCreateButton("", 150, 20, 100, 100, $BS_BITMAP)

    _Resource_SetToCtrlID($iButton_1, "RED", $RT_BITMAP)
    _Resource_SetToCtrlID($iButton_2, "GREEN", $RT_BITMAP)

    GUISetState(@SW_SHOW, $hGUI)

    While GUIGetMsg() <> $GUI_EVENT_CLOSE
    WEnd

    GUIDelete($hGUI)
EndFunc   ;==>Example

[guinness]

Hmm...I think the issue might be GUIGetStyle()?!

Edit: Reverted back to _WinAPI_SetWindowLong() approach instead. Update coming tomorrow, so Bench in the next version your code above should work. It did in the tests I conducted.

Edited July 17, 2014 by guinness