Questions about GUICtrlCreateInput

[TrickyDeath]

Hello everyone,

I have a question about this GUICtrlCreateInput (updown). I found out i can give stlye like this:

$ES_NUMBER

But i wana know does it posible to set the the increase / decrase value?

What i want:

Example the default number is 1000 and if user push up or down arrow / button wahtever, the numbers increase / decrase with 10, and not with 1.

Somehow can make a loop for it or any other way, or AutoIT does not support this option on this object?

Tricky,

[Melba23]

TrickyDeath,

It is easy if you know how:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <UpDownConstants.au3>

$hGUI = GUICreate("Test", 500, 500)

$cInput = GUICtrlCreateInput("1000", 10, 10, 100, 40)
GUICtrlSetFont($cInput, 18)
$cUpDown = GUICtrlCreateUpdown($cInput, BitOR($UDS_WRAP, $UDS_NOTHOUSANDS))
GUICtrlSetLimit($cUpDown, 1500, 500)

GUISetState()

GUIRegisterMsg($WM_NOTIFY, "_WM_NOTIFY")

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

WEnd

Func _WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)

    ; Is it from the UpDown?
    If BitAND($wParam, 0xFFFF) = $cUpDown Then
        ; Create NMUPDOWN structure
        Local $tStruct = DllStructCreate("hwnd;long;int;long;long", $lParam)
        ; Is it a change message?
        If DllStructGetData($tStruct, 3) = 0xFFFFFD2E Then ; $UDN_DELTAPOS
            ; Alter the change value
            DllStructSetData($tStruct, 5, DllStructGetData($tStruct, 5) * 10) ; Multiply by 10
        EndIf
    EndIf

EndFunc

Please ask if anything is unclear.

M23

[funkey]

For better understanding

#include <GUIConstantsEx.au3>
#include <EditConstants.au3>
#include <WindowsConstants.au3>

Global Const $UDM_SETACCEL = 1131
Global Const $UDM_SETRANGE32 = 1135


Global $UDACCEL = DllStructCreate("UINT nSec1; UINT nInc1;UINT nSec2; UINT nInc2;UINT nSec3; UINT nInc3")
Global $pUDACCEL = DllStructGetPtr($UDACCEL)

DllStructSetData($UDACCEL, "nSec1", 0) ; time in seconds
DllStructSetData($UDACCEL, "nInc1", 10) ; jump width 10
DllStructSetData($UDACCEL, "nSec2", 3) ; after 3 seconds
DllStructSetData($UDACCEL, "nInc2", 100) ; jump width 100
DllStructSetData($UDACCEL, "nSec3", 6) ; after 6 seconds
DllStructSetData($UDACCEL, "nInc3", 1000) ; jump width 1000

$hGUI = GUICreate('Test Updown', 220, 100, -1, -1)
$hInput = GUICtrlCreateInput('50', 25, 25, 60, 22);, $ES_READONLY)
$hUpDown = GUICtrlCreateUpdown($hInput)
GUICtrlSendMsg(-1, $UDM_SETRANGE32, 0, 20000) ; range from 0 to 20000
GUICtrlSendMsg(-1, $UDM_SETACCEL, 3, $pUDACCEL)

GUISetState()

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

Exit

[FireFox]

This the correct code of Melba's version :

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <StructureConstants.au3>

Global Const $tagNMUPDOWN = $tagNMHDR & ";int iPos;int iDelta"

Global $iStep = 5

GUICreate("MyGUI")

Local $iInput1 = GUICtrlCreateInput("0", 10, 10, 80, 20)
Local $iUpDown1 = GUICtrlCreateUpdown($iInput1)

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

GUISetState(@SW_SHOW)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop
    EndSwitch
WEnd

GUIDelete()

Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    Local $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    Local $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")

    Switch $iIDFrom
        Case $iUpDown1
            Local $tInfo = DllStructCreate($tagNMUPDOWN, $lParam)

            DllStructSetData($tInfo, "iDelta", (DllStructGetData($tInfo, "iDelta") > 0 ? $iStep : -$iStep))
    EndSwitch

    Return $GUI_RUNDEFMSG
EndFunc

Edited February 27, 2014 by FireFox

[TrickyDeath]

First of all OMG, web browser could not open the page, and my answare got destroyed. grrr...

Hello M23 again,

Thank you all the answares for everyone.

Gona open help file to try to understand the new codes.

But in first read it is looks understable.

Unfortunately funkey your codes are more complicated for me then Melba23's and FireFox's codes. I gona stay with theyr codes. Before i test it , I am guessing that is what i was searching for.

P.S to M23.:

Well yes, for you it is easy, but for me is not, since i try to learn programing by myself.

Wanted to PM you earlyer, but i can not. Subject( delete my first topic about store mouse coord...) no need to stay on AutoIT forum, specialy not with codes inside. (I have no rights to delete it)

Tricky,

[mikell]

