ways to pass @error (with array)

[shaqan]

Thanks to the help with StringRegExp from Melba23 I have got a function now

Func _LogFile_RegEx_Filter($string)
    $found = StringRegExp($string, ":\s(\d{1,3}\.\d{1,2}°[NSEW])", 3)
    Switch $found
        Case @error = 1
            ConsoleWrite("DBG: Array is invalid" & @CRLF)
                        $found[0] = "ERROR"
        Case @error = 2
            ConsoleWrite("DBG: Bad pattern. Array is invalid" & @CRLF)
                        $found[1] = "ERROR"
    EndSwitch

    return $found
EndFunc

I can use it fine like this

Local $mutate = _LogFile_RegEx_Filter($data)

ConsoleWrite("LAT:[" & $mutate[0] & "] LON: [" & $mutate[1] & "]")

until I feed in string which does not give a match and should error out - trying for all possible scenarios)

Instead of getting text on a console with  LAT:[ERROR] LON:[ERROR] script crashes with a

 

==> Subscript used on non-accessible variable.:

$found[0] = "ERROR"

$found^ ERROR

->20:45:50 AutoIt3.exe ended.rc:1

 

how to fix it? So that some unexpected line in log file would not make whole thing come crashing down

[BrewManNH]

Are you going to test against $found, or are you going to test against @error, because you're mixing the 2 in your switch statement.

First, you can't use an array in a Switch like that. Second, if there's an error then $found will not be an array so you can't use it like you're doing later.

[Melba23]

shaqan,

I would code the function like this so that an array is always returned:

#include <Array.au3>

$sString = "2014-03-02 14:12:27 | Current location: Unknown, Lat: 58.88°N, Lon: 94.39°E, Altitude: 105 m"
$aRet = _LogFile_RegEx_Filter($sString)
_ArrayDisplay($aRet, "", Default, 8)

$sString = "blah"
$aRet = _LogFile_RegEx_Filter($sString)
_ArrayDisplay($aRet, "", Default, 8)

Func _LogFile_RegEx_Filter($string)

    ; Run the SRE - if it works the array is created
    Local $aFound = StringRegExp($string, ":\s(\d{1,3}\.\d{1,2}°[NSEW])", 3)
    ; Switch on the @error returned
    Switch @error
        Case 1 ; Do use the correct syntax - look in the Help file to check
            ConsoleWrite("DBG: Array is invalid" & @CRLF)
            ; Declare the array as an error
            Local $aFound[2] = ["ERROR", 1]
        Case 2
            ConsoleWrite("DBG: Bad pattern. Array is invalid" & @CRLF)
            Local $aFound[2] = ["ERROR", 2]
    EndSwitch
    ; And return whatever array was created
    Return $aFound

EndFunc

All clear? Please ask if not.

M23

[shaqan]

aha, thanks. seems to work.

Local $aFound[2] = ["ERROR", 1]

that ,1] puzzled me until I realized you put it there to mark "error code" and to fill second slot in the array.

[Melba23]

shaqan,

 

seems to work

Oh ye of little faith - my code usually does.

M23

[marko001]

@Melba23 Hi Melba, and sorry to disturb you.

I got this thread while lookin for a solution to one (of my many) issue:

Q: How can I handle array errors?

This is a classic error:
 

Local $aArray[6][2] = [[1, "A"], [2, "B"], [3, "C"], [1, "A"], [2, "B"], [3, "C"]]
For $i = 0 to 9
    ConsoleWrite("Data: " & $aArray[$i][0] & @CRLF)
Next

Typical error is

