StringRegExp() Question

[buymeapc]

Hi all,

So, I have a few regex's that are trying to pull out versions from file paths, but the file paths are not quite the same. Is there a way I can get just the version out of the paths? Is there a way to do it with one regex?

Here's my attempt at it. Thank you!

Dim $paths[3] = ["\\10.231.254.23\f$\Installs\_SingleEXE\Interfaces\Billing_v0704A\setup.exe", _
             "\\10.231.254.23\f$\Installs\_SingleEXE\Interfaces\Billing_v0705A.exe", _
             "\\10.231.254.23\f$\Installs\_SingleEXE\Interfaces\Billing_v0706A_(Workstation).exe"]

For $i = 0 To 2
    $aMatches = StringRegExp($paths[$i], "(?<=_v)[a-zA-Z\\.\\r\\n0-9]*(?=_(Workstation).exe)", 3)
    If IsArray($aMatches) Then
        ConsoleWrite($aMatches[0] & @CRLF)
    Else
        $aMatches = StringRegExp($paths[$i], "(?<=_v)[a-zA-Z\\.\\r\\n0-9]*(?=\\setup.exe)", 3)
        If IsArray($aMatches) Then
            ConsoleWrite($aMatches[0] & @CRLF)
        Else
            $aMatches = StringRegExp($paths[$i], "(?<=_v)[a-zA-Z\\.\\r\\n0-9]*(?=.exe)", 3)
            If IsArray($aMatches) Then ConsoleWrite($aMatches[0] & @CRLF)
        EndIf
    EndIf
Next

Edited May 29, 2014 by buymeapc

[guinness]

Only going by your expected output.

Local $aPaths = [ _
        "\\10.231.254.23\f$\Installs\_SingleEXE\Interfaces\Billing_v0704A\setup.exe", _
        "\\10.231.254.23\f$\Installs\_SingleEXE\Interfaces\Billing_v0705A.exe", _
        "\\10.231.254.23\f$\Installs\_SingleEXE\Interfaces\Billing_v0706A_(Workstation).exe"]
Local $aMatches = 0
For $i = 0 To UBound($aPaths) - 1
    $aMatches = StringRegExp($aPaths[$i], "(?<=_v)(\w+)[\.\\_]", 3)
    If not @error Then ConsoleWrite($aMatches[0] & @CRLF)
Next

[mikell]

StringRegExp($aPaths[$i], "_v([^\W_]+)", 3)

[buymeapc]

Wow, those are way shorter than my regex! They work great! Thank you both for the help!!

[buymeapc]

One more stumbling block, I'm afraid.

It appears that element 3 of the array has a version that does not coincide with the regex. It returns "1" since it's told to gather all between the "_v" and "." or "_". I've tried a few things and I can't quite get the regex to spit out a version if ".", "_", or ".exe" is encountered. How can I tell the regex to do this?

Local $aPaths[5] = [ _
        "\\10.231.254.23\f$\Installs\_SingleEXE\Interfaces\Billing_v0704A\setup.exe", _
        "\\10.231.254.23\f$\Installs\_SingleEXE\Interfaces\Billing_v0705A.exe", _
        "\\10.231.254.23\f$\Installs\_SingleEXE\SingleSolution\_PriorReleases\CYC_v5.00.00_(SingleSolution)\CYC-Preview\2012-08-30\WPS_NC_V1110.exe", _
        "\\10.231.254.23\f$\Installs\_SingleEXE\~Utilities\_PriorReleases\FileTool\FileTool_v1.4.2.8.exe", _
        "\\10.231.254.23\f$\Installs\_SingleEXE\Interfaces\Billing_v0706A_(Workstation).exe"]
Local $aMatches = 0
For $i = 0 To UBound($aPaths) - 1
    ;$aMatches = StringRegExp($aPaths[$i], "(?i)_v([^\W_]+)", 3)
    $aMatches = StringRegExp($aPaths[$i], "(?i)(?<=_v)(\w+)[\.\\_]", 3)
    If not @error Then ConsoleWrite($aMatches[UBound($aMatches) - 1] & @CRLF)
