Listview sorting.

[Jack023]

Hello all,

I'm struggling with a sorting problem with my Listview:

I want be able to sort it by clicking the Names on top.
 

Global $listview = GUICtrlCreateListView("Date           |Requests           |Impressions                                |Clicks             |CTR            |eCPM           |Earnings           ", 15, 160, 679, 105)


func _listview()
     _GUICtrlListView_DeleteAllItems($listview)
    GUICtrlSetBkColor($listview, 0xF2F6F7)

;~  _GUICtrlListView_SetBkColor($listview, 0x0000FF)
    _GUICtrlListView_SetColumnWidth($listview, 0, 85)
EndFunc


        GUICtrlCreateListViewItem($date & "          "&"|" &$totalreq&"          "&"|" &$totalimpes&"                                "&"|"& $total_clicks&"          "&"|"& $ctr&"%          "&"|$"& $ecpm&"             "&"|$"& $totalbalance&"             ", $listview)

Sorry for the weird sentences.
Anyway , i tried some sorting things in helpfile but everytime my script will just doing weird because it's doing a while loop.

So how to sort them, until i quit the gui or click the "$Button1" button.

[water]

According to the help file: "Sorting the list by clicking the column name (as in Explorer) is not currently implemented."

[BrewManNH]

I don't see anywhere in the posted code an attempt at sorting the listview. Have you attempted to search for the dozens of examples on the forum of how to do this?

[water]

To register a sort function please have a look at _GUICtrlListView_RegisterSortCallBack.

[Melba23]

Jacko23,

You can do it like this:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GUIListView.au3>

Global $aData[4] = ["2014-03-09|456|201|3|0.45%|$2.94|$0.7654", "2014-03-08|236|231|2|0.65%|$1.25|$1.4321", _
            "2014-03-07|566|341|1|0.75%|$4.62|$0.4567", "2014-03-06|786|561|3|0.95%|$6.48|$0.8765"]

Global $fSortSense = False ; Set initial ascending sort

$hGUI = GUICreate("Test", 500, 500)

$cListView = GUICtrlCreateListView("", 10, 10, 480, 400)
_GUICtrlListView_AddColumn($cListView, "Date", 80)
_GUICtrlListView_AddColumn($cListView, "Requests", 80)
_GUICtrlListView_AddColumn($cListView, "Impressions", 80)
_GUICtrlListView_AddColumn($cListView, "Clicks")
_GUICtrlListView_AddColumn($cListView, "CTR")
_GUICtrlListView_AddColumn($cListView, "eCPM")
_GUICtrlListView_AddColumn($cListView, "Earnings", 80)

For $i = 0 To 3
    GUICtrlCreateListViewItem($aData[$i], $cListView)
Next

GUISetState()

GUIRegisterMsg($WM_NOTIFY, "_WM_NOTIFY")

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

WEnd

Func _WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam
    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $iIDFrom
        Case $cListView
            Switch $iCode
                Case $LVN_COLUMNCLICK ; A column was clicked
                    $tInfo = DllStructCreate($tagNMLISTVIEW, $lParam)
                    _GUICtrlListView_SimpleSort($cListView, $fSortSense, DllStructGetData($tInfo, "SubItem"))
            EndSwitch
    EndSwitch
EndFunc

M23

[Jack023]

Melba, You are awesome!

Thanks alot

[Jack023]

Sorry, Came to a another problem.

Func _RunAllOnStart()
    _listview()
    _HasVideoAds()
    _RegistrationDate()
    _CompletionRate()
    _CurrentBalance()
    _PayoutDate()
    _ServerDate()
    _Statistics()
    _LastRefresh()
    _ReferralStatus()
EndFunc

Func _RunAllFunc()
    GUISetState(@SW_LOCK)
    _listview()
    _ReferralStatus()
    _HasVideoAds()
    _RegistrationDate()
    _CompletionRate()
    _CurrentBalance()
    _PayoutDate()
    _ServerDate()
    _Statistics()
    _LastRefresh()
    _listview()
    GUISetState(@SW_UNLOCK)
EndFunc

Runallonstart that means when GUI starts up it will run all functions and then the sorting system works.

When i click $button1 = Refresh button then it will do the _RunAllFunc.

Then my listview is empty for some reason because i added the:

func _listview()
     _GUICtrlListView_DeleteAllItems($listview)
    GUICtrlSetBkColor($listview, 0xF2F6F7)

;~  _GUICtrlListView_SetBkColor($listview, 0x0000FF)
    _GUICtrlListView_SetColumnWidth($listview, 0, 85)
    GUIRegisterMsg($WM_NOTIFY, "_WM_NOTIFY")
EndFunc

Func _WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam
    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $iIDFrom
        Case $listview
            Switch $iCode
                Case $LVN_COLUMNCLICK ; A column was clicked
                    $tInfo = DllStructCreate($tagNMLISTVIEW, $lParam)
                    _GUICtrlListView_SimpleSort($listview, $fSortSense, DllStructGetData($tInfo, "SubItem"))
            EndSwitch
    EndSwitch
EndFunc

So how to fix this? 

[BrewManNH]