"Y:\__ AutoIt\RemoteCrypto\testcalc.au3" (27) : ==> Array variable has incorrect number of subscripts or subscript dimension range exceeded.:
ConsoleWrite("Data: " & $aArray[$i][0] & @CRLF)
ConsoleWrite("Data: " & ^ ERROR
->16:47:53 AutoIt3.exe ended.rc:1
+>16:47:53 AutoIt3Wrapper Finished.
>Exit code: 1    Time: 1.169

Obviously this is just to semplify it. In real life I come across data coming from Trade Exchange API integration and it may happen that sometimes (connection issue, latencies,...) data is not properly loaded so array creation may fail and boom.

If the array fails my code can't continue, I need array to make so many calculations, so I have to close the program and relaunch it.

Program is located on my cloud VM so I can't monitor it 24/7 but what I would like to do is it to send me a Telegram message warning me about the error, so I can connect and relaunch it.

I already work with Telegram API integration so I can perfectly use it, I just need to intercept this kind of error and before the program closes to send me the warning.

I repeat, I can't manage it just by checking dim,ubound,isarray()... 'cause these issues may happen in so many circumstances. What I would like to do is to handle the error in a smart way.

Thanks for your support,

Marco
 

[pixelsearch]

@marko001 Melba23 isn't here actually (he wrote it a few days ago, so he'll probably suggest an answer when he'll come back) 

Meanwhile you could use OnAutoItExitRegister() to test if something went wrong during the script, for example :

OnAutoItExitRegister("_ExitRegister")

Local $aArray[6][2] = [[1, "A"], [2, "B"], [3, "C"], [4, "D"], [5, "E"], [6, "F"]]

For $i = 0 to 9 ; 9 to force an Array error
    ConsoleWrite("Data: " & $aArray[$i][0] & "," & $aArray[$i][1] & @CRLF)
Next

Func _ExitRegister()
    If @exitCode = 1 Then
        ConsoleWrite("exitCode = " & @exitCode & "   " & "exitMethod = " & @exitMethod & @CRLF)
        ; send yourself a Telegram message warning (your Telegram API integration)
        ; or send it by running another script etc...
    EndIf
EndFunc   ;==>_ExitRegister

@exitMethod could be useful too, as shown in in this thread.

Edited May 2, 2022 by pixelsearch
typo

[marko001]

@pixelsearch I thought it was the solution but I tried and I got this:

I just tried to add a msgbox() once an error is caught but this pop-up will come before the msgbox()

do you think a call to a Telegram function will be passed or not?

Func _ExitRegister()
;~     If @exitCode = 1 Then
MsgBox(0,"","")
        ConsoleWrite("exitCode = " & @exitCode & "   " & "exitMethod = " & @exitMethod & @CRLF)
        ; send yourself a Telegram message warning (your Telegram API integration)
        ; or send it by running another script etc...
;~     EndIf
EndFunc   ;==>_ExitRegister

 

[pixelsearch]

You're right, it doesn't seem to work when the script is executed outside of Scite.
(my test was done on an .au3 script, ran directly from Scite, that's why it worked fine)

Let's hope someone will bring out more infos about this.

[pixelsearch]

@marko001 the following syntax seems to make it, bypassing the error message you displayed in your last post :

"C:\Program Files\AutoIt3\AutoIt3.exe" /ErrorStdOut "C:\Temp7\265.au3"

or

"C:\Temp7\265.exe" /ErrorStdOut

Edit: thanks to @Jos in this post

 

Edited May 2, 2022 by pixelsearch
added the 2 way (au3 or exe)

[marko001]

Yes, if I run from shell it works as intented.

Is there a way to compile it so that I can run by doubleclicking it instead of using Shell and (somewhere in properties) add the 

/ErrorStdOut

parameter?

Edited May 2, 2022 by marko001

[jchd]

12 hours ago, marko001 said:

In real life I come across data coming from Trade Exchange API integration and it may happen that sometimes (connection issue, latencies,...) data is not properly loaded so array creation may fail and boom.

This is exactly where the checkings have to be done and failures gracefully handled.

 

[pixelsearch]

I agree with jchd, important errors may be masked if you go on this way. Anyway...

6 hours ago, marko001 said:

Is there a way to compile it so that I can run by doubleclicking it instead of using Shell and (somewhere in properties) add the /ErrorStdOut parameter?

I found a way, based on 2 exe's, for example :

1) "Test part1.exe" (contains 1 line only, you'll double-click this exe) :

Run(@ScriptDir & "\test part2.exe" & " /ErrorStdOut")

2) "Test part2.exe"

; the full script discussed above, named "test part2"

OnAutoItExitRegister("_ExitRegister")
...

Good luck

[marko001]

@jchd I completely agree with you. Basically all errors arise from damn arrays. I will try to catch all of them

@pixelsearch yeah, first option could be the best. I will combine error prevention and this method.

Thanks all, guys, appreciated your support.

M.