Remove random chars from a string

[guinness]

Chimaera,

Fixed that problem.

[guinness]

mikell's is faster!

expandcollapse popup

Example()

Func Example()
    Local $sString = '3EDF35C6C10345A78F885679C86D701A'
    Local $aPos[] = [3, 6, 3, 7, 9] ; The positions.

    $hTimer = TimerInit()
    For $i = 1 To 1000
        _StringStringByPos_mikell($sString, "36379")
    Next
    ConsoleWrite(TimerDiff($hTimer) & @CRLF)

    $hTimer = TimerInit()
    For $i = 1 To 1000
        _StringStringByPos_guinness($sString, $aPos)
    Next
    ConsoleWrite(TimerDiff($hTimer) & @CRLF)

    ConsoleWrite(_StringStringByPos_guinness($sString, $aPos) & @CRLF)
    ConsoleWrite(_StringStringByPos_mikell($sString, '36379') & @CRLF)
EndFunc   ;==>Example

Func _StringStringByPos_guinness($sString, ByRef $aPos) ; $aPos must be a zero based array of integer values.
    Local Const $STRING_LEN = StringLen($sString)
    If Not UBound($aPos) Or Not $STRING_LEN Then Return SetError(1, 0, $sString)

    Local $iGroup = 0, $iLength = $STRING_LEN, $iTotalPos = 0, _
            $sReplacePattern = '', $sSearchPattern = ''
    For $i = 0 To UBound($aPos) - 1
        $aPos[$i] = Int($aPos[$i])
        $iLength -= $aPos[$i]
        $iTotalPos += $aPos[$i]
        $iGroup += 1 ; Increment the replacement group value.
        If $iTotalPos > $STRING_LEN Then
            $iLength += $aPos[$i]
            ExitLoop
        EndIf
        $sSearchPattern &= '([[:xdigit:]]{' & $aPos[$i] - 1 & '})[[:xdigit:]]' ; Search pattern.
        $sReplacePattern &= '${' & $iGroup & '}' ; Replacement pattern.
    Next
    If $iLength > 0 Then ; If there is values still remaining create a capture all group.
        $sSearchPattern &= '([[:xdigit:]]{' & $iLength & '})'
        $sReplacePattern &= '${' & $iGroup + 1 & '}'
    EndIf
    Return StringRegExpReplace($sString, $sSearchPattern, $sReplacePattern)
EndFunc   ;==>_StringStringByPos_guinness

Func _StringStringByPos_mikell($sString, $sDelete)
    Local $aAdd = 0, $aDelete = StringSplit($sDelete, "")
    For $i = 1 To $aDelete[0]
        $aAdd += $aDelete[$i]
        $sString = StringReplace($sString, $aAdd, '#')
    Next
    Return StringReplace($sString, '#', '')
EndFunc   ;==>_StringStringByPos_mikell

But come on, don't I get points for using a regular expression and being the first to come up with something?

[mikell]

Decidedly no doubt about this 

Edit

$iAdd sounds better than $aAdd (an academic perspective)

Edited March 2, 2014 by mikell

[Chimaera]

Its a very cheesetastic set of possibilities

Thx again

[Gianni]

mikell's is faster!

expandcollapse popup

Example()

Func Example()
    Local $sString = '3EDF35C6C10345A78F885679C86D701A'
    Local $aPos[] = [3, 6, 3, 7, 9] ; The positions.

    $hTimer = TimerInit()
    For $i = 1 To 1000
        _StringStringByPos_mikell($sString, "36379")
    Next
    ConsoleWrite(TimerDiff($hTimer) & @CRLF)

    $hTimer = TimerInit()
    For $i = 1 To 1000
        _StringStringByPos_guinness($sString, $aPos)
    Next
    ConsoleWrite(TimerDiff($hTimer) & @CRLF)

    ConsoleWrite(_StringStringByPos_guinness($sString, $aPos) & @CRLF)
    ConsoleWrite(_StringStringByPos_mikell($sString, '36379') & @CRLF)
EndFunc   ;==>Example

Func _StringStringByPos_guinness($sString, ByRef $aPos) ; $aPos must be a zero based array of integer values.
    Local Const $STRING_LEN = StringLen($sString)
    If Not UBound($aPos) Or Not $STRING_LEN Then Return SetError(1, 0, $sString)

    Local $iGroup = 0, $iLength = $STRING_LEN, $iTotalPos = 0, _
            $sReplacePattern = '', $sSearchPattern = ''
    For $i = 0 To UBound($aPos) - 1
        $aPos[$i] = Int($aPos[$i])
        $iLength -= $aPos[$i]
        $iTotalPos += $aPos[$i]
        $iGroup += 1 ; Increment the replacement group value.
        If $iTotalPos > $STRING_LEN Then
            $iLength += $aPos[$i]
            ExitLoop
        EndIf
        $sSearchPattern &= '([[:xdigit:]]{' & $aPos[$i] - 1 & '})[[:xdigit:]]' ; Search pattern.
        $sReplacePattern &= '${' & $iGroup & '}' ; Replacement pattern.
    Next
    If $iLength > 0 Then ; If there is values still remaining create a capture all group.
        $sSearchPattern &= '([[:xdigit:]]{' & $iLength & '})'
        $sReplacePattern &= '${' & $iGroup + 1 & '}'
    EndIf
    Return StringRegExpReplace($sString, $sSearchPattern, $sReplacePattern)
