Adding 2 arrays together

[Chimaera]

Been working on this

$a1 = '1|2'
Local $ab1 = StringSplit($a1, "|")
_ArrayDisplay($ab1)
$b1 = '3|4'
Local $ab2 = StringSplit($b1, "|")
_ArrayDisplay($ab2)

$c1 = _ArrayConcatenate($ab1,$ab2)
ConsoleWrite( @error & @CRLF)
_ArrayDisplay($c1)

didnt work so then this

#include <Array.au3>

$a1 = '1|2'
Local $ab1 = StringSplit($a1, "|")
_ArrayDisplay($ab1)
$b1 = '3|4'
Local $ab2 = StringSplit($b1, "|")
_ArrayDisplay($ab2)

;~ $c1 = _ArrayConcatenate($ab1,$ab2)
;~ ConsoleWrite( @error & @CRLF)
;~ _ArrayDisplay($c1)

Local $c1[2][2] = [[$ab1], [$ab2]]
ConsoleWrite( @error & @CRLF)
_ArrayDisplay($c1)

It creates 2 colums but not the data, what im trying to end up with is this

 

1 3

2 4

Any suggestions where im going wrong?

[guinness]

This works? Please pay attention to the return value of _ArrayConcatenate().

#include <Array.au3>

Local $sString_1 = '1|2'
Local $aSplit = StringSplit($sString_1, '|', $STR_NOCOUNT)
Local $aArray_1[1][UBound($aSplit)]
For $i = 0 To UBound($aSplit) - 1
    $aArray_1[0][$i] = $aSplit[$i]
Next

Local $sString_2 = '3|4'
$aSplit = StringSplit($sString_2, '|', $STR_NOCOUNT)
Local $aArray_2[1][UBound($aSplit)]
For $i = 0 To UBound($aSplit) - 1
    $aArray_2[0][$i] = $aSplit[$i]
Next

_ArrayConcatenate($aArray_1, $aArray_2)
_ArrayDisplay($aArray_1)

Edited June 29, 2014 by guinness

[guinness]

Or this...

#include <Array.au3>

Local $sString_1 = '1|2'
Local $aSplit = StringSplit($sString_1, '|', $STR_NOCOUNT)
Local $aArray_1 = OneToTwoArray($aSplit)

Local $sString_2 = '3|4'
$aSplit = StringSplit($sString_2, '|', $STR_NOCOUNT)
Local $aArray_2 = OneToTwoArray($aSplit)

_ArrayConcatenate($aArray_1, $aArray_2)
_ArrayDisplay($aArray_1)

Func OneToTwoArray(ByRef $aArray)
    Local $iUBound = UBound($aArray)
    If $iUBound > 0 Then
        Local $aReturn[1][$iUBound]
        For $i = 0 To $iUBound - 1
            $aReturn[0][$i] = $aArray[$i]
        Next
        Return $aReturn
    EndIf
    Return Null
EndFunc   ;==>OneToTwoArray

Edit: Reused $iUBound. But the code is exactly the same. Edited June 30, 2014 by guinness

[mikell]

Why not play with _ArrayTranspose (integrated) 

#include <Array.au3>

$a1 = '1|2'
Local $ab1 = StringSplit($a1, "|", 2)
_ArrayTranspose($ab1)
$b1 = '3|4'
Local $ab2 = StringSplit($b1, "|", 2)
_ArrayTranspose($ab2)

_ArrayConcatenate($ab1,$ab2)
_ArrayTranspose($ab1)
_ArrayDisplay($ab1)

Edit

simpler

#include <Array.au3>

$a1 = '1|2'
Local $ab1 = StringSplit($a1, "|", 2)
_ArrayTranspose($ab1)
$b1 = '3|4'
_ArrayAdd($ab1, $b1)

_ArrayTranspose($ab1)
_ArrayDisplay($ab1)

Edited June 29, 2014 by mikell

[Chimaera]

Hmmm  thx guys, maybe im not explaining it very well none of those work as expected

@ guinness yours only show 

Col 0 Col1

  1        2

@ mikell

Col0

1

2

3

4

 

Im after the first array in col0 and the second array in col1

 

Col 0  Col1

  1        3

  2        4

 

Im trying to match in real life an installer and a silent switch

[guinness]

I am sure my first example was to your specification.

[Chimaera]

thats all i get

[czardas]

#include <Array.au3>