Next

[BrewManNH]

When you change the playing field, the rules have to change with them. That 4th file name doesn't match the others, so of course it's not going to work with it.

Edited May 30, 2014 by BrewManNH

[jdelaney]

Might be easier just to...assuming this is a network share.

FileGetVersion

This gets them...but it's a stretch.:

Local $aPaths[5] = [ _
        "\\10.231.254.23\f$\Installs\_SingleEXE\Interfaces\Billing_v0704A\setup.exe", _
        "\\10.231.254.23\f$\Installs\_SingleEXE\Interfaces\Billing_v0705A.exe", _
        "\\10.231.254.23\f$\Installs\_SingleEXE\SingleSolution\_PriorReleases\CYC_v5.00.00_(SingleSolution)\CYC-Preview\2012-08-30\WPS_NC_V1110.exe", _
        "\\10.231.254.23\f$\Installs\_SingleEXE\~Utilities\_PriorReleases\FileTool\FileTool_v1.4.2.8.exe", _
        "\\10.231.254.23\f$\Installs\_SingleEXE\Interfaces\Billing_v0706A_(Workstation).exe"]
Local $aMatches = 0
For $i = 0 To UBound($aPaths) - 1
    ;$aMatches = StringRegExp($aPaths[$i], "(?i)_v([^\W_]+)", 3)
    $aMatches = StringRegExp($aPaths[$i], "(?i)(?<=_v)([\d\.]+\w?)[\.\\_].*exe", 3)
    If not @error Then ConsoleWrite($aMatches[UBound($aMatches) - 1] & @CRLF)
Next

If you want both versions on the 3rd one:

Local $aPaths[5] = [ _
        "\\10.231.254.23\f$\Installs\_SingleEXE\Interfaces\Billing_v0704A\setup.exe", _
        "\\10.231.254.23\f$\Installs\_SingleEXE\Interfaces\Billing_v0705A.exe", _
        "\\10.231.254.23\f$\Installs\_SingleEXE\SingleSolution\_PriorReleases\CYC_v5.00.00_(SingleSolution)\CYC-Preview\2012-08-30\WPS_NC_V1110.exe", _
        "\\10.231.254.23\f$\Installs\_SingleEXE\~Utilities\_PriorReleases\FileTool\FileTool_v1.4.2.8.exe", _
        "\\10.231.254.23\f$\Installs\_SingleEXE\Interfaces\Billing_v0706A_(Workstation).exe"]
Local $aMatches = 0
For $i = 0 To UBound($aPaths) - 1
    ;$aMatches = StringRegExp($aPaths[$i], "(?i)_v([^\W_]+)", 3)
    $aMatches = StringRegExp($aPaths[$i], "(?i)(?<=_[v])([\d\.]+\w?)[\.\\_]", 3)
    For $j = 0 to UBound($aMatches)-1
        ConsoleWrite(@TAB & "Match=[" & $aMatches[$j] & "]" )
    Next
    ConsoleWrite ( @CRLF)
Next

 Match=[0704A]
 Match=[0705A]
 Match=[5.00.00] Match=[1110]
 Match=[1.4.2.8]
 Match=[0706A]

Edited May 30, 2014 by jdelaney

[mikell]

$aMatches = StringRegExp($aPaths[$i], "(?i)_v((?:[[:alnum:].](?!exe))+)(?!.+\\)", 3)

If you have others exceptions to add, please mention them all together 

[buymeapc]

I was originally using FileGetVersion(), but since these are older installer exe's, they have the version of InstallShield set as the file version, so it would return "10.50", which is why I've been trying to get a regex going. Since these are UNC paths, using FileGetVersion() takes a bit, too since I was originally using it twice - once for "ProductVersion" (which this regex will replace) and a second for "ProductName". Now I only have to use it for the latter.

Your second regex works like a dream! Thank you!!

[guinness]

Not fair. I didn't have chance to join in on the second round.