_Array2HTMLTable()

[uncommon]

I made a function, it does as the name implies. It will make an Autoit array into a HTML table.

I looked around on the forms but could not find anything I liked so I made one. You can change the colors via Hex colors and can also turn off the headers.

The function returns the string for a HTML doc and the table. Let me know what ya'll think.

Update 4/8/14: Added <p> tag to make table centered, Just seemed to make more sence.

expandcollapse popup

;#FUNCTION#=============================================================================================================
; Name...........: _Array2HTMLTable()
; Description ...: Returns HTML string with a table created from a Autoit array
; Syntax.........: ($aArray, $BodyBGColor = "#ffffff", $HighlightBGColor = "#F0F9FF", $HeaderBGColor = "#007EE5", $BodyTxtColor = "#000000", $HeaderTxtColor = "#ffffff", $HeadersOn = 1)
; Parameters ....: $aArray - The Array to use
;                  $BodyBGColor -         [optional] The Hex color for the table body background.
;                  $HighlightBGColor -     [optional] The Hex color for the highlight background.
;                  $HeaderBGColor -     [optional] The Hex color for the table header background.
;                  $BodyTxtColor -         [optional] The Hex color for the table body Text.
;                  $HeaderTxtColor -     [optional] The Hex color for the table header Text.
;                  $HeadersOn -         [optional] Turns off the header. Headers are the contents found on the first row of the Autoit array if this feature is turned off then
;                                       the frist row of the autoit array is placed into the table body.
; Return values .: Success - The HTML string
;                  Failure - -1 or -2 depending on the problem
; Author ........: XThrax aka uncommon
; Remarks .......: CSS and JavaScript are use to make the table look nice. If you know a lot more about either you can add to it or manipulate it. I used the code I found on this website.
;                  http://webdesign.about.com/od/examples/l/bltables.htm
; Related .......: _IETableWriteToArray()
; Link ..........;
; Example .......; No
; =====================================================================================================================

Func _Array2HTMLTable($aArray, $BodyBGColor = "#ffffff", $HighlightBGColor = "#F0F9FF", $HeaderBGColor = "#007EE5", $BodyTxtColor = "#000000", $HeaderTxtColor = "#ffffff", $HeadersOn = 1)
    If IsArray($aArray) = 0 Then Return -1
    Local $aTRlines = ''
    Local $aTHlines = ''
    Local $aTDlines = ''
    Local $BodyStart = 1
    Local $TotalRows = UBound($aArray);rows
    Local $TotalColumns = UBound($aArray, 2);columns
    Local $CSS = 'table {margin: 1em; border-collapse: collapse; }' & @CRLF & _
            'td, th {padding: .3em; border: 1px #ccc solid; }' & @CRLF & _
            'thead {background: ' & $HeaderBGColor & '; }' & @CRLF & _
            'thead {color:' & $HeaderTxtColor & ';}' & @CRLF & _
            'tbody {background: ' & $BodyBGColor & '; }' & @CRLF & _
            'tbody {color: ' & $BodyTxtColor & '; }' & @CRLF & _
            '#highlight tr.hilight { background: ' & $HighlightBGColor & '; } '
    Local $JavaScript = "function tableHighlightRow() {" & @CRLF & _
            "  if (document.getElementById && document.createTextNode) {" & @CRLF & _
            "    var tables=document.getElementsByTagName('table');" & @CRLF & _
            "    for (var i=0;i<tables.length;i++)" & @CRLF & _
            "    {" & @CRLF & _
            "      if(tables[i].className=='hilite') {" & @CRLF & _
            "        var trs=tables[i].getElementsByTagName('tr');" & @CRLF & _
            "        for(var j=0;j<trs.length;j++)" & @CRLF & _
            "            {" & @CRLF & _
            "          if(trs[j].parentNode.nodeName=='TBODY') {" & @CRLF & _
            "            trs[j].onmouseover=function(){this.className='hilight';return false}" & @CRLF & _
            "            trs[j].onmouseout=function(){this.className='';return false}" & @CRLF & _
            "          }" & @CRLF & _
            "        }" & @CRLF & _
            "      }" & @CRLF & _
            "    }" & @CRLF & _
            "  }" & @CRLF & _
            "}" & @CRLF & _
            "window.onload=function(){tableHighlightRow();}"
    If $HeadersOn <> 1 Then
        $BodyStart = 0
    Else
        If $TotalRows < 2 Then Return -2;there needs to be at least two rows if headers are on
        For $x = 0 To $TotalColumns - 1
            $aTHlines = $aTHlines & '    <th>' & $aArray[0][$x] & '</th>' & @CRLF
        Next
    EndIf
    For $x = $BodyStart To $TotalRows - 1
        $aTDlines = ''
        For $i = 0 To $TotalColumns - 1
            $aTDlines = $aTDlines & '    <td>' & $aArray[$x][$i] & '</td>' & @CRLF
        Next
        $aTRlines = $aTRlines & '<tr>' & @CRLF & _
                $aTDlines & _
                '</tr>' & @CRLF
    Next
    $HTML = '<!DOCTYPE html><html>' & @CRLF & _
            '<head> ' & @CRLF & _
            '<Style>' & @CRLF & _
            $CSS & @CRLF & _
            '</Style>' & @CRLF & _
            '<script>' & @CRLF & _
            $JavaScript & @CRLF & _
            '</script>' & @CRLF & _
            '</head>' & @CRLF & _
            '<body><p align="center"><table class="hilite" id="highlight" style="width:60%">' & @CRLF & _
            '<thead>' & @CRLF & _
            '<tr>' & @CRLF & _
            $aTHlines & _
            '</tr>' & @CRLF & _
            '</thead>' & @CRLF & _
            '</p><tbody>' & @CRLF & _
            $aTRlines & _
            '</tbody>' & @CRLF & _
            '</table></body></html>'
    Return $HTML