Local $a1[2] = [1,2]
Local $a2[2] = [3,4]
Local $a3[2][2]

For $i = 0 To 1
    $a3[$i][0] = $a1[$i]
    $a3[$i][1] = $a2[$i]
Next
_ArrayDisplay($a3)

[guinness]

Are you using v3.3.12.0?

Edit: I see mine output

1 2

3 4

But it still prints different to your screenshot.

Edited June 30, 2014 by guinness

[Chimaera]

Starting AutoIt3Wrapper v.2.1.4.4 SciTE v.3.3.7.0 ;  Keyboard:00000809  OS:WIN_81/  CPU:X64 OS:X64    Environment(Language:0409  Keyboard:00000809  OS:WIN_81/  CPU:X64 OS:X64)

>Running AU3Check (3.3.10.2) 

 

Just updated to Running AU3Check (3.3.12.0)  from:C:Program Files (x86)AutoIt3

And it shows correctly now albiet the wrong way round

 

yours

Col 0  Col1

  1        2

  3        4

 

what im after

Col 0  Col1

  1        3

  2        4

 

but ill keeep working at it

Thx again

Edited June 30, 2014 by Chimaera

[guinness]

Did you try mikell's code?

[Chimaera]

Just checked and thats the one, it didnt work before probably because of the autoit version

Many thanks

[UEZ]

Here another, maybe freaky, way:
 

expandcollapse popup

#include <Array.au3>

$a1 = '1|2'
Local $ab1 = StringSplit(StringReverse($a1), "|", 2)
_ArrayTranspose($ab1)
$b1 = '3|4'
_ArrayAdd($ab1, StringReverse($b1))
$aResult = _ArrayRotate($ab1, -90)

_ArrayDisplay($aResult)

Func _ArrayRotate($aArray, $iDeg) ;coded by UEZ 2012 build 2012-02-15
    If Not IsArray($aArray) Then Return SetError(1, 0, 0) ;not an array
    If Not UBound($aArray, 0) = 2 Then Return SetError(2, 0, 0) ;not a 2D array
    If Mod($iDeg, 90) Then Return SetError(3, 0, 0) ;only 90° rotations allowed
    Local $i, $j, $k = 0, $l = 0
    Switch $iDeg
        Case 90, -270
            Local $aRotated[UBound($aArray, 2)][UBound($aArray)]
            For $i = 0 To UBound($aArray, 2) - 1
                For $j = UBound($aArray) -1 To 0 Step - 1
                    $aRotated[$i][$k] = $aArray[$j][$i]
                    $k += 1
                Next
                $k = 0
            Next
            Return $aRotated
        Case 270, -90
            Local $aRotated[UBound($aArray, 2)][UBound($aArray)]
            For $i = UBound($aArray, 2) - 1 To 0 Step - 1
                For $j = 0 To UBound($aArray) - 1
                    $aRotated[$l][$k] = $aArray[$j][$i]
                    $k += 1
                Next
                $l += 1
                $k = 0
            Next
            Return $aRotated
        Case 180, -180
            Local $aRotated[UBound($aArray)][UBound($aArray, 2)]
            For $i = UBound($aArray) - 1 To 0 Step - 1
                For $j = UBound($aArray, 2) - 1 To 0 Step - 1
                    $aRotated[$l][$k] = $aArray[$i][$j]
                    $k += 1
                Next
                $l += 1
                $k = 0
            Next
            Return $aRotated
    EndSwitch
EndFunc

Br,

UEZ

[czardas]

There are different methods, but you should try to understand how they work. In that sense my illustration is the simplest to learn from. You must (at least) be able to work this out for yourself using native functions only. It is also the most efficient method in this particular case: because it requires no transposition.

Consider this: what do you intend to do when the arrays are of different sizes?

Edited June 30, 2014 by czardas

[Oscis]

#Include <array.au3>
Opt("MustDeclareVars",1)
Local $a1 = '1|2'
Local $ab1 = StringSplit($a1, "|",2)
_ArrayDisplay($ab1)
Local $b1 = '3|4'
Local $ab2 = StringSplit($b1, "|",2)
_ArrayDisplay($ab2)
Local $c1 = _CombineArrays($ab1, $ab2)
_ArrayDisplay($c1)
Func _CombineArrays(ByRef $Array, ByRef $Array2)
    Local $CMax = UBound($Array)
    Local $Array3[$CMax][2]
    $CMax -= 1
    For $C = 0 to $CMax
        $Array3[$C][0] = $Array[$C]
        $Array3[$C][1] = $Array2[$C]
    Next
    Return $Array3
