Trouble making a decent color border around screen

[Kovacic]

Hello all.. I am working on a client server application, and part of the client application is to create color borders on the screen, while the script is performing various tasks. So far, I am using the following method:

#include <WinAPI.au3>

Border(0xFFFF00)

sleep(10000)

func border($color)
_WinAPI_DrawRect(0,0, @DesktopWidth, @DesktopHeight, $color)
_WinAPI_DrawRect(1,1, @DesktopWidth -1, @DesktopHeight -1, $color)
_WinAPI_DrawRect(2,2, @DesktopWidth -2, @DesktopHeight -2, $color)
_WinAPI_DrawRect(3,3, @DesktopWidth -3, @DesktopHeight -3, $color)
endfunc



Func _WinAPI_DrawRect($start_x, $start_y, $iWidth, $iHeight, $iColor)
    Local $hDC = _WinAPI_GetWindowDC(0) ; DC of entire screen (desktop)
    Local $tRect = DllStructCreate($tagRECT)
    DllStructSetData($tRect, 1, $start_x)
    DllStructSetData($tRect, 2, $start_y)
    DllStructSetData($tRect, 3, $iWidth)
    DllStructSetData($tRect, 4, $iHeight)
    Local $hBrush = _WinAPI_CreateSolidBrush($iColor)
    _WinAPI_FrameRect($hDC, DllStructGetPtr($tRect), $hBrush)
    ; clear resources
    _WinAPI_DeleteObject($hBrush)
    _WinAPI_ReleaseDC(0, $hDC)
EndFunc   ;==>_WinAPI_DrawRect

The above code should turn your screen border yellow (0xFFFF00) for about 10 seconds..  

The first issue is, it doesn't turn yellow, it turns Cyan...

The second problem is, Windows redraws the screen frequently, so if anything is drawn over the border, it goes away, unless I either AdlibRegister to call the draw every few seconds, OR just have it call during the while loop.

Is there a simple way I can create a good screen border, maybe as a transparent GUI that still lets users click on areas of the screen without the gui being in the way? Or is there a simple method to make that border on the screen (which will change color depending on the current state of the script) that is not effected by the windows screen redraw?

thanks in advance!!

[BrewManNH]

Try using the color in BGR (0x00FFFF) format instead of RGB (0xFFFF00)

[Kovacic]

Try using the color in BGR (0x00FFFF) format instead of RGB (0xFFFF00)

That worked Thanks!!

 That and also using just 0xFFFF

 

Still having issues with the redraw idea, but I might just go with what I got..

[UEZ]

You can try this (2 other methods):

 

#include <WinAPI.au3>
#include <WindowsConstants.au3>

$h1 = Border1(0xFFFF00)
Sleep(5000)
GUIDelete($h1)
$h2 = Border2(0xFF0000)
Sleep(5000)
GUIDelete($h2)

Func border1($color, $iSize = 4, $iX = 0, $iY = 0, $iW = @DesktopWidth, $iH = @DesktopHeight) ;coded by UEZ 2014
    Local $hGUI = GUICreate("", $iW, $iH, $iX, $iY, $WS_POPUP, BitOR($WS_EX_TOPMOST, $WS_EX_LAYERED, $WS_EX_APPWINDOW))
    Local $iLabel_bg = GUICtrlCreateLabel("", 0, 0, $iW, $iH)
    GUICtrlSetBkColor(-1, $color)
    Local $iLabel_fg = GUICtrlCreateLabel("", $iSize, $iSize, $iW - 2 * $iSize, $iH - 2 * $iSize)
    GUICtrlSetBkColor(-1, 0x010101)
    GUISetBkColor(0x010101)
    _WinAPI_SetLayeredWindowAttributes($hGUI, 0x010101, 255)
    GUISetState(@SW_SHOWNA)
    Return $hGUI
EndFunc

Func border2($color, $iSize = 4, $iX = 0, $iY = 0, $iW = @DesktopWidth, $iH = @DesktopHeight) ;coded by UEZ 2014
    Local $hGUI = GUICreate("", $iW, $iH, $iX, $iY, $WS_POPUP, BitOR($WS_EX_TOPMOST, $WS_EX_APPWINDOW))
    Local $iLabel = GUICtrlCreateLabel("", 0, 0, $iW, $iH)
    GUICtrlSetBkColor(-1, $color)
    Local $hRegion1 = _WinAPI_CreateRectRgn(0, 0, $iW, $iH)
    Local $hRegion2 = _WinAPI_CreateRectRgn($iSize, $iSize, $iW - $iSize, $iH - $iSize)
    Local $hRegion = _WinAPI_CreateRectRgn(0, 0, 0, 0)
    _WinAPI_CombineRgn($hRegion, $hRegion1, $hRegion2, $RGN_DIFF)
    _WinAPI_DeleteObject($hRegion1)
    _WinAPI_DeleteObject($hRegion2)
    _WinAPI_SetWindowRgn($hGUI, $hRegion)
    GUISetState(@SW_SHOWNA)
    Return $hGUI
EndFunc

Br,

UEZ

Edited May 21, 2014 by UEZ