ADODB.Recordset trouble

[Jewtus]

I'm running the following code

$sqlRs = ObjCreate("ADODB.Recordset")
$sqlRs.open ($SQLQUERY,$SqlConn)
$aOptionValue = $sqlRs.Fields ($fieldname).Value

and it returns the value I'm looking for, but the problem is, there should be two different values. I was expecting an array as a result, but I'm clearly missing something. Anyone have suggestions?

[Zedna]

If you want to get more than one column from select then you can use this:

$aOptionValue1 = $sqlRs.Fields (0).Value
$aOptionValue2 = $sqlRs.Fields (1).Value

Edited June 18, 2014 by Zedna

[Danp2]

Are you expecting the query to return multiple records? It isn't possible to tell from the limited information you posted. If so, then you need to use $sqlRs..MoveNext to access the subsequent records.

[Zedna]

I'm running the following code

$sqlRs = ObjCreate("ADODB.Recordset")
$sqlRs.open ($SQLQUERY,$SqlConn)
$aOptionValue = $sqlRs.Fields ($fieldname).Value

and it returns the value I'm looking for, but the problem is, there should be two different values. I was expecting an array as a result, but I'm clearly missing something. Anyone have suggestions?

 

If you need to get more rows then do it like this:

$sqlRs = ObjCreate("ADODB.Recordset")
$sqlRs.open ($SQLQUERY,$SqlConn)

While Not $sqlRs.EOF
    $aOptionValue = $sqlRs.Fields ($fieldname).Value
    ConsoleWrite($aOptionValue & @CRLF)
    $sqlRs.MoveNext
WEnd

Edited June 18, 2014 by Zedna

[Jewtus]

That was it. Thanks all!

[GaRydelaMer]

Hi all

you can use a method of recordset object to get an array from it

take a look here: http://www.w3schools.com/ado/met_rs_getrows.asp

$aReturn = $sqlRs.GetRows([$NumRows, [$Start, [$aFields]]])

for complete reading use this

    Local $aReturn = $sqlRs.GetRows()
    _ArrayDisplay($aReturn)

    $sqlRs.MoveFirst
    While Not $sqlRs.EOF
        ConsoleWrite("Row " & $sqlRs.AbsolutePosition & @LF)
        ;; Method 1
        ConsoleWrite(@TAB & "Method 1" & @LF)
        For $Field In $sqlRs.Fields
            ConsoleWrite(@TAB & $Field.Name & " = " & $Field.Value & @LF)
        Next
        ;; Method 2
        ConsoleWrite(@LF & @TAB & "Method 2" & @LF)
        For $i = 0 To $sqlRs.Fields.Count - 1
            ConsoleWrite(@TAB & $sqlRs.Fields($i).Name & " = " & $sqlRs.Fields($i).Value & @LF)
        Next
        $sqlRs.MoveNext
    WEnd

 

[water]

BTW: A good tutorial about ADO and AutoIt can be found here.