EndFunc   ;==>_Array2HTMLTable

_Array2HTMLTable.au3

Edited April 9, 2014 by uncommon

[mLipok]

This is what I missed to do the reporting system

Thanks for sharing.

Regards

mLipok

edit:

ps.

you can update link in your script:

; Link ..........; http://www.autoitscript.com/forum/topic/160422-array2htmltable/

Edited April 4, 2014 by mLipok

[mLipok]

I missed one functionality: Title
I'm not an expert on HTML, but initially I worked it out like this:

expandcollapse popup

Local $test[2][4] = [['ordinal number', 'String 1', 'String 2', 'String 4'],['1', 'My First Name', 'My Last Name', 'some other text']]
FileWrite(@ScriptDir & '\Test.html', _Array2HTMLTable($test, 'Some description'))

;#FUNCTION#=============================================================================================================
; Name...........: _Array2HTMLTable()
; Description ...: Returns HTML string with a table created from a Autoit array
; Syntax.........: ($aArray, $BodyBGColor = "#ffffff", $HighlightBGColor = "#F0F9FF", $HeaderBGColor = "#007EE5", $BodyTxtColor = "#000000", $HeaderTxtColor = "#ffffff", $HeadersOn = 1)
; Parameters ....: $aArray - The Array to use
;                  $BodyBGColor -       [optional] The Hex color for the table body background.
;                  $HighlightBGColor -  [optional] The Hex color for the highlight background.
;                  $HeaderBGColor -     [optional] The Hex color for the table header background.
;                  $BodyTxtColor -      [optional] The Hex color for the table body Text.
;                  $HeaderTxtColor -    [optional] The Hex color for the table header Text.
;                  $HeadersOn -         [optional] Turns off the header. Headers are the contents found on the first row of the Autoit array if this feature is turned off then
;                                       the frist row of the autoit array is placed into the table body.
; Return values .: Success - The HTML string
;                  Failure - -1 or -2 depending on the problem
; Author ........: XThrax aka uncommon
; Remarks .......: CSS and JavaScript are use to make the table look nice. If you know a lot more about either you can add to it or manipulate it. I used the code I found on this website.
;                  http://webdesign.about.com/od/examples/l/bltables.htm
; Related .......: _IETableWriteToArray()
; Link ..........; http://www.autoitscript.com/forum/topic/160422-array2htmltable/
; Example .......; No
; =====================================================================================================================