EndFunc

I noticed czardas' code after I already typed this up. He does in fact have the most efficient solution. I decided to post what I had anyway, in case you wanted to see a more general implementation.

[Chimaera]

Consider this: what do you intend to do when the arrays are of different sizes?

 They wont be because each exe has a silent switch and/or doesn't which is a blank space , this now loads the exes from one part of the ini file and the switches from another like this example and lines them up ready for use.

This is just a small part of the whole obviously but you will get the idea.

Im probably not going about this the best way but you kinda go with what you know i guess.

Many thanks to all for the help

Edited June 30, 2014 by Chimaera

[UEZ]

Why do you want one 2D array instead of 2x 1D arrays? It's much easier to use 2x 1D arrays.

The Ubound of both 1D arrays must be the same thus you can read one array with the path and associate the parameters from the 2nd array.

 

Br,

UEZ

[czardas]

UEZ makes a good point.

In any case, the orientation of your 2D array is irrelevant. When reading or writing to an array, you can loop first through columns followed by rows, or vice versa. You can loop either backwards or forwards. The standard layout of a table (or 2D array) is for aesthetic purposes only. Think of a chess game: it doesn't make any difference which side of the board you sit or which colour pieces are yours. The only difference is your own visual perspective.

Edited June 30, 2014 by czardas

[Chimaera]

I'm not sure it makes any difference to me as long as the switch is postioned at the end of the program, its more a way of keeping the 2 together so i can access the data

I haven't got as far as how to call the installer and the switch yet but ill get to it

I guess im just working towards a way of holding the data together, i suppose i could have pulled it from an excel sheet who knows..

I still haven't worked out the msi installers which will have to be in Case statements i think, early days yet

[kylomas]

Chimaera,

A generalized way of concatenating arrays such that each array is a column of the reuslting 2D array.  The arrays can be of any size.

expandcollapse popup

#include <array.au3>

local $a1[20] = [1,2,3,4,5,6,7,8,9,0,1,2,3,4,5,6,7,8,9,0]
local $a2[10] = [1,2,3,4,5,6,7,8,9,0]
local $a3[50] = ['','',3,4,5,6,7,8,9,0,1,2,3,4,5,6,7,8,9,0,1,2,3,4,5,6,7,8,9,0,1,2,3,4,5,6,7,8,9,0]
local $a4[5] = [1,2,3,4,5]
local $ax[1]
local $MyGoofyArray[3]  =   ['Mo', 'Larry', 'Curly']
local $a5[7] = [1,2,3,4,5,6,7]

local $a10 = _array_combine($a1,$a2,$a3,$ax,$a4,$a5,$MyGoofyArray)

_arraydisplay($a10)

func _array_combine($arr1,$arr2,$arr3=0,$arr4=0,$arr5=0,$arr6=0,$arr7=0,$arr8=0,$arr9=0,$arr10=0)

    ;-----------------------------------------------------------------------------------------------------------------
    ; combine 2 to 10 1D arrays into 1 2D array
    ;-----------------------------------------------------------------------------------------------------------------

    ; ensure at least two arrays
    if not IsArray($arr1) or not IsArray($arr2) then return seterror(1,0,0)

    ; find # of arrays passed ($1 = # of arrays)
    for $1 = 1 to 10
        if not isarray(eval("arr" & $1)) then ExitLoop
    Next

    ; set # of cols variable to # of arrays in parameter
    local $num_cols = $1 - 1
    local $max_rows = 0

    ; set # elements to largest array passed
    for $1 = 1 to $num_cols
        if ubound(eval("arr" & $1)) - 1 > $max_rows then $max_rows = ubound(eval("arr" & $1))
    next

    ConsoleWrite('Formatting target array as ' & $num_cols & ' columns and ' & $max_rows & ' elements.' & @LF)

    ; define result array
    local $aTarget[$max_rows][$num_cols], $aTemp

    ; populate result array
    for $1 = 0 to $num_cols -1
        $aTemp = eval("arr" & $1+1)
        for $2 = 0 to ubound($aTemp) - 1
            $aTarget[$2][$1] = $aTemp[$2]
        Next
    next

    return $aTarget

endfunc