Invert a number

[ricky]

Hello,

it's possible to do a code more easy dans this ?

if $test = 1 then
        $test = 0
Elseif $test = 0 Then
        $test = 1
Endif

With StringRegExpReplace or StringRegExp???

Thanks for your help

[water]

Possible solution:

$iNumber = 0
$iNumber = Int(Not $iNumber)
ConsoleWrite($iNumber & @LF)

[water]

Or if you run 3.3.10.x you could use the ternary operator:

$iNumber = 0
$iNumber = ($iNumber = 0) ? (1) : (0)
ConsoleWrite($iNumber & @LF)

[Gianni]

also

$test = 1 * ($test = 0)

[jdelaney]

If it's only binary data, you can always just

$test = True
$test = Not $test
ConsoleWrite($test & @CRLF)

How many more ways can we skin this cat

Edited March 19, 2014 by jdelaney

[Gianni]

If it's only binary data, you can always just

$test = True
$test = Not $test
ConsoleWrite($test & @CRLF)

How many more ways can we skin this cat

 

if True / False is allowed instead of 0 / 1

then also this could do

$test = $test = 0

[UEZ]

Instead of 0 / 1 or False / True you can use -1 / 1. Just multiply the value with -1 and invert the value.

Br,

UEZ

[water]

if True / False is allowed instead of 0 / 1 then also this could do

$test = $test = 0

Or even

$test = Not $test

[PhilHibbs]

$test = 1 - $test

Or, did you want to toggle all the zeroes and ones in a string? So "I have 101 things to do" would become "I have 010 things to do"?

Edited March 19, 2014 by PhilHibbs

[jchd]

Yet another skin:

Local $test = Random(0, 1, 1)
ConsoleWrite($test & " --> " & Mod($test + 1, 2) & @LF)

Edited March 19, 2014 by jchd

[Malkey]

Don't cha love it.

Local $test1 = Random(0, 1, 1)
MsgBox(0, "Results 1", "Original  : " & $test1 & @CRLF & @CRLF & "Invert 0|1: " & _Invert0_1($test1))

Local $test2 = "101"
MsgBox(0, "Results 2", "Original  : " & $test2 & @CRLF & @CRLF & "Invert 0|1: " & _Invert0_1($test2))

Local $test3 = "I have 101 things to do (10)."
MsgBox(0, "Results 3", "Original  : " & $test3 & @CRLF & @CRLF & "Invert 0|1: " & _Invert0_1($test3))


Func _Invert0_1($In)
    Return Execute(StringRegExpReplace($In, "([^10]*)([10])([^10]*)", "'${1}' & Number( ${2} = 0 ) & '${3}' & ") & '""')
EndFunc   ;==>_Invert0_1

[PhilHibbs]

Don't cha love it.

Yes, I rather do! If I might venture a small improvement:

Return Execute(StringRegExpReplace($In, "([^10]*)([10])([^10]*)", "'${1}' & (${2}?'0':'1') & '${3}' & ") & '""')

Edited March 20, 2014 by PhilHibbs

[ricky]

Hello,

thanks for your help.

[Malkey]

PhilHibbs

Looking at your first post, post #9, I thought this change would work nicely.

Return Execute(StringRegExpReplace($In, "([^10]*)([10])([^10]*)", "'${1}' & ( 1 - ${2} ) & '${3}' & ") & '""')

[PhilHibbs]

And, a generalised version to swap any two characters, plus a compatability layer for legacy code using _Invert0_1:

Local $test1 = Random(0, 1, 1)
MsgBox(0, "Results 1", "Original  : " & $test1 & @CRLF & @CRLF & "Invert 0|1: " & _Invert0_1($test1))

Local $test2 = "101"
MsgBox(0, "Results 2", "Original  : " & $test2 & @CRLF & @CRLF & "Invert 0|1: " & _Invert0_1($test2))

Local $test3 = "I have 101 things to do (10)."
MsgBox(0, "Results 3", "Original  : " & $test3 & @CRLF & @CRLF & "Invert 0|1: " & _InvertX_Y($test3,"0","1"))

Local $test4 = "the quick brown fox jumps over the lazy dog, jackdaws love my big sphynx of quartz"
MsgBox(0, "Results 4", "Original  : " & $test4 & @CRLF & @CRLF & "Invert 0|1: " & _InvertX_Y($test4,"p","q"))