EndFunc   ;==>_StringStringByPos_guinness

Func _StringStringByPos_mikell($sString, $sDelete)
    Local $aAdd = 0, $aDelete = StringSplit($sDelete, "")
    For $i = 1 To $aDelete[0]
        $aAdd += $aDelete[$i]
        $sString = StringReplace($sString, $aAdd, '#')
    Next
    Return StringReplace($sString, '#', '')
EndFunc   ;==>_StringStringByPos_mikell

But come on, don't I get points for using a regular expression and being the first to come up with something?

 

try your test with this to be deleted: "36999" for example

mikell's way gives not output at all,

while guinness's way gives wrong result....

emm.. sorry

Edited March 2, 2014 by PincoPanco

[mikell]

Surely, you can decide to make the script truncate the 'delete' number to force it to work

An other way is to set an error and that means no output

The best way remains to check the error at the number creation time so once defined it will always work ^^

[guinness]

Fixed it again. See post #5.

[UEZ]

Here my variant:

Global $sString = "3EDF35C6C10345A78F885679C86D701A"
Global $aRemove = [3, 6, 3, 7, 9]
Global $sNew, $iStart = 1
For $i = 0 To UBound($aRemove) - 1
    $sNew &= StringMid($sString, $iStart, $aRemove[$i] - 1)
    $iStart += $aRemove[$i]
    If $iStart > StringLen($sString) Then ExitLoop
Next
$sNew &= StringMid($sString, $iStart, StringLen($sString))

ConsoleWrite($sNew & @CRLF)

Br,

UEZ

[mikell]

An other one using a regex because of the bug in : StringReplace($string, $pos, "")

$string = "3EDF35C6C10345A78F885679C86D701A"
$delete = "36379"
;$delete = "9999"

$aDel = StringSplit($delete, "")
Local $add = 0
For $i = 1 to $aDel[0]
    $add += $aDel[$i]-1
    $string = StringRegExpReplace($string, '(.{' & $add & '}).(.+)', '$1$2')
   ; $string = StringReplace($string, $add, "")
Next
Msgbox(0,"", (@extended = 0) ? "error $add" : $string)

[guinness]

I know that version is going to be slower than mine -_0.

[mikell]

Probably (not tested)

It's nothing else but the spare wheel of the StringReplace bug 

Should be faster with StringReplace ...

[guinness]

Yeh it's a strange bug, though honestly speaking I have never used an integer value to mark the char position.

[mikell]

So did I until recently, I remembered this feature when reading the topic which evoked this bug

It's an interesting feature which deserves a fix, don't you think so ?

[guinness]

don't you think so ?

Of course I do, but a Trac request needs to be created else Jon won't be able to fix it otherwise.

[mikell]

Such a thing is a Developer's work, sort of 

[guinness]

Such a thing is a Developer's work, sort of 

Well I have more pressing things to do and I can't be watching all of the posts all of the time. It's why we have the tools there for users to post bug reports and/or requests. If it's down to us Devs to use, then why have those tools in the first place?

[mikell]

Sorry, I didn't say that to pressure you

I never used this tool and just thought it would be best and much more quickly done by a Dev

Edit

OK I did it here http://www.autoitscript.com/trac/autoit/ticket/2666#ticket

Edited March 3, 2014 by mikell

[kylomas]

another....

local $str = '3EDF35C6C10345A78F885679C86D701A'

local $repl = 36379
;local $repl = 99999999999999999999999999

while $repl
    $str = stringleft($str,stringleft($repl,1)-1) & stringright($str,stringlen($str)-StringLeft($repl,1))
    $repl = stringtrimleft($repl,1)
WEnd

ConsoleWrite($str & @LF)

Edited March 3, 2014 by kylomas

[Chimaera]

That last one doesnt work by my recogging

36379

3EDF35C6C10345A78F885679C86D701A 

     ^             ^     ^             ^                  ^

 ie 

3EF35C61045A78F85679C86701A  yours gives

3E356C035A78F885679C86D701A

It seems to take the third and 4th char

Just to clarify so im sure people get what i mean

36379

It is to count 3 to the right then delete count 6 more from the delete spot and remove then 3 more to the right etc

This could be any number 36379 next time it could be 52286

Its a random number from my other code not a fixed set of chars to be done it will change every time

Edited March 3, 2014 by Chimaera

[Gianni]

my >previous snipped is ready to use without errors (I hope )

here another way

Local $sString = "3EDF35C6C10345A78F885679C86D701A"
Local $cut = "36379"
ConsoleWrite("in : " & $sString & @CRLF & "out: " & example($sString, $cut) & @CRLF)

Func example($string, $cut)
    Local $out = ""
    Local $cuts = StringSplit($cut, "")
    For $i = 1 To $cuts[0]
        $out &= StringLeft($string, $cuts[$i] - 1)
        $string = StringTrimLeft($string, $cuts[$i])
    Next
    $out &= $string
    Return $out
EndFunc   ;==>example

Edited March 3, 2014 by PincoPanco