The bumper thread of missing winapi examples.

[mLipok]

#2762 for _WinAPI_GetDriveType()

[guinness]

#include <MsgBoxConstants.au3>
#include <WinAPIFiles.au3>

Example()

Func Example()
    ; Find the drive type of the home drive, generally this is the C:\ drive.
    Local $iTypeOfDrive = _WinAPI_GetDriveType(@HomeDrive) ; For example C:

    ; Create a variable to hold the display message.
    Local $sMessage = ""
    Switch $iTypeOfDrive
        Case $DRIVE_UNKNOWN
            $sMessage = "The drive type cannot be determined."
        Case $DRIVE_NO_ROOT_DIR
            $sMessage = "The root path is invalid."
        Case $DRIVE_REMOVABLE
            $sMessage = "The drive is removable media."
        Case $DRIVE_FIXED
            $sMessage = "The drive is a fixed drive."
        Case $DRIVE_REMOTE
            $sMessage = "The drive is a remote (network) drive."
        Case $DRIVE_CDROM
            $sMessage = "The drive is a CD-ROM drive."
        Case $DRIVE_RAMDISK
            $sMessage = "The drive is a RAM disk."
    EndSwitch

    ; Display the message about the drive type.
    MsgBox($MB_SYSTEMMODAL, "", $sMessage)
EndFunc   ;==>Example

[mLipok]

Now I think you show us how to make a "correct" example for new HelpFile?
Thanks for pointing the right way, here and on the track.

mLipok

[guinness]

Just follow the 2nd post and don't use ConsoleWrite() when you wish to display an output to the user of some description. Also comments of some kind don't hurt either. Remember to think from the perspective of a new user discovering AutoIt for the first time. Good luck.

Edited June 24, 2014 by guinness

[mLipok]

Just to add (if these are designed for the help file) then they should pass Au3Check with the following parameters (see below) and use the correct variable naming convention as stated in the Readme.txt (located in the docs zip file).

 

