Regular expression to parse simple arithmetic or similar.

[guinness]

It's not because I am lazy, I believe many hands make light work and this is for PreExpand which will benefit the community anyway. Your input is greatly appreciated in creating a regular expression that can parse simple arithmetic expressions such as ((1 + -10) /809) or 1 + 9, though a different method can be considered if you don't like regexp. Speed isn't an issue, though something that takes 10 minutes to parse isn't ideal of course.

Thanks.

PS I guess this can be constituted as another game!

Edited June 25, 2014 by guinness

[jdelaney]

I suppose Execute() would be cheating then .

[guinness]

I suppose Execute() would be cheating then .

I think you misunderstood. I want to parse a script to find the expressions so I can then use Execute() to evaluate that expression (or my Shunting-Yard UDF).

[jdelaney]

Ah, so a regexp that includes only things that would be in an expression...got it.  Do you have a small text example?

Maybe this, as the regexp:  

#include <Array.au3>
$string = "some text ((1 + -10) /809) or 1 + 9"
$regexp = "\s?([\d\+\/\-\*\s\^\(\)]{3,})\s?"
$a = StringRegExp($string, $regexp, 3)
_ArrayDisplay($a)

Edited June 25, 2014 by jdelaney

[guinness]

Example.

$sExample = 10 + 100 / 29
ConsoleWrite($sExample & @CRLF)
ConsoleWrite((100 / 90) * 7001 & @CRLF)

#include <Array.au3>

$aSRE = StringRegExp(ClipGet(), '([\d+\-*\\\s\^\(\)]+)', $STR_REGEXPARRAYGLOBALMATCH)
_ArrayDisplay($aSRE)

It's getting there with that regular expression. Notice I escaped -.

[UEZ]

Is this the result you want?

#include <Array.au3>
$string = "some text ((1 + -10) /809) or 1 + 9"
$regexp = "\s?([\d\+\/\-\*\s\^\(\)]{3,})\s+?"
$a = StringRegExp($string, $regexp, 3)
For $i = 0 To UBound($a) - 1
    $string = StringReplace($string, $a[$i], Execute($a[$i]))
Next
ConsoleWrite($string & @CRLF)

Br,

UEZ

[jdelaney]

Don't forget to include a decimal, as well (i've modified my prior example, but have not included the ".")

Edited June 25, 2014 by jdelaney

[guinness]

Thanks UEZ. I added . to the class as jdelaney pointed out.

[guinness]

The regular expression I am currently testing...

\h?([\d\+\/\-\*\h\^\(\).]{3,})(?:\h+|,)?

[guinness]

This is why it's not as easy as I envisaged. Notice Chr(1).

#include <Array.au3>

$sData = FileRead(@ScriptFullPath)
$sPattern = "\s?([\d\+\/\-\*\s\^\(\)]{3,})\s+?"

$aSRE = StringRegExp($sData, $sPattern, $STR_REGEXPARRAYGLOBALMATCH)
For $i = 0 To UBound($aSRE) - 1
    $sExecute = Execute(StringStripWS($aSRE[$i], $STR_STRIPALL))
    If Not @error Then
        $sData = StringReplace($sData, $aSRE[$i], $sExecute)
    EndIf
Next
ConsoleWrite($sData & @CRLF)

; Testing scenarios.
Chr(1)
SetError(@error, 20, True)
Local Const $sTest = 10 + 10 + 10, $vExample = 100 - 1

[jchd]

I don't know if this is what you need but here's what I believe a simple arithmetic parser limited to integers (including hex), reals and macros (not checked for existence but could be even if painful):

expandcollapse popup

#include <StringConstants.au3>

Local $numberREdef =                '(?(DEFINE) (?<number> 0x [[:xdigit:]]{1,16} | \d* \. \d+ | \d{1,19} ) )'
Local $macroREdef =                 '(?(DEFINE) (?<macro> @ [a-z_]+\w* ) )'
Local $valueREdef =                 '(?(DEFINE) (?<value> [+-]? (?: (?&number) | (?&macro) ) ) )'
Local $operatorREdef =              '(?(DEFINE) (?<operator> [-+*/^] ) )'
Local $subexpressionREdef =         '(?(DEFINE) (?<subexpression> (?&value) (?: (?&operator) (?&subexpression) )* | \( (?&subexpression) \) ) )'
Local $expressionREdef =            '(?(DEFINE) (?<expression> (?&subexpression) (?: (?&operator) (?&expression) )* | \( (?&expression) \) ) )'
Local $pattern = "(?ix)" & $numberREdef & $macroREdef & $valueREdef & $operatorREdef & $subexpressionREdef & $expressionREdef & "^(?&expression)$"