Func _Array2HTMLTable($aArray, $sTitle = '', $BodyBGColor = "#ffffff", $HighlightBGColor = "#F0F9FF", $HeaderBGColor = "#007EE5", $BodyTxtColor = "#000000", $HeaderTxtColor = "#ffffff", $HeadersOn = 1)
    If IsArray($aArray) = 0 Then Return -1
    Local $aTRlines = ''
    Local $aTHlines = ''
    Local $aTDlines = ''
    Local $BodyStart = 1
    Local $TotalRows = UBound($aArray);rows
    Local $TotalColumns = UBound($aArray, 2);columns
    Local $CSS = 'table {margin: 1em; border-collapse: collapse; }' & @CRLF & _
            'td, th {padding: .3em; border: 1px #ccc solid; }' & @CRLF & _
            'thead {background: ' & $HeaderBGColor & '; }' & @CRLF & _
            'thead {color:' & $HeaderTxtColor & ';}' & @CRLF & _
            'tbody {background: ' & $BodyBGColor & '; }' & @CRLF & _
            'tbody {color: ' & $BodyTxtColor & '; }' & @CRLF & _
            '#highlight tr.hilight { background: ' & $HighlightBGColor & '; } '
    Local $JavaScript = "function tableHighlightRow() {" & @CRLF & _
            "  if (document.getElementById && document.createTextNode) {" & @CRLF & _
            "    var tables=document.getElementsByTagName('table');" & @CRLF & _
            "    for (var i=0;i<tables.length;i++)" & @CRLF & _
            "    {" & @CRLF & _
            "      if(tables[i].className=='hilite') {" & @CRLF & _
            "        var trs=tables[i].getElementsByTagName('tr');" & @CRLF & _
            "        for(var j=0;j<trs.length;j++)" & @CRLF & _
            "           {" & @CRLF & _
            "          if(trs[j].parentNode.nodeName=='TBODY') {" & @CRLF & _
            "            trs[j].onmouseover=function(){this.className='hilight';return false}" & @CRLF & _
            "            trs[j].onmouseout=function(){this.className='';return false}" & @CRLF & _
            "          }" & @CRLF & _
            "        }" & @CRLF & _
            "      }" & @CRLF & _
            "    }" & @CRLF & _
            "  }" & @CRLF & _
            "}" & @CRLF & _
            "window.onload=function(){tableHighlightRow();}"
    If $HeadersOn <> 1 Then
        $BodyStart = 0
    Else
        If $TotalRows < 2 Then Return -2;there needs to be at least two rows if headers are on
        For $x = 0 To $TotalColumns - 1
            $aTHlines = $aTHlines & '   <th>' & $aArray[0][$x] & '</th>' & @CRLF
        Next
    EndIf
    For $x = $BodyStart To $TotalRows - 1
        $aTDlines = ''
        For $i = 0 To $TotalColumns - 1
            $aTDlines = $aTDlines & '   <td>' & $aArray[$x][$i] & '</td>' & @CRLF
        Next
        $aTRlines = $aTRlines & '<tr>' & @CRLF & _
                $aTDlines & _
                '</tr>' & @CRLF
    Next
    If $sTitle <> '' Then
        $sTitle = '<br>' & $sTitle & '<br>'
    EndIf

    $HTML = '<!DOCTYPE html><html>' & @CRLF & _
            '<head> ' & @CRLF & _
            '<Style>' & @CRLF & _
            $CSS & @CRLF & _
            '</Style>' & @CRLF & _
            '<script>' & @CRLF & _
            $JavaScript & @CRLF & _
            '</script>' & @CRLF & _
            '</head>' & @CRLF & _
            '<body>' & $sTitle & '<table class="hilite" id="highlight" style="width:60%">' & @CRLF & _
            '<thead>' & @CRLF & _
            '<tr>' & @CRLF & _
            $aTHlines & _
            '</tr>' & @CRLF & _
            '</thead>' & @CRLF & _
            '<tbody>' & @CRLF & _
            $aTRlines & _
            '</tbody>' & @CRLF & _
            '</table></body></html>'
    Return $HTML
EndFunc   ;==>_Array2HTMLTable

Perhaps someone correct me.
It would be appreciated.

mLipok

Edited April 4, 2014 by mLipok

[uncommon]

It looks like you inserted a statement right before the table. I am not sure what you are trying to acomplish....

Edited April 4, 2014 by uncommon

[mLipok]

I want to use this with:

>Smtp Mailer That Supports Html And Attachments

I meant to send reports in tabular form.
But before the report I need to put additional comment.
I can not put it as the title of the email because the title of the email will be different than my comment.

[uncommon]

You could try something like this.

I also like that INetSmtpMailCom function by jos

expandcollapse popup

#include <File.au3>

Local $test[2][4] = [['ordinal number', 'String 1', 'String 2', 'String 4'],['1', 'My First Name', 'My Last Name', 'some other text']]
FileWrite(@ScriptDir & '\Test.html', _Array2HTMLTable($test, 'Some description'))

$Docfile = _Array2HTMLTable($test)
_SendMail("xxxxxxx@aol.com", "Reports about something", "Insert comment here" & @CRLF & @CRLF & $Docfile)

