using arrow keys on UpDown control?

[Mic]

Have the #include and have setting vert or horz arrow keys for this control without success. Is there a working example of this? tia.

[Melba23]

Mic,

Your question is unclear - what exactly are you trying to do?

M23

[Mic]

I guess I'm old too :-) - trying to get the arrow keys to increment/decrement value of the UpDown control when it is selected. Have #include <UpDownConstants.au3> and $UDS_ARROWKEYS but the arrow keys are not altering control.

[Melba23]

Mic,

The easiest way is to use _IsPressed:

#include <GUIConstantsEx.au3>
#include <Misc.au3>

Local $hDLL = DllOpen("user32.dll")

$hGUI = GUICreate("Test", 500, 500)

$cInput = GUICtrlCreateInput(100, 10, 10, 200, 20)
GUICtrlCreateUpdown($cInput)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            DllClose($hDLL)
            Exit
    EndSwitch

    If _IsPressed("26", $hDLL) Then ; Up
        GUICtrlSetData($cInput, GUICtrlRead($cInput) + 1)
        Sleep(100)
    ElseIf _IsPressed("28", $hDLL) Then ; Down
        GUICtrlSetData($cInput, GUICtrlRead($cInput) - 1)
        Sleep(100)
    EndIf
WEnd

Good enough - or do we have to get fancy?

M23

[mrider]

 

The easiest way is to use _IsPressed:

Or else using $UDS_ARROWKEYS

#include <GUIConstantsEx.au3>
#include <UpdownConstants.au3>

$hGUI = GUICreate("Test", 500, 500)

$cInput = GUICtrlCreateInput(100, 10, 10, 200, 20)
GUICtrlCreateUpdown($cInput, $UDS_ARROWKEYS)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

[EDIT] I kept leaving in the DLL stuff...

Edited June 24, 2014 by mrider

[iamtheky]

I vote that should be default behavior, and you should have to specify $UDS_NoArrowKeys

[Melba23]

mrider,

Nice catch - learnt something new (again)!

M23

[Mic]

Thanks for the working examples. I am using $UDS_ARROWKEYS from within ISN AutoIt Studio where arrow keys are not changing control values .... the working example will allow me to debug this - thanks again!

[Mic]

removing ISN from the equation for the moment and using the $cinput example above, I can set the default with

    GUICtrlSetData($cinput, 5)

but 

   GUICtrlSetLimit( $cinput, 30, 0)

does not set the max and min for this control ... it's 'cos I'm old, right? :-)

 

   

[mrider]

That fails because you are setting the limit on the input box, not the up/down control.

BAD:

#include <GUIConstantsEx.au3>
#include <UpdownConstants.au3>
$hGUI = GUICreate("Test", 500, 500)
$cInput = GUICtrlCreateInput(10, 10, 10, 200, 20)
GUICtrlCreateUpdown($cInput, $UDS_ARROWKEYS)
GUICtrlSetLimit($cInput, 30)
GUICtrlCreateButton("Button", 10, 60)

GUISetState()
While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

GOOD:

#include <GUIConstantsEx.au3>
#include <UpdownConstants.au3>
$hGUI = GUICreate("Test", 500, 500)
$cInput = GUICtrlCreateInput(10, 10, 10, 200, 20)
GUICtrlCreateUpdown($cInput, $UDS_ARROWKEYS)
GUICtrlSetLimit(-1, 30)
GUICtrlCreateButton("Button", 10, 60)

GUISetState()
While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Edited June 24, 2014 by mrider

[mrider]

Two other things to keep in mind:

1. You might consider $ES_NUMBER as part of the style in the input field.
2. GUICtrlSetLimit won't block direct input into the text field, you'll need to enforce that yourself.  Unless someone knows something about up/down controls that I don't - which is a distinct possibility.

A better version:

#include <GUIConstantsEx.au3>
#include <UpdownConstants.au3>
#include <GuiEdit.au3>


Global Const $MIN = 0
Global const $MAX = 30
$hGUI = GUICreate("Test", 500, 500)
$cInput = GUICtrlCreateInput("10", 10, 10, 200, 20, $ES_NUMBER)
GUICtrlCreateUpdown($cInput, BitOR($UDS_ARROWKEYS, $UDS_NOTHOUSANDS))
GUICtrlSetLimit(-1, $MAX, $MIN)

GUISetState()
While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

    Local $value = Number(GUICtrlRead($cInput))
    If $value < $MIN Then
        GUICtrlSetData($cInput, $MIN)
    ElseIf $value > $MAX Then
        GUICtrlSetData($cInput, $MAX)
    EndIf
WEnd

[Mic]

Thanks for all the info - all works without ISN's attempt to automatically do this with "click and point" - am coding UpDowns manually.