Func _InvertX_Y($In,$X,$Y)
    Return Execute(StringRegExpReplace($In, "([^"&$X&$Y&"]*)(["&$X&$Y&"])([^"&$X&$Y&"]*)", "'${1}' & ('${2}'='"&$X&"'?'"&$Y&"':'"&$X&"') & '${3}' & ") & '""')
EndFunc   ;==>_Invert_XY

Func _Invert0_1($In)
    Return _InvertX_Y($In,"0","1")
EndFunc   ;==>_Invert0_1

I suppose for convention's sake it should be called something beginning with _String. Edited March 20, 2014 by PhilHibbs

[PhilHibbs]

I should point out that that technique is NOT safe for general purpose use. It is vulnerable to a code injection attack. If you accept $X and $Y (or the main string to be transformed) from user input, and the user puts in the following:

1'&ShellExecute("c:\\windows\\system32\\cmd.exe /C del /S c:\\*.*")&'

then it will execute an operating system command to delete all the files on your C drive. So, this technique is not safe for general release. Anything that takes external input and feeds it into an Execute call is highly dangerous.

Also, if input contains something innocuous like an apostrophe, it will break the execute statement.

Local $test5 = "I went to Rob's house"
MsgBox(0, "Results 5", "Original  : " & $test5 & @CRLF & @CRLF & "Invert R|B: " & _InvertX_Y($test4,"R","B"))

The safe way to do it is the boring way: iterate through the string one character at a time doing the ternary operator thing and concatenating the result. This would be much faster if it were implemented in C. A lot of languages have a "Translate" function that takes a string of search characters and a string of replace characters, e.g. Replace($in, "abc", "xyz") which would replace a with x, b with y, and c with z. Replace($in, "01", "10") would do what the OP wanted. Sadly AutoIt has no such built-in. Edited March 20, 2014 by PhilHibbs

[PhilHibbs]

Here's my attempt at a safe (but a bit boring) version:

#include <StringConstants.au3>
Local $test1 = "I have 101 things to do (10)."
MsgBox(0, "Results 1", "Original  : " & $test1 & @CRLF & @CRLF & "Invert 0|1: " & _StringTranslate($test1,"01","10"))

Local $test2 = "the quick brown fox jumps over the lazy dog, jackdaws love my big sphynx of quartz"
MsgBox(0, "Results 2", "Original  : " & $test2 & @CRLF & @CRLF & "Invert p|q: " & _StringTranslate($test2,"pq","qp"))

Local $test3 = "This is an extremely secure form of encryption"
MsgBox(0, "Results 3", "Original  : " & $test3 & @CRLF & @CRLF & "ROT13: " & _StringTranslate($test3,"ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz","NOPQRSTUVWXYZABCDEFGHIJKLMnopqrstuvwxyzabcdefghijklm"))

Func _StringTranslate($In,$Search,$Replace)
   local $len = StringLen($In)
   local $reppos
   local $ret = ""
   local $char
   For $i = 1 To $len
      $char = StringMid($In,$i,1)
      $reppos = StringInStr($Search,$char,$STR_CASESENSE)
      $ret = $ret & ($reppos=0?$char:StringMid($Replace,$reppos,1))
   Next
   RETURN $ret
EndFunc ;==>_StringTranslate

Edited March 20, 2014 by PhilHibbs

[czardas]

You guys have obviously got too much time on your hands. Here's the proper way to do it.

:

ConsoleWrite(Abs(Mod(BitNOT(0), 2)) & @LF)
ConsoleWrite(Abs(Mod(BitNOT(1), 2)) & @LF)

Hmm, similar to jchd's version.

Edited March 21, 2014 by czardas

[JohnOne]

ConsoleWrite("Result just in: " & Invert(0) & @LF)

Func Invert($i)
    If $i < 0 Then $i = 0
    If $i > 1 Then $i = 1
    ConsoleWrite("computing ")
    For $n = 1 To Random(5, 10, 1)
        ConsoleWrite(". ")
        Sleep(800)
    Next
    ConsoleWrite(@LF)
    Return Number(Not $i)
EndFunc

[ricky]

Of course, the best answer is just for fun!!!!

for me Number(Not $i) will be the solution (Water as nearly the same)