Func _SendMail($ToAddress, $Subject, $Body)
    $SmtpServer = "smtp.gmail.com" ; address for the smtp-server to use - REQUIRED
    $FromName = "" ; name from who the email was sent
    $FromAddress = "xxxxxxxx@gmail.com" ; address from where the mail should come
    $AttachFiles = "" ; the file(s) you want to attach seperated with a ; (Semicolon) - leave blank if not needed
    $CcAddress = "" ; address for cc - leave blank if not needed
    $BccAddress = "" ; address for bcc - leave blank if not needed
    $Importance = "Normal" ; Send message priority: "High", "Normal", "Low"
    $Username = "xxxxxxxxx@gmail.com" ; username for the account used from where the mail gets sent - REQUIRED
    $Password = "password" ; password for the account used from where the mail gets sent - REQUIRED
    $IPPort = 465 ; port used for sending the mail
    $ssl = 1 ; enables/disables secure socket layer sending - put to 1 if using httpS
    Global $oMyRet[2]
    Global $oMyError = ObjEvent("AutoIt.Error", "MyErrFunc")
    $rc = _INetSmtpMailCom($SmtpServer, $FromName, $FromAddress, $ToAddress, $Subject, $Body, $AttachFiles, $CcAddress, $BccAddress, $Importance, $Username, $Password, $IPPort, $ssl)
    If @error Then
        MsgBox(0, "Error sending message", "Error code:" & @error & "  Description:" & $rc)
    EndIf
EndFunc   ;==>_SendMail
Func _INetSmtpMailCom($s_SmtpServer, $s_FromName, $s_FromAddress, $s_ToAddress, $s_Subject = "", $as_Body = "", $s_AttachFiles = "", $s_CcAddress = "", $s_BccAddress = "", $s_Importance = "Normal", $s_Username = "", $s_Password = "", $IPPort = 25, $ssl = 0)
    Local $objEmail = ObjCreate("CDO.Message")
    $objEmail.From = '"' & $s_FromName & '" <' & $s_FromAddress & '>'
    $objEmail.To = $s_ToAddress
    Local $i_Error = 0
    Local $i_Error_desciption = ""
    If $s_CcAddress <> "" Then $objEmail.Cc = $s_CcAddress
    If $s_BccAddress <> "" Then $objEmail.Bcc = $s_BccAddress
    $objEmail.Subject = $s_Subject
    If StringInStr($as_Body, "<") And StringInStr($as_Body, ">") Then
        $objEmail.HTMLBody = $as_Body
    Else
        $objEmail.Textbody = $as_Body & @CRLF
    EndIf
    If $s_AttachFiles <> "" Then
        Local $S_Files2Attach = StringSplit($s_AttachFiles, ";")
        For $x = 1 To $S_Files2Attach[0]
            $S_Files2Attach[$x] = _PathFull($S_Files2Attach[$x])
;~          ConsoleWrite('@@ Debug : $S_Files2Attach[$x] = ' & $S_Files2Attach[$x] & @LF & '>Error code: ' & @error & @LF) ;### Debug Console
            If FileExists($S_Files2Attach[$x]) Then
                ConsoleWrite('+> File attachment added: ' & $S_Files2Attach[$x] & @LF)
                $objEmail.AddAttachment($S_Files2Attach[$x])
            Else
                ConsoleWrite('!> File not found to attach: ' & $S_Files2Attach[$x] & @LF)
                SetError(1)
                Return 0
            EndIf
        Next
    EndIf
    $objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
    $objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = $s_SmtpServer
    If Number($IPPort) = 0 Then $IPPort = 25
    $objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = $IPPort
    ;Authenticated SMTP
    If $s_Username <> "" Then
        $objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
        $objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusername") = $s_Username
        $objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendpassword") = $s_Password
    EndIf
    If $ssl Then
        $objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True
    EndIf
    ;Update settings
    $objEmail.Configuration.Fields.Update
    ; Set Email Importance
    Switch $s_Importance
        Case "High"
            $objEmail.Fields.Item("urn:schemas:mailheader:Importance") = "High"
        Case "Normal"
            $objEmail.Fields.Item("urn:schemas:mailheader:Importance") = "Normal"
        Case "Low"
            $objEmail.Fields.Item("urn:schemas:mailheader:Importance") = "Low"
    EndSwitch
    $objEmail.Fields.Update
    ; Sent the Message
    $objEmail.Send
    If @error Then
        SetError(2)
        Return $oMyRet[1]
    EndIf
    $objEmail = ""
