Date and time GUI bug?

[bobsyuruncle]

Hey guys... not a vital issue or anything, but I've setup the format of date and time in a user input field (code included below), but the output is off on the second field and I can't figure where it's getting it from.... the code displayed is the only place in the program that modifies these fields:

$StartDate = GUICtrlCreateDate(@Year&"/"&@MON&"/"&@MDAY&" "&@HOUR&":00", 8, 112, 138, 21)
    ; to select a specific default format
    $DTM_SETFORMAT_ = 0x1032 ; $DTM_SETFORMATW
    $style = "yyyy/MM/dd HH:mm"
    GUICtrlSendMsg($StartDate, $DTM_SETFORMAT_, 0, $style)
$EndDate = GUICtrlCreateDate(@Year&"/"&@MON&"/"&@MDAY+1&" "&@HOUR&":00", 8, 152, 138, 21)
    $DTM_SETFORMAT_ = 0x1032 ; $DTM_SETFORMATW
    $style = "yyyy/MM/dd HH:mm"
    GUICtrlSendMsg($EndDate, $DTM_SETFORMAT_, 0, $style)

The outputs are:
Startdate: 2014/04/04 17:00
(good so far)
EndDate: 2014/04/05 07:25
(Where did 07:25 come from? FYI 25 is the current Minute time of the test, but the 07Hour is not. Current hour is 17:00)
Both fields have almost exactly the same code and syntax with endDate being incrimented by 1.

Nowhere else in my script am I making any modifications to either field, just read.

Thanks for your help

Edited April 5, 2014 by bobsyuruncle

[Melba23]

bobsyuruncle,

No idea what is happening, but I would not recommend setting the end date the way you are doing it - what happens on the last day of the month?

Much better to use the correct function to increment the date - which also removes the problem you are seeing when I run the following:

#include <GUIConstantsEx.au3>
#include <Date.au3>

$sStyle = "yyyy/MM/dd HH:mm"

$hGUI = GUICreate("Test", 500, 500)

$sDate = @YEAR & "/" & @MON & "/" & @MDAY & " " & @HOUR & ":00"
$StartDate = GUICtrlCreateDate($sDate, 10, 110, 140, 20)
GUICtrlSendMsg($StartDate, $DTM_SETFORMATW, 0, $sStyle)

$sDate = _DateAdd("D", 1, $sDate) ; Increment by 1 day <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
$EndDate = GUICtrlCreateDate($sDate, 10, 150, 140, 20)
GUICtrlSendMsg($EndDate, $DTM_SETFORMATW, 0, $sStyle)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Does it work for you too?

M23

[bobsyuruncle]

Thank you.

This worked and was cleaner than what I was trying.

[Jos]

Assume that @MDAY+1 messes up the format as @MON is a 2 character string and the outcome of @MDAY+1 is in this case a 1 digit number converted back to a 1 character string.

Jos