Tab switching with CTRL+TAB / CTRL+SHIFT+TAB

[mLipok]

In one program I seen functionality , in which the use of a combination of keys
CTRL + TAB or CTRL + SHIFT + TAB

results in a
switching tabs to the right or left.

Does anyone have an idea how to do it in AutoIt ?

mLipok

[Melba23]

mLipok,

If you want this functionality in an AutoIt GUI then I would use accelerator keys like this:

#include <GUIConstantsEx.au3>

Global $aTab[3]

$hGUI = GUICreate("Test", 500, 500)

$cTab = GUICtrlCreateTab(10, 10, 480, 200)

$aTab[0] = GUICtrlCreateTabItem("Tab 0")
$aTab[1] = GUICtrlCreateTabItem("Tab 1")
$aTab[2] = GUICtrlCreateTabItem("Tab 2")
GUICtrlCreateTabItem("")

$cTab_Right = GUICtrlCreateDummy()
$cTab_Left = GUICtrlCreateDummy()

GUISetState()

Global $aAccelKeys[2][2] = [["^{TAB}", $cTab_Right],["^+{TAB}", $cTab_Left]]
GUISetAccelerators($aAccelKeys)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cTab_Right
            $iTab = GUICtrlRead($cTab) + 1
            If $iTab > (UBound($aTab) - 1) Then $iTab = 0
            GUICtrlSetState($aTab[$iTab], $GUI_SHOW)
        Case $cTab_Left
            $iTab = GUICtrlRead($cTab) - 1
            If $iTab < 0 Then $iTab = UBound($aTab) - 1
            GUICtrlSetState($aTab[$iTab], $GUI_SHOW)
    EndSwitch
WEnd

M23

[abberration]

Melba23, you beat me to it, but I will post what I wrote anyways. Yours looks more efficient, though.

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <TabConstants.au3>
#include <WindowsConstants.au3>
#include <GuiTab.au3>

HotKeySet("^{TAB}", "_TabRight")
HotKeySet("^+{TAB}", "_TabLeft")

$Form1 = GUICreate("Form1", 444, 232)
$hWnd = GUICtrlCreateTab(16, 16, 409, 193)
$TabSheet1 = GUICtrlCreateTabItem("TabSheet1")
GUICtrlSetState(-1, $GUI_SHOW)
$TabSheet2 = GUICtrlCreateTabItem("TabSheet2")
$TabSheet3 = GUICtrlCreateTabItem("TabSheet3")
$TabSheet4 = GUICtrlCreateTabItem("TabSheet4")
$TabSheet5 = GUICtrlCreateTabItem("TabSheet5")
GUICtrlCreateTabItem("")
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

Func _TabRight()
    $CurPos = _GUICtrlTab_GetCurSel($hWnd)
    _GUICtrlTab_SetCurSel($hWnd, $CurPos + 1)
EndFunc

Func _TabLeft()
    $CurPos = _GUICtrlTab_GetCurSel($hWnd)
    _GUICtrlTab_SetCurSel($hWnd, $CurPos - 1)
EndFunc

[Melba23]

aberration,

The only real difference is your use of HotKeys. I usually prefer Accelerators when dealing with GUIs as they are only active when the GUI is active and so do not interfere with other apps.

M23

[abberration]

M23,

I did not realize the difference between hotkeys and accelerators. Somehow, I thought accelerators were faster or were given higher priority.

Thanks for the info.

[mLipok]

Thank you.
It works great.
By the way, enlightened me as to how to use GUICtrlCreateDummy(), and as to how to make this feature helpful.

As previously did not use it at all.

Cheers

mLipok

[Melba23]

mLipok,

Dummy controls can be very handy - see >here for some other suggested uses.

M23

[mLipok]

This is inspirational.

Thanks.

[Melba23]

aberration,

I have added some explanatory remarks to the Help file page explaining the difference.

mLipok,

Nice to hear.

M23

[mLipok]

  On 6/7/2014 at 3:35 PM, Melba23 said:

I have added some explanatory remarks to the Help file page explaining the difference.

 

Very nice

[Evocation]

thx guys... this helps me at my current work...