Using _WinAPI_GetWindowFileName for 64bit processes within 32bit script?

[VAN0]

Hello.

When script is running in 32bit mode _WinAPI_GetWindowFileName fails to retrieve path of a 64bit process.

Does anyone know how to fix this?

Thank you.

[EDIT]

Seems like the problem is in GetModuleFileNameEx

Edited March 10, 2014 by VAN0

[guinness]

It's how MS works.

[funkey]

I use QueryFullProcessImageName.

Here a fast example:

expandcollapse popup

#include <WinAPIProc.au3>

Run("calc.exe")
Global $hWnd = WinWait("[CLASS:CalcFrame]")

Global $sProcess = __WinAPI_GetWindowFileName($hWnd)
ConsoleWrite($sProcess & @LF)


Func _WinAPI_QueryFullProcessImageName($hProcess)
    Local Const $PROCESS_NAME_NATIVE = 1
    Local $dwSize = 65535
    Local $aRet = DllCall("kernel32.dll", "BOOL", "QueryFullProcessImageName", "handle", $hProcess, "dword", $PROCESS_NAME_NATIVE, "str", "", "dword*", $dwSize)
    Return $aRet[3]
EndFunc


Func __WinAPI_GetWindowFileName($hWnd)
    Local $PID = 0

    Local $Result = DllCall("user32.dll", "bool", "IsWindow", "hwnd", $hWnd)
    If $Result[0] Then
        $Result = DllCall("user32.dll", "dword", "GetWindowThreadProcessId", "hwnd", $hWnd, "dword*", 0)
        $PID = $Result[2]
    EndIf
    If Not $PID Then Return SetError(1, 0, '')

    $Result = __WinAPI_GetProcessFileName($PID)
    If @error Then Return SetError(@error, @extended, '')

    Return $Result
EndFunc   ;==>_WinAPI_GetWindowFileName

Func __WinAPI_GetProcessFileName($PID = 0)
    If Not $PID Then $PID = @AutoItPID

    Local $hProcess = DllCall('kernel32.dll', 'handle', 'OpenProcess', 'dword', __Iif($__WINVER < 0x0600, 0x00000410, 0x00001010), _
            'bool', 0, 'dword', $PID)
    If @error Or Not $hProcess[0] Then Return SetError(@error + 20, @extended, '')

;~  Local $Path = _WinAPI_GetModuleFileNameEx($hProcess[0])
    Local $Path = _WinAPI_QueryFullProcessImageName($hProcess[0])
    Local $iError = @error

    DllCall("kernel32.dll", "bool", "CloseHandle", "handle", $hProcess[0])
    If $iError Then Return SetError(@error, 0, '')

    Return $Path
EndFunc   ;==>_WinAPI_GetProcessFileName

[VAN0]

Thank you very much!

Your code and code from Yashied is exactly what I needed:

#Include <WinAPIEx.au3>

ConsoleWrite(_DosPathNameToPathName('\Device\HarddiskVolume2\Program Files\SomeProgram\exe.exe') & @CR)

Func _DosPathNameToPathName($sPath)

    Local $sName, $aDrive = DriveGetDrive('ALL')

    If Not IsArray($aDrive) Then
        Return SetError(1, 0, $sPath)
    EndIf

    For $i = 1 To $aDrive[0]
        $sName = _WinAPI_QueryDosDevice($aDrive[$i])
        If StringInStr($sPath, $sName) = 1 Then
            Return StringReplace($sPath, $sName, StringUpper($aDrive[$i]), 1)
        EndIf
    Next
    Return SetError(2, 0, $sPath)
EndFunc   ;==>_DosPathNameToPathName

WinAPIEx.au3

Global $sProcess = _DosPathNameToPathName(__WinAPI_GetWindowFileName($hWnd))
ConsoleWrite($sProcess & @LF)

Although it doesn't get drive letters for network drives, but in my case it's irrelevant.

Thanks again

Edited March 11, 2014 by VAN0

[funkey]

If you use 0 instead of $PROCESS_NAME_NATIVE then you get the Win32 path format 

Func _WinAPI_QueryFullProcessImageName($hProcess)
    Local Const $PROCESS_NAME_NATIVE = 1
    Local $dwSize = 65535
    Local $aRet = DllCall("kernel32.dll", "BOOL", "QueryFullProcessImageName", "handle", $hProcess, "dword", 0, "str", "", "dword*", $dwSize)
    Return $aRet[3]
EndFunc

Edited March 11, 2014 by funkey

[VAN0]

Absolutely perfect.

Thank you!

[VAN0]

Hello. What could possibly cause this method not work on games? Specifically War Thunder. It doesn't matter if I run the game in fullscreen or windowed, this script can't get the path of the executable.

Any advice?

Thank you.

[JohnOne]

There is a lot of error checking in funkey's code.

Put in some message boxes or console writes to find out what is failing and what the error codes are.

[VAN0]

It returns @error = 20

which is these lines:

Local $hProcess = DllCall('kernel32.dll', 'handle', 'OpenProcess', 'dword', __Iif($__WINVER < 0x0600, 0x00000410, 0x00001010), _
            'bool', 0, 'dword', $PID)
    If @error Or Not $hProcess[0] Then Return SetError(@error + 20, @extended, '')

I've checked $PID is correct for the window.

Edited August 5, 2014 by VAN0

[JohnOne]

Probably need different access to the process, maybe it's protected or is running with administritive right or something.

You can read about access rights here, there are probably constants in the WinAPI includes.

[VAN0]

Thank you. This is more then I can chew right now. I'm not fully understanding how this code works in the first place.

For now I use win32_process class. Much slower, but works fine for my use:

Func __WinAPI_GetWindowFileName($hWnd)

    Local $PID = 0

    Local $Result = DllCall("user32.dll", "bool", "IsWindow", "hwnd", $hWnd)
    If $Result[0] Then
        $Result = DllCall("user32.dll", "dword", "GetWindowThreadProcessId", "hwnd", $hWnd, "dword*", 0)
        $PID = $Result[2]
    EndIf
    If Not $PID Then Return SetError(1, 0, '')
    $Result = __WinAPI_GetProcessFileName($PID)
    If @error Then
        Dim $oWMIService = ObjGet("winmgmts:{impersonationLevel=impersonate}!\\.\root\cimv2")
        $o_ColListOfProcesses = $oWMIService.ExecQuery ("SELECT * FROM Win32_Process WHERE ProcessId = " & $PID)
        $er = @error
        $ex = @extended
        For $o_ObjProcess in $o_ColListOfProcesses
                Return $o_ObjProcess.ExecutablePath
        Next

        Return SetError($er, $ex, '')
    EndIf

    Return $Result
EndFunc   ;==>__WinAPI_GetWindowFileName

Edited August 6, 2014 by VAN0