EndFunc   ;==>_INetSmtpMailCom
Func MyErrFunc()
    $HexNumber = Hex($oMyError.number, 8)
    $oMyRet[0] = $HexNumber
    $oMyRet[1] = StringStripWS($oMyError.description, 3)
    ConsoleWrite("### COM Error !  Number: " & $HexNumber & "   ScriptLine: " & $oMyError.scriptline & "   Description:" & $oMyRet[1] & @LF)
    SetError(1); something to check for when this function returns
    Return
EndFunc   ;==>MyErrFunc

Func _Array2HTMLTable($aArray, $BodyBGColor = "#ffffff", $HighlightBGColor = "#F0F9FF", $HeaderBGColor = "#007EE5", $BodyTxtColor = "#000000", $HeaderTxtColor = "#ffffff", $HeadersOn = 1)
    If IsArray($aArray) = 0 Then Return -1
    Local $aTRlines = ''
    Local $aTHlines = ''
    Local $aTDlines = ''
    Local $BodyStart = 1
    Local $TotalRows = UBound($aArray);rows
    Local $TotalColumns = UBound($aArray, 2);columns
    Local $CSS = 'table {margin: 1em; border-collapse: collapse; }' & @CRLF & _
            'td, th {padding: .3em; border: 1px #ccc solid; }' & @CRLF & _
            'thead {background: ' & $HeaderBGColor & '; }' & @CRLF & _
            'thead {color:' & $HeaderTxtColor & ';}' & @CRLF & _
            'tbody {background: ' & $BodyBGColor & '; }' & @CRLF & _
            'tbody {color: ' & $BodyTxtColor & '; }' & @CRLF & _
            '#highlight tr.hilight { background: ' & $HighlightBGColor & '; } '
    Local $JavaScript = "function tableHighlightRow() {" & @CRLF & _
            "  if (document.getElementById && document.createTextNode) {" & @CRLF & _
            "    var tables=document.getElementsByTagName('table');" & @CRLF & _
            "    for (var i=0;i<tables.length;i++)" & @CRLF & _
            "    {" & @CRLF & _
            "      if(tables[i].className=='hilite') {" & @CRLF & _
            "        var trs=tables[i].getElementsByTagName('tr');" & @CRLF & _
            "        for(var j=0;j<trs.length;j++)" & @CRLF & _
            "           {" & @CRLF & _
            "          if(trs[j].parentNode.nodeName=='TBODY') {" & @CRLF & _
            "            trs[j].onmouseover=function(){this.className='hilight';return false}" & @CRLF & _
            "            trs[j].onmouseout=function(){this.className='';return false}" & @CRLF & _
            "          }" & @CRLF & _
            "        }" & @CRLF & _
            "      }" & @CRLF & _
            "    }" & @CRLF & _
            "  }" & @CRLF & _
            "}" & @CRLF & _
            "window.onload=function(){tableHighlightRow();}"
    If $HeadersOn <> 1 Then
        $BodyStart = 0
    Else
        If $TotalRows < 2 Then Return -2;there needs to be at least two rows if headers are on
        For $x = 0 To $TotalColumns - 1
            $aTHlines = $aTHlines & '   <th>' & $aArray[0][$x] & '</th>' & @CRLF
        Next
    EndIf
    For $x = $BodyStart To $TotalRows - 1
        $aTDlines = ''
        For $i = 0 To $TotalColumns - 1
            $aTDlines = $aTDlines & '   <td>' & $aArray[$x][$i] & '</td>' & @CRLF
        Next
        $aTRlines = $aTRlines & '<tr>' & @CRLF & _
                $aTDlines & _
                '</tr>' & @CRLF
    Next
    $HTML = '<!DOCTYPE html><html>' & @CRLF & _
            '<head> ' & @CRLF & _
            '<Style>' & @CRLF & _
            $CSS & @CRLF & _
            '</Style>' & @CRLF & _
            '<script>' & @CRLF & _
            $JavaScript & @CRLF & _
            '</script>' & @CRLF & _
            '</head>' & @CRLF & _
            '<body><table class="hilite" id="highlight" style="width:60%">' & @CRLF & _
            '<thead>' & @CRLF & _
            '<tr>' & @CRLF & _
            $aTHlines & _
            '</tr>' & @CRLF & _
            '</thead>' & @CRLF & _
            '<tbody>' & @CRLF & _
            $aTRlines & _
            '</tbody>' & @CRLF & _
            '</table></body></html>'
    Return $HTML
EndFunc   ;==>_Array2HTMLTable