Local $aTest = [ _
    "+123", _                            ; good boys
    "1-+2", _
    "1 + 2 / 5 + 5 --6", _
    "3*( -1+ 2 )", _
    "(1+(((1)))+1)+7*(5+3/(1+(1)/1))", _
    "(1+2*3+(-2))", _
    "((1+2)*(3/4))", _
    "-.1", _
    "@NumParams + 0x45*3/5", _
    "0x12 * -5", _
    "3-a +1", _                            ; horrors
    "1+$a", _
    "15 > 2", _
    "(123 + 5", _
    "++12", _
    "0x + 5", _
    "0x333333333333333333333333333333333 + 5", _
    "@123 * 5", _
    "^8", _
    "6*", _
    "123+()", _
    "-1.2.3", _
    "(123+5*(12+)7)" _
]

For $s In $aTest
    Local $ns = StringStripWS($s,  $STR_STRIPALL)
    Local $ret = StringRegExp($ns, $pattern)
    ConsoleWrite($s & " --> " & $ns & " --> " & $ret & @LF)
Next

It's far from perfect: it doesn't check numerical boundaries for instance. Yet it will bark at many ill-formed expressions.

I suspect that the subexpression level is superfluous. I'll look at that sometime soon.

Edited June 26, 2014 by jchd

[guinness]

Thanks jchd. I will test this in the evening. Very much appreciate for your input.

[czardas]

I have done some simple tests for numbers => _StringIsNumber(). I don't know if the expressions will be of much use to you, but you might want to look.

http://www.czardas.co.uk/repository/stringf.au3

Edited June 26, 2014 by czardas

[guinness]

Thanks czardas.

[jchd]

I didn't try hard due to lack of time but I didn't succeed in getting rid of the intermediary subexpression level. From what I suspect it's needed to cope with every possible use of parenthesis, but I'm not 100% certain of that.

Anyway, if that proves useful to someone, here's a version allowing variables (including array elements):

expandcollapse popup

#include <StringConstants.au3>

Local $numberREdef =                '(?(DEFINE) (?<number> 0x [[:xdigit:]]{1,16} | \d* \. \d+ | \d{1,19} ) )'
Local $macroREdef =                 '(?(DEFINE) (?<macro> @ [a-z_]+\w* ) )'
Local $variableREdef =              '(?(DEFINE) (?<variable> \$ \w+ (?: \[ (?&expression) \]){0,16} ) )'
Local $valueREdef =                 '(?(DEFINE) (?<value> [+-]? (?: (?&number) | (?&macro) | (?&variable) ) ) )'
Local $operatorREdef =              '(?(DEFINE) (?<operator> [-+*/^] ) )'
Local $subexpressionREdef =         '(?(DEFINE) (?<subexpression> (?&value) (?: (?&operator) (?&subexpression) )* | \( (?&subexpression) \) ) )'
Local $expressionREdef =            '(?(DEFINE) (?<expression> (?&subexpression) (?: (?&operator) (?&expression) )* | \( (?&expression) \) ) )'
Local $pattern = "(?ix)" & $numberREdef & $macroREdef & $variableREdef & $valueREdef & $operatorREdef & $subexpressionREdef & $expressionREdef & "^(?&expression)$"

Local $aTest = [ _
    "+123", _                           ; good boys
    "1-+2", _
    "1 + 2 / 5 + 5 --6", _
    "3*( -1+ 2 )", _
    "(1+(((1)))+1)+7*(5+3/(1+(1)/1))", _
    "(1+2*3+(-2))", _
    "((1+2)*(3/4))", _
    "@123 * 5", _
    "$test[2][3] + @AutoItPID * $var[$i + 3*$j]", _
    "-.1", _
    "@NumParams + 0x45*3/5", _
    "1+$a", _
    "0x123 * -5", _
    "3-a +1", _                         ; horrors
    "15 > 2", _
    "(123 + 5", _
    "++12", _
    "0x + 5", _
    "0x5555555555555555555555555555 + 5", _
    "$a[2", _
    "^8", _
    "123+()", _
    "(123+5*(12+)7)" _
]

For $s In $aTest
    Local $ns = StringStripWS($s,  $STR_STRIPALL)
    Local $ret = StringRegExp($ns, $pattern)
    ConsoleWrite($s & " --> " & $ns & " --> " & $ret & @LF)
Next

Minor known bug: I remove whitespaces to simplify regexps but this has the drawback that an invalid expression involving a macro or flat variable followed by space(s) and then digits gets mangled, which could result in the expression being declared valid unduly.