An easier way to sort a ListView.

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GUIListView.au3>

Global $aData[4] = ["2014-03-09|456|201|3|0.45%|$2.94|$0.7654", "2014-03-08|236|231|2|0.65%|$1.25|$1.4321", _
        "2014-03-07|566|341|1|0.75%|$4.62|$0.4567", "2014-03-06|786|561|3|0.95%|$6.48|$0.8765"]

Global $fSortSense = False ; Set initial ascending sort

$hGUI = GUICreate("Test", 500, 500)

$cListView = GUICtrlCreateListView("", 10, 10, 480, 400)
_GUICtrlListView_AddColumn($cListView, "Date", 80)
_GUICtrlListView_AddColumn($cListView, "Requests", 80)
_GUICtrlListView_AddColumn($cListView, "Impressions", 80)
_GUICtrlListView_AddColumn($cListView, "Clicks")
_GUICtrlListView_AddColumn($cListView, "CTR")
_GUICtrlListView_AddColumn($cListView, "eCPM")
_GUICtrlListView_AddColumn($cListView, "Earnings", 80)

For $i = 0 To 3
    GUICtrlCreateListViewItem($aData[$i], $cListView)
Next

GUISetState()

Global $iCol
While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cListView
            $iCol = GUICtrlGetState($cListView)
            _GUICtrlListView_SimpleSort($cListView, $fSortSense, $iCol)
    EndSwitch

WEnd

[Melba23]

BrewManNH,

I keep forgetting that you can do it that way!

M23

[BrewManNH]

I'm infinitely lazy, I only like to type as much/little as possible to achieve my objective.

[Jack023]

Well done, it's working right now ! 

[OneJeremias]

Might someone take a look at my code and tell me why it's not sorting? Nothing happens when I click the column header, although I do believe I have implemented BrewMan's code correctly. I'm wondering if it has anything to do with the data I pull from the excel spreadsheet...can anything from that process cause problems with sorting this way?
 
Thanks for any help:

expandcollapse popup

#include <Excel.au3>
#include <Array.au3>
#include <GuiImageList.au3>
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <GUIListBox.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>

Global $fSortSense = False ; Set initial ascending sort

$oExcel = _ExcelBookOpen("c:\users.xls", @SW_HIDE)
_ExcelSheetActivate($oExcel, "Sheet1")
$result = _ExcelReadSheetToArray($oExcel)
_ExcelBookClose($oExcel)


#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 986, 581, 192, 124)
$hListView = _GUICtrlListView_Create($Form1, "Computer name|User|Dept|Location", 20, 15, 500, 170)  ; create the list view
_GUICtrlListView_SetColumnWidth($hListView, 0, 100)
_GUICtrlListView_SetColumnWidth($hListView, 1, 175)
_GUICtrlListView_SetColumnWidth($hListView, 2, 130)
_GUICtrlListView_SetColumnWidth($hListView, 4, 50)
_GUICtrlListView_SetExtendedListViewStyle($hListView, $LVS_EX_FULLROWSELECT )                       ; selecting one item highlights entire row
$Button1 = GUICtrlCreateButton("Ninite", 525, 56, 89, 33)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

for $i = 0 to UBound($result,1) - 3
    _GUICtrlListView_AddItem($hListView, $result[$i + 2][1], 0)
    _GUICtrlListView_AddSubItem ($hListView, $i, $result[$i + 2][2], 1)
    _GUICtrlListView_AddSubItem ($hListView, $i, $result[$i + 2][3], 2)
    _GUICtrlListView_AddSubItem ($hListView, $i, $result[$i + 2][4], 3)
    ;Sleep(2000)
Next

GUISetState()

Global $iCol

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hListView
            $iCol = GUICtrlGetState($hListView)
            _GUICtrlListView_SimpleSort($hListView, $fSortSense, $iCol)
    EndSwitch
WEnd

[BrewManNH]

GUIGetMsg won't work with control handles, and the listview was created using the UDF and not the native functions. If you create your listview with the native function it should work.

$hListView = GUICtrlCreateListView("Computer name|User|Dept|Location", 20, 15, 500, 170)  ; create the list view

[OneJeremias]

Ok great, that worked!

However, I'm not entirely clear on why. When I switched to using a native function, what does that mean in terms of what GUIGetMsg is receiving? It is not getting a control handle anymore? I believe I have a [very] incomplete understanding of how all the pieces work together, so please excuse me if my code indicates that I'm farther along than I actually am :-)

[BrewManNH]

GUIGetMsg works with the control IDs that AutoIt's native functions return, and with the handle from the GUICreate function. It will not work with the handles returned by the UDF functions which is why your script wouldn't work when you used _GUICtrlListView_Create to create the listview. You can get the handle from a control ID using GUICtrlGetHandle, but you can't get the control ID from the handle because there isn't one.

The built-in functions in AutoIt will usually only work with control IDs returned from AutoIt built-in functions. The UDFs will most of the time work with either, although some of them don't work 100% accurately with a control ID.

[OneJeremias]

Ok that makes sense.  Thank you for the help! On to the next piece of this project which will inevitably send me back here :-)