How can I find the max value whith StringSplit

[rootx]

Hello friends,

I need to extrapolate the max value from this cicle.

Object: remove everything before the last backslash to have "img" folder without the path

 

<sub>Example()

Func Example()
    Local $sText = "C:folder1folder2img"
    Local $aArray = StringSplit($sText, '', $STR_ENTIRESPLIT)
    For $i = 1 To $aArray[0]</sub>

              _{MsgBox($MB_SYSTEMMODAL, "", "$aArray[" & $i & "] - " & $aArray[$i])}

   <sub>Next

EndFunc</sub>

Tanks

Edited May 14, 2014 by rootx

[JLogan3o13]

Do you mean the total indexes in the array? You would just look at the value of $aArray[0].

Example()

 Func Example()
     Local $sText = "C:\folder1\folder2\img"
     Local $aArray = StringSplit($sText, '\', 1)
        MsgBox(0, "", $aArray[0])
 EndFunc

Edited May 14, 2014 by JLogan3o13

[czardas]

$STR_ENTIRESPLIT is not needed, because the delimiter is a single character. You can also get the folder name from the path by using StringRight and StringInStr - searching from the right to get the final backslash character's position.

Edited May 14, 2014 by czardas

[somdcomputerguy]

Local $sText = "C:\folder1\folder2\img"
Local $sText1 = "C:\folder1\img"
Local $aArray = StringSplit($sText, '\')
Local $aArray1 = StringSplit($sText1, '\')
Local $var = $aArray[0], $var1 = $aArray1[0]
ConsoleWrite($aArray[$var] & @LF & $aArray1[$var1] & @LF)

Edited May 14, 2014 by somdcomputerguy

[somdcomputerguy]

oops, I had $sText1 in both StringSplit lines. I edited my post.

[UEZ]

Here some variants which came to my mind:

#include <File.au3>
Local $sText = "C:\folder1\folder2\img"

;variant 1
ConsoleWrite("1: " & StringRight($sText, StringLen($sText) - StringInStr($sText, "\", 0, -1)) & @CRLF)

;variant 2
ConsoleWrite("2: " & StringTrimLeft($sText, StringInStr($sText, "\", 0, -1)) & @CRLF)

;variant 3
ConsoleWrite("3: " & StringMid($sText, StringInStr($sText, "\", 0, -1) + 1) & @CRLF)

;variant 4
ConsoleWrite("4: " & StringRegExpReplace($sText, "^.*\\(.*)$", "$1") & @CRLF)

;variant 5
Local $sDrive = "", $sDir = "", $sFilename = "", $sExtension = ""
Local $aPathSplit = _PathSplit($sText, $sDrive, $sDir, $sFilename, $sExtension)
ConsoleWrite("5: " & $aPathSplit[3] & @CRLF)

Br,

UEZ

[rootx]

Thanks everyone,

UEZ... wonderfully great answer.

My solution

_{;set path}

_{Local $imgfolder = FileSelectFolder("Inserisci il nome della cartella che contiene le immagini", "", "", @ScriptDir)}

_{;write value to init.txt}

_{FileWrite($file,(StringRight($imgfolder, StringLen($imgfolder) - StringInStr($imgfolder, "", 0, -1))))}

works fine.

Edited May 15, 2014 by rootx