OK this is a simpler way (a bit tricky though) using the example from the helpfile and a dummy input

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $input, $msg

    GUICreate("My GUI UpDown", -1, -1, -1, -1, $WS_SIZEBOX)
    $input = GUICtrlCreateInput("1000", 10, 10, 50, 30)
    $dummy_input = GUICtrlCreateInput("", 75, 10, 1, 30)
    GUICtrlCreateUpdown($dummy_input)
    GUISetState(@SW_SHOW)

    While 1
        $msg = GUIGetMsg()
        Switch $msg
            Case $GUI_EVENT_CLOSE
                ExitLoop
            Case $dummy_input
                GuiCtrlSetData($input, 1000 + GuiCtrlRead($dummy_input)*10)
        EndSwitch
    WEnd
EndFunc   ;==>Example

Edited February 27, 2014 by mikell

[funkey]

My code is too complicated?????

Here a shorter Version:

#include <GUIConstantsEx.au3>
#include <EditConstants.au3>
#include <WindowsConstants.au3>

$UDM_SETACCEL = 1131
$UDM_SETRANGE32 = 1135
$UDACCEL = DllStructCreate("UINT nSec; UINT nInc")
$pUDACCEL = DllStructGetPtr($UDACCEL)
DllStructSetData($UDACCEL, "nSec", 0)
DllStructSetData($UDACCEL, "nInc", 10) ; jump width 10


$hGUI = GUICreate('Test', 220, 100, -1, -1)
$hInput = GUICtrlCreateInput('50', 25, 25, 48, 22, $ES_READONLY)
$hUpDown = GUICtrlCreateUpdown($hInput)
GUICtrlSendMsg(-1, $UDM_SETRANGE32, 0, 1000) ; range from 0 to 1000
GUICtrlSendMsg(-1, $UDM_SETACCEL, 1, $pUDACCEL)

GUISetState()

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

[FireFox]

My code is too complicated?????

It may be your avatar which confuses him...

[Melba23]

funkey,

Thanks for posting your $UDACCEL solution - very nice code.

M23

[mikell]

My code is too complicated?????

 

By comparing with the use of a dummy, decidedly yes it is 

[TrickyDeath]

Dear funkey,

Like i said before, i am learning programing by myself. Maybe you alredy did it in school, so for you it is easy to understand, but if you have nearly no knowleadge and u start it from 0, it will be complicated. At least for me looks like, since i never saw those orders what you useing in your codes. First of all, I did not said your code is wrong, or long or anything like this.

Sorry if you misunderstand me.

From that 2 answare what i said, i could understand most of the orders (codes) with out use help file. :/

//to FireFox - 

When i try to run your code it say this:

D:_Instal4GLAutoITScriptsTextBoxUpDown.au3(35,88) : ERROR: syntax error (illegal character)

            DllStructSetData($tInfo, "iDelta", (DllStructGetData($tInfo, "iDelta") > 0 ?

 

for this line:

DllStructSetData($tInfo, "iDelta", (DllStructGetData($tInfo, "iDelta") > 0 ? $iStep : -$iStep))

 

Anyway, Melba's code work fine and i can use it.

Edited February 27, 2014 by TrickyDeath

[funkey]

Tricky, I did not misunderstand you. I just forgot to post some Smileys      

Firefox' version uses features of the latest stable version.

Melba: Thanks, but it's not my code, I just use it for years now, since 'Großvater' posted it on German Forum.

[TrickyDeath]

For all who looking for the same solution:

All the codes work fine in test.

Except FireFox's codes. Don't blame me pls.

Ty funkey, probably that is why it is does not working for me...

Smileys make your post better.

 

P.S.:

Can i use multiple "mark solved"?

[mLipok]

 

 

for this line:

DllStructSetData($tInfo, "iDelta", (DllStructGetData($tInfo, "iDelta") > 0 ? $iStep : -$iStep))

which version of AutoIt you use ?

in this line is Ternary operator from AutoIt 3.3.10.0 or later

edit:
oh I see @funkey mention about this in post #12

Edited February 27, 2014 by mLipok

[FireFox]

Well it's just to compact the code.

Replace by :

If DllStructGetData($tInfo, "iDelta") > 0 Then
    DllStructSetData($tInfo, "iDelta", $iStep)
Else
    DllStructSetData($tInfo, "iDelta", -$iStep)
EndIf

[TrickyDeath]

//to mLipok - AutoIT version is

"Version 3.3.6

    Oct 19 2013 17:27:41"

 

seams like mine is not so up to date. :/

[mLipok]

yes indeed

edit:

3.3.6.0 (7th March, 2010) (Release)

http://www.autoitscript.com/autoit3/docs/history.htm

edit 2:

you have to look here:

http://www.autoitscript.com/site/autoit/downloads/

http://www.autoitscript.com/site/autoit-script-editor/downloads/

Edited February 27, 2014 by mLipok

[TrickyDeath]

I did download and instal the newest version and now it say:

Version 3.3.7

    Dec 12 2013 20:45:19

 

while the website say:

on first link:

Latest version: v3.3.10.2

 

Updated: 30th December, 2013

 

On second:

AutoIt v3.3.10.2

[mLipok]

 

Version 3.3.7

    Dec 12 2013 20:45:19

 

where you read this info ?

It look like SciTe4AutoIt version, but not AutoIt .

[TrickyDeath]

In the AutoIT script editor (SciTE / help menu - About SciTE)