GUICtrlSetBkColor changes button style to $BS_UGLY ;(

[2Radon]

 This is frustrating.

$btnCreds = GUICtrlCreateButton("Set Username And Password", 40, 90, 250, 25)
; Creates it light gray and nicely rectangular with sharp corners

GUICtrlSetBkColor($btnCreds, $COLOR_RED)
; Changes the button's style to a MS Paint rounded corner rectangle. Ugh!

GUICtrlSetStyle($btnCreds, $GUI_SS_DEFAULT_BUTTON)
; Found this in forums, and it changes the color back to the default light gray also. ;(

Please save my button!

[mLipok]

Your Repro script is incomplete.

here is working repro:

expandcollapse popup

#include <ColorConstants.au3>
#include <GUIConstantsEx.au3>
#include <ButtonConstants.au3>

Example()

Func Example()
    ; Create a GUI with various controls.
    Local $hGUI = GUICreate("Example", 300, 200)

    ; Create a button control.
    Local $iNotepad = GUICtrlCreateButton("Run Notepad", 120, 170, 85, 25)
    Local $iClose = GUICtrlCreateButton("Close", 210, 170, 85, 25)

    #Region REPRO
    $btnCreds = GUICtrlCreateButton("Set Username And Password", 40, 90, 250, 25)
    ; Creates it light gray and nicely rectangular with sharp corners

    GUICtrlSetBkColor($btnCreds, $COLOR_RED)
    ; Changes the button's style to a MS Paint rounded corner rectangle. Ugh!
    GUICtrlSetStyle($btnCreds, $GUI_SS_DEFAULT_BUTTON)
    ; Found this in forums, and it changes the color back to the default light gray also. ;(
    #EndRegion REPRO

    ; Display the GUI.
    GUISetState(@SW_SHOW, $hGUI)


    Local $iPID = 0

    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $iClose
                ExitLoop

            Case $iNotepad
                ; Run Notepad with the window maximized.
                $iPID = Run("notepad.exe", "", @SW_SHOWMAXIMIZED)

        EndSwitch
    WEnd

    ; Delete the previous GUI and all controls.
    GUIDelete($hGUI)

    ; Close the Notepad process using the PID returned by Run.
    If $iPID Then ProcessClose($iPID)
EndFunc   ;==>Example

And indeed there is "strange" behavior maybe a bug.

but solution is really easy:

first use 

GUICtrlSetStyle

and after that use

GUICtrlSetBkColor

[2Radon]

Thanks, but it is the same. Use GUICtrlSetStyle and then GUICtrlSetBkColor and it will set the style back to the ugly one instantly, so that is not a solution.

[mLipok]

so what you want to achieve with this:

GUICtrlSetStyle($btnCreds, $GUI_SS_DEFAULT_BUTTON)
    ; Found this in forums, and it changes the color back to the default light gray also. ;(

[mLipok]

look here: GUICtrlCreateButton

 

To combine styles with the default style use BitOR( $GUI_SS_DEFAULT_BUTTON, newstyle, ... ).

 

Now i think this is not strange but intentional=standard behavior.

[2Radon]

look here: GUICtrlCreateButton

Now i think this is not strange but intentional=standard behavior.

 

Nay man, I think you ain't getting it.

GUICtrlSetBkColour changes the style, as you see in this image.

[mLipok]

It seems to its behavior belongs to Windows Settings or you 

---

here is my results:

Can you show me your results form my repro.

EDIT:

Did you use any othere styles to build your GUI ?

EIDT2:

remember to change order:

GUICtrlSetStyle($btnCreds, $GUI_SS_DEFAULT_BUTTON)
    ; Found this in forums, and it changes the color back to the default light gray also. ;(
    GUICtrlSetBkColor($btnCreds, $COLOR_RED)
    ; Changes the button's style to a MS Paint rounded corner rectangle. Ugh!

Edited April 17, 2014 by mLipok

[2Radon]

No it is simply the buttons, there is no other case or scene or anything at all!! Whatever you do BkColor wants it to look so ugly!

In your picture it is the same, no need to show. Look at your repro button and look at my button picture I posted above. compare the way the top button looks to the way bottom buttons look. BkColor makes it stylistically look like that. CtrlStyle resets the color back to default while BkColor sets the style to that ugly one.

[Melba23]

2Radon,

Be careful because colouring buttons can cause problems - such as the button being captured by the {ENTER} key and, as you have noticed, all styles being removed. This is due to a bug deep in the AutoIt core code which will not be fixed until that code is rewritten (i.e. probably never).

My advice - do not colour buttons.

M23

[KaFu]

As close as I could get ...

expandcollapse popup

; http://www.autoitscript.com/forum/topic/113811-guictrlbutton-settextcolor/
; based on post by Yashied
 
#include <GUIButton.au3>
#include <GUIImageList.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>
 
GUICreate('MyGUI', 200, 100)
GUICtrlCreateButton('OK', 65, 10, 70, 23)
GUICtrlCreateButton('OK', 65, 40, 70, 23)
GUICtrlSetBkColor(-1, 0x00FF00)
GUICtrlCreateButton('', 65, 70, 70, 23)
_GUICtrlButton_SetTextBkColor(-1, 'OK', 0xFF0000, 0x00FF00)
GUISetState()
 
Do
Until GUIGetMsg() = -3
 
Func _GUICtrlButton_SetTextBkColor($iCtrlID, $sText, $iTextColor, $iBkColor)
 
Local $hWnd, $hTheme, $hImageList, $hBitmap, $hBack, $hDC, $hMemDC, $hSrcDC, $tRect, $pRect, $Width, $Height, $Prev, $Flags = BitOR($DT_CENTER, $DT_SINGLELINE, $DT_VCENTER)
 
$hWnd = GUICtrlGetHandle($iCtrlID)
If Not $hWnd Then
Return 0
EndIf
$hTheme = DllCall('uxtheme.dll', 'ptr', 'OpenThemeData', 'hwnd', $hWnd, 'wstr', 'BUTTON')
If (@error) Or (Not $hTheme[0]) Then
GUICtrlSetColor($iCtrlID, $iTextColor)
GUICtrlSetData($iCtrlID, $sText)
Return 1
EndIf
$Width = _WinAPI_GetClientWidth($hWnd)
$Height = _WinAPI_GetClientHeight($hWnd)
$hImageList = _GUIImageList_Create($Width - 8, $Height - 8, 4, 4)
$tRect = DllStructCreate('int[4]')
DllStructSetData($tRect, 1, -4, 1)
DllStructSetData($tRect, 1, -4, 2)
DllStructSetData($tRect, 1, $Width - 4, 3)
DllStructSetData($tRect, 1, $Height - 4, 4)
$pRect = DllStructGetPtr($tRect)
$hDC = _WinAPI_GetDC(0)
$hMemDC = _WinAPI_CreateCompatibleDC($hDC)
$hSrcDC = _WinAPI_CreateCompatibleDC($hDC)
$hBitmap = _WinAPI_CreateCompatibleBitmap($hDC, $Width - 8, $Height - 8)
 
;$hBack = _WinAPI_CreateCompatibleBitmap($hDC, $Width - 8, $Height - 8)
$hBack = _WinAPI_CreateSolidBitmap($hWnd, $iBkColor, $Width - 8, $Height - 8)
 
_WinAPI_ReleaseDC(0, $hDC)
_WinAPI_SelectObject($hSrcDC, $hBack)
_WinAPI_SelectObject($hMemDC, _SendMessage($hWnd, $WM_GETFONT))
_WinAPI_SetTextColor($hMemDC, BitOR(BitAND($iTextColor, 0x00FF00), BitShift(BitAND($iTextColor, 0x0000FF), -16), BitShift(BitAND($iTextColor, 0xFF0000), 16)))
 
_WinAPI_SetBkMode($hMemDC, $TRANSPARENT)
 
; PBS_NORMAL, PBS_HOT, PBS_PRESSED, PBS_DISABLED, PBS_DEFAULTED
For $i = 1 To 5
$Prev = _WinAPI_SelectObject($hMemDC, $hBitmap)
DllCall('uxtheme.dll', 'int', 'DrawThemeBackground', 'ptr', $hTheme[0], 'hwnd', $hSrcDC, 'int', 4, 'int', $i, 'ptr', $pRect, 'ptr', 0)
_WinAPI_BitBlt($hMemDC, 0, 0, $Width - 8, $Height - 8, $hSrcDC, 0, 0, $MERGECOPY)
If $i = 4 Then
DllCall('uxtheme.dll', 'int', 'DrawThemeText', 'ptr', $hTheme[0], 'hwnd', $hMemDC, 'int', 1, 'int', 4, 'wstr', $sText, 'int', -1, 'dword', $Flags, 'dword', 0, 'ptr', $pRect)
Else
_WinAPI_DrawText($hMemDC, $sText, $tRect, $Flags)
EndIf
_WinAPI_SelectObject($hMemDC, $Prev)
_GUIImageList_Add($hImageList, $hBitmap)
Next
; PBS_HOT (Stylus Hot)
_GUIImageList_SetImageCount($hImageList, 6)
_GUIImageList_Copy($hImageList, 1, 5)
_WinAPI_DeleteDC($hMemDC)
_WinAPI_DeleteDC($hSrcDC)
_WinAPI_DeleteObject($hBitmap)
_WinAPI_DeleteObject($hBack)
DllCall('uxtheme.dll', 'int', 'CloseThemeData', 'ptr', $hTheme[0])
$Prev = _GUICtrlButton_GetImageList($hWnd)
If $Prev[0] Then
_GUIImageList_Destroy($Prev[0])
EndIf
GUICtrlSetData($iCtrlID, '')
If Not _GUICtrlButton_SetImageList($hWnd, $hImageList, 4) Then
_GUIImageList_Destroy($hImageList)
Return 0
EndIf
Return 1
EndFunc   ;==>_GUICtrlButton_SetTextBkColor

[UEZ]

Here a version using GDI+ (works only on 3.3.10.0+ versions):

expandcollapse popup

#include <ButtonConstants.au3>
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>


_GDIPlus_Startup()
Global Const $hGUI = GUICreate("Colored Buttons using GDI+", 600, 300)
Global Const $iBtn1 = GUICtrlCreateButton("Default", 125, 75, 150, 150)
GUICtrlSetFont(-1, 14.5, 400, 0, "Arial", 4)
Global Const $iBtn2 = GUICtrlCreateButton("", 325, 75, 150, 150, $BS_BITMAP)
Global Const $hBmp = _GDIPlus_BtnCtrlSetBgColor($iBtn2, "Colored", 146, 146)
GUISetState()

Do
    Switch GUIGetMsg()
        Case $iBtn1
            MsgBox(0, "Test", "Default button has been pressed")
        Case $iBtn2
            MsgBox(0, "Test", "Colored button has been pressed")
        Case $GUI_EVENT_CLOSE
            _WinAPI_DeleteObject($hBmp)
            _GDIPlus_Shutdown()
            GUIDelete()
            Exit
    EndSwitch
Until False

Func _GDIPlus_BtnCtrlSetBgColor($iBtn, $sText, $iW, $iH, $iStartColor = 0xF0FFFFF0, $iEndColor = 0x4040FF40, $sFontSize = 14, $sFont = "Arial") ;coded by UEZ 2014
    Local Const $hBitmap = _GDIPlus_BitmapCreateFromScan0($iW, $iH)
    Local Const $hGfx = _GDIPlus_ImageGetGraphicsContext($hBitmap)
;~  _GDIPlus_GraphicsSetSmoothingMode($hGfx, $GDIP_SMOOTHINGMODE_HIGHQUALITY)
    _GDIPlus_GraphicsSetTextRenderingHint($hGfx, 4)
    Local Const $hBrush_Bg = _GDIPlus_LineBrushCreate($iW / 8, 0, $iW / 2, $iH - $iH / 8, $iStartColor, $iEndColor, 1)
;~  _GDIPlus_LineBrushSetLinearBlend($hBrush_Bg, 0.15, 0.999)
    _GDIPlus_GraphicsFillRect($hGfx, 0, 0, $iW, $iH, $hBrush_Bg)
    Local $hBrush_Txt = _GDIPlus_BrushCreateSolid(0xFF000000)
    Local $hFamily = _GDIPlus_FontFamilyCreate($sFont)
    Local $hFont = _GDIPlus_FontCreate($hFamily, $sFontSize)
    Local $hLayout = _GDIPlus_RectFCreate(0, 0, $iW, $iH)
    Local $hStringFormat = _GDIPlus_StringFormatCreate()
    _GDIPlus_StringFormatSetAlign($hStringFormat, 1)
    _GDIPlus_StringFormatSetLineAlign($hStringFormat, 1)
    _GDIPlus_GraphicsDrawStringEx($hGfx, $sText, $hFont, $hLayout, $hStringFormat, $hBrush_Txt)
    Local Const $hGDIBitmap = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hBitmap)
    _WinAPI_DeleteObject(_SendMessage(GUICtrlGetHandle($iBtn), $BM_SETIMAGE, $IMAGE_BITMAP, $hGDIBitmap))
    _GDIPlus_BrushDispose($hBrush_Bg)
    _GDIPlus_BrushDispose($hBrush_Txt)
    _GDIPlus_FontFamilyDispose($hFamily)
    _GDIPlus_FontDispose($hFont)
    _GDIPlus_StringFormatDispose($hStringFormat)
    _GDIPlus_GraphicsDispose($hGfx)
    _GDIPlus_BitmapDispose($hBitmap)
    Return $hGDIBitmap
EndFunc

Br,

UEZ

Edited April 17, 2014 by UEZ