###Parameters###
Parameters naming:
The first letter signifies the expected type of the variable. This should be as follows:
$a<letter> - Array (the following letter describes the data type taken from the rest of the data types below,
if it varies then v can be used.
$d - Binary data.
$h - Handle, usually to a file or window. NB: AutoIt handled controls return IDs, and so use $id instead.
$id - An AutoIt control Id.
$i - Integer.
$b - Boolean.
$f - Floating point number.
$n - general number with no preference for floating point or integer.
$s - String.
$v - Variant (unknown/variable type of data).
$o - COM object.
$p - Pointer. It is assumed that it points to a struct so no further letters are needed.
The type of struct being pointed to should be inferrable from the variable name e.g. $pWindowRect can be assumed to be a pointer to a $tagRECT structure.

 

there is inconsistency as to naming variables described here:

http://www.autoitscript.com/wiki/Best_coding_practices#Names_of_Variables

focus on:

$b - Boolean.

$f - Floating point number.

 

additionally this wiki page do not describe:

$d

Can it be the occasion to explain and normalize.

mLipok

[guinness]

The wiki is the wiki, this is maintained by you guys not the Devs.

[mLipok]

I know.

I just search something and found this:

http://www.autoitscript.com/autoit3/udfs/UDF_Standards.htm

Variable Names described here are current applicable standard, that You just invoked in post #2.

If so Wiki should be changed ie. by me.

[mLipok]

_WinAPI_GetPriorityClass

#include <WinAPIProc.au3>

Example_WinAPI_GetPriorityClass()

Func Example_WinAPI_GetPriorityClass()
    Local $PID = Run("notepad.exe")
    ProcessWait("notepad.exe")

    $Class = _WinAPI_GetPriorityClass($PID)
    If Not $Class Then
        Exit MsgBox(0, "Failure", "_WinAPI_GetPriorityClass")
    EndIf

    Switch $Class
        Case 0x00008000
            ConsoleWrite("ABOVE_NORMAL_PRIORITY_CLASS" & @LF)
        Case 0x00004000
            ConsoleWrite("BELOW_NORMAL_PRIORITY_CLASS" & @LF)
        Case 0x00000080
            ConsoleWrite("HIGH_PRIORITY_CLASS" & @LF)
        Case 0x00000040
            ConsoleWrite("IDLE_PRIORITY_CLASS" & @LF)
        Case 0x00000020
            ConsoleWrite("NORMAL_PRIORITY_CLASS" & @LF)
        Case 0x00000100
            ConsoleWrite("REALTIME_PRIORITY_CLASS" & @LF)
    EndSwitch
    ProcessClose($PID)
EndFunc   ;==>Example_WinAPI_GetPriorityClass 

 

 

 

#2765

Edited June 25, 2014 by mLipok

[JohnOne]

_WinAPI_AdjustWindowRectEx

#include <WinAPISys.au3>

Local $iLeft = 100, $iTop = 100, $iRight = 300, $iBottom = 300

Local $dsRect = DllStructCreate($tagRECT)

DllStructSetData($dsRect, "Left", $iLeft)
DllStructSetData($dsRect, "Top", $iTop)
DllStructSetData($dsRect, "Right", $iRight)
DllStructSetData($dsRect, "Bottom", $iBottom)

ConsoleWrite("Rect before" & @LF)
For $i = 1 To 4
    ConsoleWrite(DllStructGetData($dsRect, $i) & @LF)
Next

If Not _WinAPI_AdjustWindowRectEx($dsRect, 0, 0, True) Then
    Exit MsgBox(0, "Failure", "_WinAPI_AdjustWindowRectEx")
EndIf

ConsoleWrite("Rect after" & @LF)
For $i = 1 To 4
    ConsoleWrite(DllStructGetData($dsRect, $i) & @LF)
Next

[JohnOne]

_WinAPI_GetProfilesDirectory

#include <WinAPIFiles.au3>

ConsoleWrite(_WinAPI_GetProfilesDirectory() & @LF)

[JohnOne]

_WinAPI_GetROP2

expandcollapse popup

#include <WinAPI.au3>
#include <WinAPIGdi.au3>

$R2 = _WinAPI_GetROP2(_WinAPI_GetDC(Null))

If Not $R2 Then
    Exit MsgBox(0, "Failure", "_WinAPI_GetROP2")
EndIf

Switch $R2
        Case $R2_BLACK
            ConsoleWrite("Pixel is always 0." & @LF)
        Case $R2_COPYPEN
            ConsoleWrite("Pixel is the pen color." & @LF)
        Case $R2_MASKNOTPEN
            ConsoleWrite("Pixel is a combination of the colors common to both the screen and the inverse of the pen." & @LF)
        Case $R2_MASKPEN
            ConsoleWrite("Pixel is a combination of the colors common to both the pen and the screen." & @LF)
        Case $R2_MASKPENNOT
            ConsoleWrite("Pixel is a combination of the colors common to both the pen and the inverse of the screen." & @LF)
        Case $R2_MERGENOTPEN
            ConsoleWrite("Pixel is a combination of the screen color and the inverse of the pen color." & @LF)
        Case $R2_MERGEPEN
            ConsoleWrite("Pixel is a combination of the pen color and the screen color." & @LF)
        Case $R2_MERGEPENNOT
            ConsoleWrite("Pixel is a combination of the pen color and the inverse of the screen color." & @LF)
        Case $R2_NOP
            ConsoleWrite("Pixel remains unchanged." & @LF)
        Case $R2_NOT
            ConsoleWrite("Pixel is the inverse of the screen color." & @LF)
        Case $R2_NOTCOPYPEN
            ConsoleWrite("Pixel is the inverse of the pen color." & @LF)
        Case $R2_NOTMASKPEN
            ConsoleWrite("Pixel is the inverse of the R2_MASKPEN color." & @LF)
        Case $R2_NOTMERGEPEN
            ConsoleWrite("Pixel is the inverse of the R2_MERGEPEN color." & @LF)
        Case $R2_NOTXORPEN
            ConsoleWrite("Pixel is the inverse of the R2_XORPEN color." & @LF)
        Case $R2_WHITE
            ConsoleWrite("Pixel is always 1." & @LF)
        Case $R2_XORPEN
            ConsoleWrite("Pixel is a combination of the colors in the pen and in the screen, but not in both." & @LF)
EndSwitch 

[JohnOne]

_WinAPI_GetDefaultUserProfileDirectory

#include <WinAPIShellEx.au3>

ConsoleWrite(_WinAPI_GetDefaultUserProfileDirectory() & @LF)

[JohnOne]

_WinAPI_GetDeviceCaps

expandcollapse popup

#include <WinAPI.au3>

Const $DRIVERVERSION = 0     ;/* Device driver version                    */
Const $TECHNOLOGY    = 2     ;/* Device classification                    */
Const $HORZSIZE      = 4     ;/* Horizontal size in millimeters           */
Const $VERTSIZE      = 6     ;/* Vertical size in millimeters             */
Const $HORZRES       = 8     ;/* Horizontal width in pixels               */
Const $VERTRES       = 10    ;/* Vertical height in pixels                */
Const $BITSPIXEL     = 12    ;/* Number of bits per pixel                 */
Const $PLANES        = 14    ;/* Number of planes                         */
Const $NUMBRUSHES    = 16    ;/* Number of brushes the device has         */
Const $NUMPENS       = 18    ;/* Number of pens the device has            */
Const $NUMMARKERS    = 20    ;/* Number of markers the device has         */
Const $NUMFONTS      = 22    ;/* Number of fonts the device has           */
Const $NUMCOLORS     = 24    ;/* Number of colors the device supports     */
Const $PDEVICESIZE   = 26    ;/* Size required for device descriptor      */
Const $CURVECAPS     = 28    ;/* Curve capabilities                       */
Const $LINECAPS      = 30    ;/* Line capabilities                        */
Const $POLYGONALCAPS = 32    ;/* Polygonal capabilities                   */
Const $TEXTCAPS      = 34    ;/* Text capabilities                        */
Const $CLIPCAPS      = 36    ;/* Clipping capabilities                    */
Const $RASTERCAPS    = 38    ;/* Bitblt capabilities                      */
Const $ASPECTX       = 40    ;/* Length of the X leg                      */
Const $ASPECTY       = 42    ;/* Length of the Y leg                      */
Const $ASPECTXY      = 44    ;/* Length of the hypotenuse                 */
Const $LOGPIXELSX    = 88    ;/* Logical pixels/inch in X                 */
Const $LOGPIXELSY    = 90    ;/* Logical pixels/inch in Y                 */
Const $SIZEPALETTE   = 104    ;/* Number of entries in physical palette    */
Const $NUMRESERVED   = 106    ;/* Number of reserved entries in palette    */
Const $COLORRES      = 108    ;/* Actual color resolution                  */
Const $PHYSICALWIDTH   = 110  ;/* Physical Width in device units           */
Const $PHYSICALHEIGHT  = 111  ;/* Physical Height in device units          */
Const $PHYSICALOFFSETX = 112  ;/* Physical Printable Area x margin         */
Const $PHYSICALOFFSETY = 113  ;/* Physical Printable Area y margin         */
Const $SCALINGFACTORX  = 114  ;/* Scaling factor x                         */
Const $SCALINGFACTORY  = 115  ;/* Scaling factor y                         */
Const $VREFRESH        = 116  ;/* Current vertical refresh rate of the display device (for displays only) in Hz   */
Const $DESKTOPVERTRES  = 117  ;/* Horizontal width of entire desktop in pixels  */
Const $DESKTOPHORZRES  = 118  ;/* Vertical height of entire desktop in pixels   */
Const $BLTALIGNMENT    = 119  ;/* Preferred blt alignment                 */
Const $SHADEBLENDCAPS  = 120  ;/* Shading and blending caps               */
Const $COLORMGMTCAPS   = 121  ;/* Color Management caps                   */

;const values from MSVC 2010 winGDI.h

ConsoleWrite(_WinAPI_GetDeviceCaps( _WinAPI_GetDC(null), $DRIVERVERSION) & @LF) 

Edited June 26, 2014 by JohnOne

[JohnOne]

_WinAPI_GetPolyFillMode

#include <WinAPIGdi.au3>

$FillMode = _WinAPI_GetPolyFillMode ( _WinAPI_GetDC(null) )

If Not $FillMode Then
    Exit MsgBox(0, "Failure", "_WinAPI_GetPolyFillMode")
EndIf

Switch $FillMode
    Case $ALTERNATE
        ConsoleWrite("ALTERNATE" & @LF)
    Case $WINDING
        ConsoleWrite("WINDING" & @LF)
EndSwitch

[JohnOne]

_WinAPI_GetPEType

#include <WinAPIFiles.au3>

$PEType = _WinAPI_GetPEType(@ScriptDir & "\file.exe")

If Not $PEType Then
    Exit MsgBox(0, "Failure", "_WinAPI_GetPEType")
EndIf

Switch $PEType
    Case $IMAGE_FILE_MACHINE_I386
        ConsoleWrite("I386" & @LF)
    Case $IMAGE_FILE_MACHINE_IA64
        ConsoleWrite("IA64" & @LF)
    Case $IMAGE_FILE_MACHINE_AMD64
        ConsoleWrite("AMD64" & @LF)
    Case $IMAGE_FILE_MACHINE_ARM
        ConsoleWrite("ARM" & @LF)
EndSwitch

; There are more $IMAGE_FILE_MACHINE_* constants defined in APIFilesConstants.au3

Edited June 26, 2014 by JohnOne

[JohnOne]

_WinAPI_GetProcessHandleCount

#include <WinAPIProc.au3>

$PID = Run("notepad.exe")
ProcessWait("notepad.exe")

$HandleCount = _WinAPI_GetProcessHandleCount($PID)

If Not $HandleCount Then
    Exit MsgBox(0, "Failure", "_WinAPI_GetProcessHandleCount")
    ProcessClose($PID)
EndIf

ProcessClose($PID)
ConsoleWrite($HandleCount & @LF)

[JohnOne]

_WinAPI_GetProcessIoCounters

#include <WinAPIProc.au3>
#include <Array.au3>

$PID = ProcessExists("scite.exe")
If Not $PID Then
    Exit MsgBox(0, "Error", "Process does not exist")
EndIf

$IoCounters = _WinAPI_GetProcessIoCounters($PID)
If @error Then
    Exit MsgBox(0, "Failure", "_WinAPI_GetProcessIoCounters")
EndIf

_ArrayDisplay($IoCounters)

[JohnOne]

_WinAPI_GetStartupInfo

#include <WinAPISys.au3>

$tSTARTUPINFO = _WinAPI_GetStartupInfo ( )

For $i = 1 To 18
    ConsoleWrite(DllStructGetData($tSTARTUPINFO, $i) & @LF)
Next

[JohnOne]

_WinAPI_GetStdHandle 

#include <WinAPI.au3>

For $i = 0 To 2
    ConsoleWrite(_WinAPI_GetStdHandle ( $i ) & @LF)
Next

[JohnOne]

_WinAPI_GetSystemDEPPolicy

#include <WinAPISys.au3>

$DEPPolicy = _WinAPI_GetSystemDEPPolicy()

Switch $DEPPolicy
    Case 0
        ConsoleWrite("AlwaysOff" & @LF)
    Case 1
        ConsoleWrite("AlwaysOn" & @LF)
    Case 2
        ConsoleWrite("OptIn" & @LF)
    Case 3
        ConsoleWrite("OptOut" & @LF)
EndSwitch